annotate base/methods.lisp @ 121:4198b52e612b

More docstrings

darcs-hash:20070727142154-f76cc-f59d4ad1216346f392d5b9f9e5b153a6f07a9bd9.gz

(cl:in-package #:amuse) 

;;; monody 

(defmethod ensure-monody ((m monody))
  (let ((result t))
    (dotimes (i (1- (length m)) result)
      ;; assumes the events are time ordered which (since monody is a
      ;; subclass of time-ordered-constituent) they ought to be. 
      (let ((e1 (elt m i))
            (e2 (elt m (1+ i))))
        (unless (or (before e1 e2) (meets e1 e2))
          (setf result nil))))))

;;; diatonic pitch (represented using MIPS)

(defmethod asa-pitch-string ((mp diatonic-pitch))
  (mips:p-pn (list (%p-pc mp) (%p-pm mp))))

(defmethod diatonic-pitch-octave ((mp diatonic-pitch))
  (let* ((asa-string (asa-pitch-string mp))
         (start (position-if #'digit-char-p asa-string)))
    (values (parse-integer asa-string :start start))))

(defmethod diatonic-pitch-accidental ((mp diatonic-pitch))
  (let* ((asa-string (asa-pitch-string mp))
         (start 1)
         (end (position-if #'digit-char-p asa-string))
         (malist '((#\n . 0) (#\s . +1) (#\f . -1)))
         (multiplier (cdr (assoc (char asa-string 1) malist)))) 
    (* multiplier (- end start))))

(defmethod diatonic-pitch-name ((mp diatonic-pitch))
  (elt (asa-pitch-string mp) 0))

(defmethod middle-c ((mp diatonic-pitch))
  (make-diatonic-pitch 39 23))

(defmethod midi-pitch-number ((mp diatonic-pitch))
  (+ (%p-pc mp) 21))

(defmethod octave ((mp diatonic-pitch))
  (1- (floor (midi-pitch-number mp) 12)))

(defmethod diatonic-pitch ((mp diatonic-pitch))
  mp)

(defmethod print-object ((o diatonic-pitch) stream)
  (print-unreadable-object (o stream :type t)
    (let ((asa-string (asa-pitch-string o)))
      (write asa-string :stream stream))))

(defmethod asa-interval-string ((mpi diatonic-pitch-interval))
  (mips:pi-pin (%diatonic-pitch-interval-span mpi)))

(defmethod print-object ((o diatonic-pitch-interval) stream)
  (print-unreadable-object (o stream :type t)
    (let ((asa-string (asa-interval-string o)))
      (write asa-string :stream stream))))

;;; Chromatic pitch 

(defmethod octave ((cp chromatic-pitch))
  (1- (floor (%chromatic-pitch-number cp) 12)))

(defmethod middle-c ((cp chromatic-pitch))
  (make-chromatic-pitch 60))

(defmethod chromatic-pitch ((pitch-designator chromatic-pitch))
  pitch-designator)

(defmethod midi-pitch-number ((pitch-designator chromatic-pitch))
  (%chromatic-pitch-number pitch-designator))

(defmethod midi-pitch-number ((pitch-designator pitch))
  (%chromatic-pitch-number (chromatic-pitch pitch-designator)))

(defmethod print-object ((o chromatic-pitch) stream)
  (print-unreadable-object (o stream :type t)
    (write (midi-pitch-number o) :stream stream)))

(defmethod print-object ((o chromatic-pitch-interval) stream)
  (print-unreadable-object (o stream :type t)
    (write (span o) :stream stream)))


(defmethod span ((pitch-interval-designator chromatic-pitch-interval))
  (%chromatic-pitch-interval-span pitch-interval-designator))

(defmethod duration ((period-designator period))
  (%period-interval period-designator))

(defmethod (setf duration) ((value real) (period-designator period))
  (setf (%period-interval period-designator) value))

(defmethod timepoint ((moment-designator moment))
  (%moment-time moment-designator))

(defmethod (setf timepoint) ((value real) (moment-designator moment))
  (setf (%moment-time moment-designator) value))

(defmethod cut-off ((anchored-period-designator anchored-period))
  (make-instance 'moment
		 :time (+ (%moment-time anchored-period-designator)
			  (%period-interval anchored-period-designator))))

(defmethod print-object ((o moment) stream)
  (print-unreadable-object (o stream :type t)
    (write (timepoint o) :stream stream)))

(defmethod print-object ((o period ) stream)
  (print-unreadable-object (o stream :type t)
    (write (duration o) :stream stream)))



(defmethod beat-units-per-bar ((time-signature basic-time-signature))
  (%basic-time-signature-numerator time-signature))

(defmethod beat-units ((time-signature basic-time-signature))
  (%basic-time-signature-denominator time-signature))

(defmethod time-signature-equal ((ts1 basic-time-signature) 
                                 (ts2 basic-time-signature))
  (let ((n1 (time-signature-numerator ts1))
        (n2 (time-signature-numerator ts2))
        (d1 (time-signature-denominator ts1))
        (d2 (time-signature-denominator ts2)))
    (and n1 n2 (= n1 n2) 
         d1 d2 (= d1 d2))))

(defmethod print-object ((bts basic-time-signature) stream)
  (print-unreadable-object (bts stream :type t)
    (format stream "~A/~A" (beat-units-per-bar bts) (beat-units bts))))

(defmethod key-signature-sharps ((key-signature basic-key-signature))
  (%basic-key-signature-sharp-count key-signature))

(defmethod key-signature-mode ((ks midi-key-signature))
  (%midi-key-signature-mode ks))

(defmethod print-object ((mks midi-key-signature) stream)
  (print-unreadable-object (mks stream :type t)
    (format stream "~A ~A"
            (%basic-key-signature-sharp-count mks)
            (%midi-key-signature-mode mks))))

(defmethod key-signature-equal ((ks1 basic-key-signature) 
                                (ks2 basic-key-signature))
  (let ((s1 (key-signature-sharps ks1))
        (s2 (key-signature-sharps ks2)))
    (and s1 s2 (= s1 s2))))

(defmethod key-signature-equal ((ks1 midi-key-signature) 
                                (ks2 midi-key-signature))
  (let ((s1 (key-signature-sharps ks1))
        (s2 (key-signature-sharps ks2))
        (m1 (key-signature-mode   ks1))
        (m2 (key-signature-mode   ks2)))
    (and s1 s2 (= s1 s2) 
         m1 m2 (= m1 m2))))

(defmethod bpm ((tempo tempo))
  (%tempo-bpm tempo))

(defmethod print-object ((tempo tempo) stream)
  (print-unreadable-object (tempo stream :type t)
    (write (bpm tempo) :stream stream)))

(defmethod tempo-equal ((t1 tempo) (t2 tempo))
  (and (bpm t1) (bpm t2) (= t1 t2)))
       

;; Time protocol

(defmethod time+ ((object1 moment) (object2 period))
  "Returns a <moment>. Implemented as a straightforward
summation."
  (make-moment (+ (timepoint object1) (duration object2))))

(defmethod time+ ((object1 period) (object2 moment)) ;?
  "Returns a <moment>. Implemented as a straightforward summation
and defined by default as (time+ <moment> <period>)."
  (time+ object2 object1))

(defmethod time+ ((object1 period) (object2 period))
  "Returns a <period>. Implemented as a straightforward
summation."
  (make-floating-period (+ (duration object1)
			   (duration object2))))

(defmethod time+ ((object1 moment) (object2 moment))
  "Returns <condition:undefined-action>. The question makes no
sense."
  (error 'undefined-action :operation 'time+ :datatype (list (class-of object1) (class-of object2))))

(defmethod time- ((object1 moment) (object2 moment))
  "Returns <anchored-period> with an onset at object2 and
  extending to object1"
  (make-anchored-period (timepoint object2)
			(- (timepoint object1)
			   (timepoint object2))))

(defmethod time- ((object1 moment) (object2 period))
  "Simple subtraction - Returns a <moment>"
  (make-moment (- (timepoint object1) (duration object2))))

(defmethod time- ((object1 period) (object2 moment)) ;?
  "Returns <condition:undefined-action>. The question makes no
sense"
  (error 'undefined-action
	 :operation 'time-
	 :datatype (list (class-of object1) (class-of object2))))

(defmethod time- ((object1 period) (object2 period))
  "Returns <floating-period> spanning the difference of the
periods"
  (make-floating-period (- (duration object2)
			   (duration object1))))

;; these ones are less certain. I've just put them in, but think I
;; should remove them and force the user to specify what they mean
;; when they give objects that are both moments *and* periods to these
;; functions.

(defmethod time- ((object1 anchored-period) (object2 anchored-period)) ;? 
  (time- (moment object1) (moment object2)))

(defmethod time- (object1 (object2 anchored-period)) ;?
  (time- object1 (moment object2)))

(defmethod time- ((object1 anchored-period) object2) ;?
  (time- (moment object1) object2))

(defmethod time> ((object1 moment) (object2 moment))
  (> (timepoint object1) (timepoint object2)))

(defmethod time< ((object1 moment) (object2 moment))
  (< (timepoint object1) (timepoint object2)))

(defmethod time= ((object1 moment) (object2 moment))
  (= (timepoint object1) (timepoint object2)))

(defmethod duration> ((object1 period) (object2 period))
  (> (duration object1) (duration object2)))

(defmethod duration= ((object1 period) (object2 period))
  (= (duration object1) (duration object2)))

(defmethod duration* ((object1 period) (object2 number))
  (make-floating-period (* (duration object1) object2)))

(defmethod duration* ((object1 number) (object2 period))
  (duration* object2 object1))

(defmethod duration/ ((object1 period) (object2 number))
  (make-floating-period (/ (duration object1) object2)))

;;;; Pitch protocol

;;; Some catch-all methods for undefined operations and cases where we
;;; don't have enough information:
(macrolet ((def (name class1 class2)
             `(defmethod ,name ((object1 ,class1) (object2 ,class2))
               (error 'undefined-action :operation ',name
                :datatype (list (class-of object1) (class-of object2))))))
  (def pitch+ pitch-designator pitch-designator)
  (def pitch- pitch-interval-designator pitch-designator))

(macrolet ((def (name class1 class2)
             `(defmethod ,name ((object1 ,class1) (object2 ,class2))
               (error 'insufficient-information :operation ',name
                :datatype (list (class-of object1) (class-of object2))))))
  (def pitch+ pitch-designator pitch-interval-designator)
  (def pitch+ pitch-interval-designator pitch-designator)
  (def pitch+ pitch-interval-designator pitch-interval-designator)
  (def pitch- pitch-designator pitch-designator)
  (def pitch- pitch-designator pitch-interval-designator)
  (def pitch- pitch-interval-designator pitch-interval-designator))

;;; chromatic pitch intervals

(defmethod pitch+ ((object1 chromatic-pitch)
		   (object2 chromatic-pitch-interval))
  (make-chromatic-pitch (+ (midi-pitch-number object1) (span object2))))

(defmethod pitch+  ((object1 chromatic-pitch-interval)
		    (object2 chromatic-pitch))
  (make-chromatic-pitch (+ (span object1) (midi-pitch-number object2))))

(defmethod pitch+ ((object1 chromatic-pitch-interval)
		   (object2 chromatic-pitch-interval))
  (make-chromatic-pitch-interval (+ (span object1) (span object2))))

(defmethod pitch- ((object1 chromatic-pitch) 
                   (object2 chromatic-pitch))
  (make-chromatic-pitch-interval
   (- (midi-pitch-number object1) (midi-pitch-number object2))))

(defmethod pitch- ((object1 chromatic-pitch)
                   (object2 chromatic-pitch-interval))
  (make-chromatic-pitch (- (midi-pitch-number object1) (span object2))))

(defmethod pitch- ((object1 chromatic-pitch-interval)
		   (object2 chromatic-pitch-interval))
  (make-chromatic-pitch-interval (- (span object1) (span object2))))

(defmethod pitch> ((object1 chromatic-pitch)
		   (object2 chromatic-pitch))
  (> (midi-pitch-number object1) (midi-pitch-number object2)))

(defmethod pitch= ((object1 chromatic-pitch)
		   (object2 chromatic-pitch))
  (= (midi-pitch-number object1) (midi-pitch-number object2)))

(defmethod interval> ((object1 chromatic-pitch-interval)
                      (object2 chromatic-pitch-interval))
  (> (span object1) (span object2)))

(defmethod interval= ((object1 chromatic-pitch-interval)
                      (object2 chromatic-pitch-interval))
  (= (span object1) (span object2)))

;;; diatonic pitch intervals

(defmethod pitch+ ((object1 diatonic-pitch) (object2 diatonic-pitch-interval))
  (let* ((cp (%p-pc object1))
         (mp (%p-pm object1))
         (span (span object2))
         (cps (first span))
         (mps (second span)))
    (make-mips-pitch (+ cp cps) (+ mp mps))))

(defmethod pitch+ ((object1 diatonic-pitch-interval) (object2 diatonic-pitch))
  (let* ((cp (%p-pc object2))
         (mp (%p-pm object2))
         (span (span object1))
         (cps (first span))
         (mps (second span)))
    (make-mips-pitch (+ cp cps) (+ mp mps))))

(defmethod pitch+ ((object1 diatonic-pitch-interval)
		   (object2 diatonic-pitch-interval))
  (let* ((span1 (span object1))
         (span2 (span object2)))
    (make-mips-pitch-interval (+ (first span1) (first span2))
                              (+ (second span1) (second span2)))))

(defmethod pitch- ((object1 diatonic-pitch) (object2 diatonic-pitch))
  (let ((cp1 (%p-pc object1))
        (mp1 (%p-pm object1))
        (cp2 (%p-pc object2))
        (mp2 (%p-pm object2)))
    (make-mips-pitch-interval (- cp1 cp2) (- mp1 mp2))))

(defmethod pitch- ((object1 diatonic-pitch) (object2 diatonic-pitch-interval))
  (let* ((cp (%p-pc object1))
         (mp (%p-pm object1))
         (span (span object2))
         (cps (first span))
         (mps (second span)))
    (make-mips-pitch (- cp cps) (- mp mps))))

(defmethod pitch- ((object1 diatonic-pitch-interval)
		   (object2 diatonic-pitch-interval))
  (let ((span1 (span object1))
        (span2 (span object2)))
    (make-mips-pitch-interval (- (first span1) (first span2))
                              (- (second span1) (second span2)))))

(defmethod pitch> ((p1 diatonic-pitch) (p2 diatonic-pitch))
  (error 'undefined-action :operation 'pitch>
         :datatype (list (class-of p1) (class-of p2))))

(defmethod pitch= ((p1 diatonic-pitch) (p2 diatonic-pitch))
  (let ((c1 (%p-pc p1)) (m1 (%p-pm p1))
        (c2 (%p-pc p2)) (m2 (%p-pm p2)))
    (and c1 c2 (= c1 c2)
         m1 m2 (= m1 m2))))


;; Allen

(defmethod meets ((object1 anchored-period)
		  (object2 anchored-period))
  (or (time= (cut-off object1) object2)
      (time= (cut-off object2) object1)))

(defmethod before ((object1 anchored-period)
		   (object2 anchored-period))
  (time> object2 (cut-off object1)))

(defmethod overlaps ((object1 anchored-period)
		     (object2 anchored-period))
  ;; FIXME: Is there a tidier method?
  (or (and (time> object2 object1) ; object1 starts before object2
	   (time> (cut-off object1) object2) ; object1 ends after object2 starts
	   (time> (cut-off object2) (cut-off object1))) ; object1 ends before object2 does
      (and (time> object1 object2) ; object1 starts after object2
	   (time> (cut-off object2) object1) ; object1 starts before object2 ends
	   (time> (cut-off object1) (cut-off object2))))) ; object1 ends after object2 does

(defmethod during ((object1 anchored-period)
		   (object2 anchored-period))
  (and (time> object1 object2)
       (time< (cut-off object2) (cut-off object2))))

(defmethod starts ((object1 anchored-period)
		   (object2 anchored-period))
  (time= object1 object2))

(defmethod ends ((object1 anchored-period)
		 (object2 anchored-period))
  (time= (cut-off object1) (cut-off object2)))

;; ...and

(defmethod period= ((object1 anchored-period)
                    (object2 anchored-period))
  (and (time= object1 object2)
       (duration= object1 object2)))
(defmethod period= ((object1 floating-period)
		    (object2 floating-period))
  (duration= object1 object2))

(defmethod period-intersection ((object1 anchored-period)
				(object2 anchored-period))
  (cond
    ((disjoint object1 object2)
     ;; if they don't overlap, return nil, not a negative-valued
     ;; period
     nil)
    ((let* ((start (if (time> (onset object2) (onset object1))
		       (onset object2)
		       (onset object1)))
	    (duration (duration (time- (if (time> (cut-off object2) (cut-off object1))
					   (cut-off object1)
					   (cut-off object2))
				       start))))
       (make-anchored-period (timepoint start) duration)))))