Mercurial > hg > tony

view tonyapp.pro @ 586:1dfdbd017cf5

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Suppress property boxes. They aren't visible anyway, but updates to their invisible state seems to be causing problems with certain Qt builds on Windows.
author Chris Cannam
date Wed, 04 Sep 2019 14:19:57 +0100
parents f52766aa747b
children 0eebba29d477 fe1a77d4aeaa
line wrap: on
line source

TEMPLATE = app

exists(config.pri) {
    include(config.pri)
}

!exists(config.pri) {
    include(noconfig.pri)
}

include(base.pri)

QT += network xml gui widgets svg

TARGET = Tony
linux*:TARGET = tony
solaris*:TARGET = tony

OBJECTS_DIR = o
MOC_DIR = o

ICON = tony.icns
RC_FILE = icons/tony.rc

RESOURCES += tony.qrc

QMAKE_INFO_PLIST = deploy/osx/Info.plist

include(svgui/files.pri)
include(svapp/files.pri)

for (file, SVGUI_SOURCES)    { SOURCES += $$sprintf("svgui/%1",    $$file) }
for (file, SVAPP_SOURCES)    { SOURCES += $$sprintf("svapp/%1",    $$file) }

for (file, SVGUI_HEADERS)    { HEADERS += $$sprintf("svgui/%1",    $$file) }
for (file, SVAPP_HEADERS)    { HEADERS += $$sprintf("svapp/%1",    $$file) }

HEADERS += main/MainWindow.h \
           main/NetworkPermissionTester.h \
           main/Analyser.h

SOURCES += main/main.cpp \
           main/Analyser.cpp \
           main/NetworkPermissionTester.cpp \
           main/MainWindow.cpp