view svcore.pro @ 1671:82d03c9661f9 single-point

Rework isReady()/getCompletion() on models. Previously the new overhauled models were implementing getCompletion() but inheriting a version of isReady() (from the Model base) that didn't call it, referring only to isOK(). So they were reporting completion as soon as they had begun. Instead hoist getCompletion() to abstract base and call it from Model::isReady().

TEMPLATE = lib

INCLUDEPATH += ../vamp-plugin-sdk

exists(config.pri) {
    include(config.pri)
}

CONFIG += staticlib qt thread warn_on stl rtti exceptions c++11
QT += network xml
QT -= gui

TARGET = svcore

DEPENDPATH += . data plugin plugin/api/alsa ../dataquay ../checker ../piper-cpp
INCLUDEPATH += . data plugin plugin/api/alsa ../dataquay ../checker ../piper-cpp
OBJECTS_DIR = o
MOC_DIR = o

# Doesn't work with this library, which contains C99 as well as C++
PRECOMPILED_HEADER =

# Set up suitable platform defines for RtMidi
linux*:   DEFINES += __LINUX_ALSASEQ__
macx*:    DEFINES += __MACOSX_CORE__
win*:     DEFINES += __WINDOWS_MM__
solaris*: DEFINES += __RTMIDI_DUMMY_ONLY__

include(files.pri)

HEADERS = $$SVCORE_HEADERS
SOURCES = $$SVCORE_SOURCES