diff plugin.pri @ 116:2405126aa5fe

Of course, the use of dll to build a plugin only works on Windows (where it's necessary because we have static_runtime defined), not on other platforms (where we have a lib- prefix on non-plugin libraries, and we don't have static runtime anyway). Fix and simplify with an additional qmake include file

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/plugin.pri	Fri Mar 06 13:32:45 2020 +0000
@@ -0,0 +1,40 @@
+
+exists(config.pri) {
+    include(config.pri)
+}
+
+!exists(config.pri) {
+    include(noconfig.pri)
+}
+
+CONFIG -= qt
+
+win* {
+    CONFIG += dll
+}
+!win* {
+    CONFIG += plugin
+}
+
+CONFIG += no_plugin_name_prefix release warn_on
+
+QMAKE_CXXFLAGS -= -Werror
+
+INCLUDEPATH += $$PWD/vamp-plugin-sdk
+
+# 
+win32-msvc* {
+    LIBS += -EXPORT:vampGetPluginDescriptor
+}
+win32-g++* {
+    LIBS += -Wl,--version-script=$$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.map
+}
+linux* {
+    LIBS += -Wl,--version-script=$$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.map -Wl,-no-undefined
+}
+macx* {
+    LIBS += -exported_symbols_list $$PWD/vamp-plugin-sdk/skeleton/vamp-plugin.list
+}
+
+QMAKE_POST_LINK += $$DEPLOYDIR/mark-for-signing out
+