Mercurial > hg > tony

view tonyapp.pro @ 571:2cf4978eb724

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Fix failure of "Form Note from Selection" to work correctly when an existing note spanned one end of the selection but did not reach the other. Also update subrepos to fix a deadlock
author Chris Cannam
date Thu, 20 Jun 2019 11:10:59 +0100
parents 25aa28a27252
children f52766aa747b
line wrap: on
line source

TEMPLATE = app

exists(config.pri) {
    include(config.pri)
}

!exists(config.pri) {
    include(noconfig.pri)
}

include(base.pri)

QT += network xml gui widgets svg

TARGET = Tony
linux*:TARGET = tony
solaris*:TARGET = tony

OBJECTS_DIR = o
MOC_DIR = o

ICON = tony.icns
RC_FILE = icons/tony.rc

RESOURCES += tony.qrc

QMAKE_INFO_PLIST = deploy/osx/Info.plist

include(svgui/files.pri)
include(svapp/files.pri)

for (file, SVGUI_SOURCES)    { SOURCES += $$sprintf("svgui/%1",    $$file) }
for (file, SVAPP_SOURCES)    { SOURCES += $$sprintf("svapp/%1",    $$file) }

for (file, SVGUI_HEADERS)    { HEADERS += $$sprintf("svgui/%1",    $$file) }
for (file, SVAPP_HEADERS)    { HEADERS += $$sprintf("svapp/%1",    $$file) }

HEADERS += src/MainWindow.h \
           src/NetworkPermissionTester.h \
           src/Analyser.h

SOURCES += src/main.cpp \
           src/Analyser.cpp \
           src/NetworkPermissionTester.cpp \
           src/MainWindow.cpp