Mercurial > hg > vamp-plugin-pack

view plugin.pri @ 129:afd72eb2b0aa tip

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Added tag v1.0-windows-32bit for changeset 7d5387c63447
author Chris Cannam
date Fri, 12 Jun 2020 17:20:52 +0100
parents 2405126aa5fe
children
line wrap: on
line source

exists(config.pri) {
    include(config.pri)
}

!exists(config.pri) {
    include(noconfig.pri)
}

CONFIG -= qt

win* {
    CONFIG += dll
}
!win* {
    CONFIG += plugin
}

CONFIG += no_plugin_name_prefix release warn_on

QMAKE_CXXFLAGS -= -Werror

INCLUDEPATH += $$PWD/vamp-plugin-sdk

# 
win32-msvc* {
    LIBS += -EXPORT:vampGetPluginDescriptor
}
win32-g++* {
    LIBS += -Wl,--version-script=$$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.map
}
linux* {
    LIBS += -Wl,--version-script=$$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.map -Wl,-no-undefined
}
macx* {
    LIBS += -exported_symbols_list $$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.list
}

QMAKE_POST_LINK += $$DEPLOYDIR/mark-for-signing out