annotate fvector.yeti @ 35:1f80673af4c7

Make concat take a list of arbitrary length; test it, and improve test output

module fvector;

import java.util: Arrays;

zeros n =
    new double[n];

ones n =
   (a = zeros n;
    for [0..n-1] do i:
        a[i] := 1.0;
    done;
    a);

vector l is list?<number> -> ~double[] =
   (arr = array(l);
    len = length arr;
    v = zeros len;
    for [0..len-1] do i:
        v[i] := arr[i];
    done;
    v);

list' a is ~double[] -> list<number> =
    list a;

length' =
    length . list';

equal v1 v2 =
    list' v1 == list' v2;

copyOf v is ~double[] -> ~double[] =
    Arrays#copyOf(v, list' v |> length);

rangeOf v start len is ~double[] -> number -> number -> ~double[] =
    Arrays#copyOfRange(v, start, start + len);

resizedTo n v is number -> ~double[] -> ~double[] =
    Arrays#copyOf(v, n);

concat vv is list?<~double[]> -> ~double[] =
   (len = sum (map length' vv);
    vout = zeros len;
    var base = 0;
    for vv do v: 
        vlen = length' v;
        for [0..vlen-1] do i: vout[base + i] := v[i] done;
        base := base + vlen;
    done;
    vout);

{
zeros, ones,
vector,
length = length',
list = list',
equal,
copyOf, rangeOf, resizedTo,
concat,
}