cannam@89: #!/usr/bin/perl
cannam@89: 
cannam@89: # Transform K&R C function definitions into ANSI equivalent.
cannam@89: #
cannam@89: # Author: Paul Marquess
cannam@89: # Version: 1.0
cannam@89: # Date: 3 October 2006
cannam@89: 
cannam@89: # TODO
cannam@89: #
cannam@89: # Asumes no function pointer parameters. unless they are typedefed.
cannam@89: # Assumes no literal strings that look like function definitions
cannam@89: # Assumes functions start at the beginning of a line
cannam@89: 
cannam@89: use strict;
cannam@89: use warnings;
cannam@89: 
cannam@89: local $/;
cannam@89: $_ = <>;
cannam@89: 
cannam@89: my $sp = qr{ \s* (?: /\* .*? \*/ )? \s* }x; # assume no nested comments
cannam@89: 
cannam@89: my $d1    = qr{ $sp (?: [\w\*\s]+ $sp)* $sp \w+ $sp [\[\]\s]* $sp }x ;
cannam@89: my $decl  = qr{ $sp (?: \w+ $sp )+ $d1 }xo ;
cannam@89: my $dList = qr{ $sp $decl (?: $sp , $d1 )* $sp ; $sp }xo ;
cannam@89: 
cannam@89: 
cannam@89: while (s/^
cannam@89:             (                  # Start $1
cannam@89:                 (              #   Start $2
cannam@89:                     .*?        #     Minimal eat content
cannam@89:                     ( ^ \w [\w\s\*]+ )    #     $3 -- function name
cannam@89:                     \s*        #     optional whitespace
cannam@89:                 )              # $2 - Matched up to before parameter list
cannam@89: 
cannam@89:                 \( \s*         # Literal "(" + optional whitespace
cannam@89:                 ( [^\)]+ )     # $4 - one or more anythings except ")"
cannam@89:                 \s* \)         # optional whitespace surrounding a Literal ")"
cannam@89: 
cannam@89:                 ( (?: $dList )+ ) # $5
cannam@89: 
cannam@89:                 $sp ^ {        # literal "{" at start of line
cannam@89:             )                  # Remember to $1
cannam@89:         //xsom
cannam@89:       )
cannam@89: {
cannam@89:     my $all = $1 ;
cannam@89:     my $prefix = $2;
cannam@89:     my $param_list = $4 ;
cannam@89:     my $params = $5;
cannam@89: 
cannam@89:     StripComments($params);
cannam@89:     StripComments($param_list);
cannam@89:     $param_list =~ s/^\s+//;
cannam@89:     $param_list =~ s/\s+$//;
cannam@89: 
cannam@89:     my $i = 0 ;
cannam@89:     my %pList = map { $_ => $i++ }
cannam@89:                 split /\s*,\s*/, $param_list;
cannam@89:     my $pMatch = '(\b' . join('|', keys %pList) . '\b)\W*$' ;
cannam@89: 
cannam@89:     my @params = split /\s*;\s*/, $params;
cannam@89:     my @outParams = ();
cannam@89:     foreach my $p (@params)
cannam@89:     {
cannam@89:         if ($p =~ /,/)
cannam@89:         {
cannam@89:             my @bits = split /\s*,\s*/, $p;
cannam@89:             my $first = shift @bits;
cannam@89:             $first =~ s/^\s*//;
cannam@89:             push @outParams, $first;
cannam@89:             $first =~ /^(\w+\s*)/;
cannam@89:             my $type = $1 ;
cannam@89:             push @outParams, map { $type . $_ } @bits;
cannam@89:         }
cannam@89:         else
cannam@89:         {
cannam@89:             $p =~ s/^\s+//;
cannam@89:             push @outParams, $p;
cannam@89:         }
cannam@89:     }
cannam@89: 
cannam@89: 
cannam@89:     my %tmp = map { /$pMatch/;  $_ => $pList{$1}  }
cannam@89:               @outParams ;
cannam@89: 
cannam@89:     @outParams = map  { "    $_" }
cannam@89:                  sort { $tmp{$a} <=> $tmp{$b} }
cannam@89:                  @outParams ;
cannam@89: 
cannam@89:     print $prefix ;
cannam@89:     print "(\n" . join(",\n", @outParams) . ")\n";
cannam@89:     print "{" ;
cannam@89: 
cannam@89: }
cannam@89: 
cannam@89: # Output any trailing code.
cannam@89: print ;
cannam@89: exit 0;
cannam@89: 
cannam@89: 
cannam@89: sub StripComments
cannam@89: {
cannam@89: 
cannam@89:   no warnings;
cannam@89: 
cannam@89:   # Strip C & C++ coments
cannam@89:   # From the perlfaq
cannam@89:   $_[0] =~
cannam@89: 
cannam@89:     s{
cannam@89:        /\*         ##  Start of /* ... */ comment
cannam@89:        [^*]*\*+    ##  Non-* followed by 1-or-more *'s
cannam@89:        (
cannam@89:          [^/*][^*]*\*+
cannam@89:        )*          ##  0-or-more things which don't start with /
cannam@89:                    ##    but do end with '*'
cannam@89:        /           ##  End of /* ... */ comment
cannam@89: 
cannam@89:      |         ##     OR  C++ Comment
cannam@89:        //          ## Start of C++ comment //
cannam@89:        [^\n]*      ## followed by 0-or-more non end of line characters
cannam@89: 
cannam@89:      |         ##     OR  various things which aren't comments:
cannam@89: 
cannam@89:        (
cannam@89:          "           ##  Start of " ... " string
cannam@89:          (
cannam@89:            \\.           ##  Escaped char
cannam@89:          |               ##    OR
cannam@89:            [^"\\]        ##  Non "\
cannam@89:          )*
cannam@89:          "           ##  End of " ... " string
cannam@89: 
cannam@89:        |         ##     OR
cannam@89: 
cannam@89:          '           ##  Start of ' ... ' string
cannam@89:          (
cannam@89:            \\.           ##  Escaped char
cannam@89:          |               ##    OR
cannam@89:            [^'\\]        ##  Non '\
cannam@89:          )*
cannam@89:          '           ##  End of ' ... ' string
cannam@89: 
cannam@89:        |         ##     OR
cannam@89: 
cannam@89:          .           ##  Anything other char
cannam@89:          [^/"'\\]*   ##  Chars which doesn't start a comment, string or escape
cannam@89:        )
cannam@89:      }{$2}gxs;
cannam@89: 
cannam@89: }