Mercurial > hg > vamp-plugin-pack

view ua-vamp-plugins.pro @ 111:fe176cd5280c

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Various updates to add Azi metadata + ensure it gets installed
author Chris Cannam
date Fri, 06 Mar 2020 10:47:39 +0000
parents 721eca4cf59b
children 732a4bf233df
line wrap: on
line source

TEMPLATE = lib

exists(config.pri) {
    include(config.pri)
}

!exists(config.pri) {
    include(noconfig.pri)
}

CONFIG -= qt
CONFIG += plugin no_plugin_name_prefix release warn_on

TARGET = out/ua-vamp-plugins

OBJECTS_DIR = ua-vamp-plugins/o

INCLUDEPATH += $$PWD/vamp-plugin-sdk $$PWD/ua-vamp-plugins/src

QMAKE_CXXFLAGS -= -Werror

win32-msvc* {
    LIBS += -EXPORT:vampGetPluginDescriptor
}
win32-g++* {
    LIBS += -Wl,--version-script=$$PWD/ua-vamp-plugins/vamp-plugin.map
}
linux* {
    LIBS += -Wl,--version-script=$$PWD/ua-vamp-plugins/vamp-plugin.map -Wl,-no-undefined
}
macx* {
    LIBS += -exported_symbols_list $$PWD/ua-vamp-plugins/vamp-plugin.list
}

QMAKE_POST_LINK += $$DEPLOYDIR/mark-for-signing out

!win* {
    QMAKE_POST_LINK += && \
        cp ua-vamp-plugins/ua-vamp-plugins.cat out/ && \
        cp ua-vamp-plugins/LICENSE out/ua-vamp-plugins_COPYING.txt && \
        cp ua-vamp-plugins/readme.md out/ua-vamp-plugins_README.md
}

SOURCES += \
    ua-vamp-plugins/onsetsUA.cpp \
    ua-vamp-plugins/mf0UA.cpp \
    ua-vamp-plugins/plugins.cpp \
    ua-vamp-plugins/src/myfft.cpp \
    ua-vamp-plugins/src/bands.cpp \
    ua-vamp-plugins/src/onsetdetection.cpp \
    ua-vamp-plugins/src/combination.cpp \
    ua-vamp-plugins/src/spectralpattern.cpp \
    ua-vamp-plugins/src/peaksatt.cpp \
    ua-vamp-plugins/src/graph.cpp \
    ua-vamp-plugins/src/mf0.cpp \
    vamp-plugin-sdk/src/vamp-sdk/FFT.cpp \
    vamp-plugin-sdk/src/vamp-sdk/PluginAdapter.cpp \
    vamp-plugin-sdk/src/vamp-sdk/RealTime.cpp