cannam@85: # Copyright (C) 1999-2011 Erik de Castro Lopo (erikd AT mega-nerd DOT com).
cannam@85: 
cannam@85: dnl Require autoconf version
cannam@85: AC_PREREQ(2.57)
cannam@85: 
cannam@85: AC_INIT([libsndfile],[1.0.25],[sndfile@mega-nerd.com],
cannam@85: 		[libsndfile],[http://www.mega-nerd.com/libsndfile/])
cannam@85: 
cannam@85: # Put config stuff in Cfg.
cannam@85: AC_CONFIG_AUX_DIR(Cfg)
cannam@85: 
cannam@85: AC_CONFIG_SRCDIR([src/sndfile.c])
cannam@85: AC_CANONICAL_TARGET([])
cannam@85: 
cannam@85: AC_CONFIG_MACRO_DIR([M4])
cannam@85: AC_CONFIG_HEADERS([src/config.h])
cannam@85: 
cannam@85: AM_INIT_AUTOMAKE($PACKAGE_NAME,$PACKAGE_VERSION)
cannam@85: AM_SILENT_RULES([yes])
cannam@85: 
cannam@85: dnl Add parameters for aclocal
cannam@85: AC_SUBST(ACLOCAL_AMFLAGS, "-I M4")
cannam@85: 
cannam@85: AC_LANG([C])
cannam@85: 
cannam@85: AC_PROG_CC
cannam@85: AM_PROG_CC_C_O
cannam@85: AC_PROG_CXX
cannam@85: AC_PROG_SED
cannam@85: 
cannam@85: # Do not check for F77.
cannam@85: define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
cannam@85: 
cannam@85: AM_PROG_LIBTOOL
cannam@85: LT_PROG_RC
cannam@85: 
cannam@85: AC_CHECK_PROG(HAVE_AUTOGEN, autogen, yes, no)
cannam@85: AC_CHECK_PROG(HAVE_WINE, wine, yes, no)
cannam@85: 
cannam@85: AC_PROG_INSTALL
cannam@85: AC_PROG_LN_S
cannam@85: 
cannam@85: #------------------------------------------------------------------------------------
cannam@85: # Rules for library version information:
cannam@85: #
cannam@85: #  1. Start with version information of `0:0:0' for each libtool library.
cannam@85: #  2. Update the version information only immediately before a public release of
cannam@85: #     your software. More frequent updates are unnecessary, and only guarantee
cannam@85: #     that the current interface number gets larger faster.
cannam@85: #  3. If the library source code has changed at all since the last update, then
cannam@85: #     increment revision (`c:r:a' becomes `c:r+1:a').
cannam@85: #  4. If any interfaces have been added, removed, or changed since the last update,
cannam@85: #     increment current, and set revision to 0.
cannam@85: #  5. If any interfaces have been added since the last public release, then increment
cannam@85: #     age.
cannam@85: #  6. If any interfaces have been removed since the last public release, then set age
cannam@85: #     to 0.
cannam@85: 
cannam@85: CLEAN_VERSION=`echo $PACKAGE_VERSION | $SED "s/p.*//"`
cannam@85: VERSION_MINOR=`echo $CLEAN_VERSION | $SED "s/.*\.//"`
cannam@85: 
cannam@85: SHARED_VERSION_INFO="1:$VERSION_MINOR:0"
cannam@85: 
cannam@85: #------------------------------------------------------------------------------------
cannam@85: 
cannam@85: AC_HEADER_STDC
cannam@85: 
cannam@85: AC_CHECK_HEADERS(endian.h)
cannam@85: AC_CHECK_HEADERS(byteswap.h)
cannam@85: AC_CHECK_HEADERS(locale.h)
cannam@85: AC_CHECK_HEADERS(sys/time.h)
cannam@85: 
cannam@85: AC_HEADER_SYS_WAIT
cannam@85: 
cannam@85: AC_CHECK_DECLS(S_IRGRP)
cannam@85: if test x$ac_cv_have_decl_S_IRGRP = xyes ; then
cannam@85: 	AC_DEFINE_UNQUOTED([HAVE_DECL_S_IRGRP],1,[Set to 1 if S_IRGRP is defined.])
cannam@85: else
cannam@85: 	AC_DEFINE_UNQUOTED([HAVE_DECL_S_IRGRP],0)
cannam@85: 	fi
cannam@85: 
cannam@85: AM_CONDITIONAL([LINUX_MINGW_CROSS_TEST],
cannam@85: 	[test "$build_os:$target_os:$host_os:$HAVE_WINE" = "linux-gnu:mingw32msvc:mingw32msvc:yes"])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for support of the struct hack.
cannam@85: 
cannam@85: MN_C99_FLEXIBLE_ARRAY
cannam@85: 
cannam@85: if test x$ac_cv_c99_flexible_array = xyes ; then
cannam@85: 	AC_DEFINE([HAVE_FLEXIBLE_ARRAY],1, [Set to 1 if the compile supports the struct hack.])
cannam@85: else
cannam@85: 	AC_MSG_WARN([[*** This compiler does not support the 1999 ISO C Standard ***]])
cannam@85: 	AC_MSG_WARN([[*** feature known as the flexible array struct member.     ***]])
cannam@85: 	AC_DEFINE([HAVE_FLEXIBLE_ARRAY],0)
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Couple of initializations here. Fill in real values later.
cannam@85: 
cannam@85: SHLIB_VERSION_ARG=""
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Finished checking, handle options.
cannam@85: 
cannam@85: AC_ARG_ENABLE(experimental,
cannam@85: 	AC_HELP_STRING([--enable-experimental], [enable experimental code]))
cannam@85: 
cannam@85: EXPERIMENTAL_CODE=0
cannam@85: if test x$enable_experimental = xyes ; then
cannam@85: 	EXPERIMENTAL_CODE=1
cannam@85: 	fi
cannam@85: AC_DEFINE_UNQUOTED([ENABLE_EXPERIMENTAL_CODE],${EXPERIMENTAL_CODE}, [Set to 1 to enable experimental code.])
cannam@85: 
cannam@85: AC_ARG_ENABLE(gcc-werror,
cannam@85: 	AC_HELP_STRING([--enable-gcc-werror], [enable -Werror in all Makefiles]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(gcc-pipe,
cannam@85: 	AC_HELP_STRING([--disable-gcc-pipe], [disable gcc -pipe option]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(gcc-opt,
cannam@85: 	AC_HELP_STRING([--disable-gcc-opt], [disable gcc optimisations]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(cpu-clip,
cannam@85: 	AC_HELP_STRING([--disable-cpu-clip], [disable tricky cpu specific clipper]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(bow-docs,
cannam@85: 	AC_HELP_STRING([--enable-bow-docs], [enable black-on-white html docs]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(sqlite,
cannam@85: 	AC_HELP_STRING([--disable-sqlite], [disable use of sqlite]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(alsa,
cannam@85: 	AC_HELP_STRING([--disable-alsa], [disable use of ALSA]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(external-libs,
cannam@85: 	AC_HELP_STRING([--disable-external-libs], [disable use of FLAC, Ogg and Vorbis [[default=no]]]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(octave,
cannam@85: 	AC_HELP_STRING([--enable-octave], [disable building of GNU Octave module]))
cannam@85: 
cannam@85: AC_ARG_ENABLE(test-coverage,
cannam@85: 	AC_HELP_STRING([--enable-test-coverage], [enable test coverage]))
cannam@85: AM_CONDITIONAL([ENABLE_TEST_COVERAGE], [test "$enable_test_coverage" = yes])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check types and their sizes.
cannam@85: 
cannam@85: AC_CHECK_SIZEOF(wchar_t,4)
cannam@85: AC_CHECK_SIZEOF(short,2)
cannam@85: AC_CHECK_SIZEOF(int,4)
cannam@85: AC_CHECK_SIZEOF(long,4)
cannam@85: AC_CHECK_SIZEOF(float,4)
cannam@85: AC_CHECK_SIZEOF(double,4)
cannam@85: AC_CHECK_SIZEOF(void*,8)
cannam@85: AC_CHECK_SIZEOF(size_t,4)
cannam@85: AC_CHECK_SIZEOF(int64_t,8)
cannam@85: AC_CHECK_SIZEOF(long long,8)
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Find an appropriate type for sf_count_t.
cannam@85: # On systems supporting files larger than 2 Gig, sf_count_t must be a 64 bit value.
cannam@85: # Unfortunately there is more than one way of ensuring this so need to do some
cannam@85: # pretty rigourous testing here.
cannam@85: 
cannam@85: unset ac_cv_sizeof_off_t
cannam@85: 
cannam@85: AC_CHECK_SIZEOF(off_t,1)	# Fake default value.
cannam@85: 
cannam@85: case "$host_os" in
cannam@85: 	mingw32msvc | mingw32)
cannam@85: 		TYPEOF_SF_COUNT_T="__int64"
cannam@85: 		SF_COUNT_MAX="0x7FFFFFFFFFFFFFFFLL"
cannam@85: 		SIZEOF_SF_COUNT_T=8
cannam@85: 		AC_DEFINE([__USE_MINGW_ANSI_STDIO],1,[Set to 1 to use C99 printf/snprintf in MinGW.])
cannam@85: 		;;
cannam@85: 	*)
cannam@85: 		if test "x$ac_cv_sizeof_off_t" = "x8" ; then
cannam@85: 			# If sizeof (off_t) is 8, no further checking is needed.
cannam@85: 			TYPEOF_SF_COUNT_T="int64_t"
cannam@85: 			SF_COUNT_MAX="0x7FFFFFFFFFFFFFFFLL"
cannam@85: 			SIZEOF_SF_COUNT_T=8
cannam@85: 		else
cannam@85: 			# Check for common 64 bit file offset types.
cannam@85: 			AC_CHECK_SIZEOF(loff_t,1)	# Fake default value.
cannam@85: 			AC_CHECK_SIZEOF(off64_t,1)	# Fake default value.
cannam@85: 
cannam@85: 			TYPEOF_SF_COUNT_T="unknown"
cannam@85: 			if test "x$ac_cv_sizeof_loff_t" = "x8" ; then
cannam@85: 				TYPEOF_SF_COUNT_T="int64_t"
cannam@85: 				SIZEOF_SF_COUNT_T=8
cannam@85: 			elif test "x$ac_cv_sizeof_off64_t" = "x8" ; then
cannam@85: 				TYPEOF_SF_COUNT_T="int64_t"
cannam@85: 				SIZEOF_SF_COUNT_T=8
cannam@85: 				fi
cannam@85: 
cannam@85: 			# Save the old sizeof (off_t) value  and then unset it to see if it
cannam@85: 			# changes when Large File Support is enabled.
cannam@85: 
cannam@85: 			pre_largefile_sizeof_off_t=$ac_cv_sizeof_off_t
cannam@85: 			unset ac_cv_sizeof_off_t
cannam@85: 
cannam@85: 			AC_SYS_EXTRA_LARGEFILE
cannam@85: 
cannam@85: 			if test "x$ac_cv_sys_largefile_CFLAGS" = "xno" ; then
cannam@85: 				ac_cv_sys_largefile_CFLAGS=""
cannam@85: 				fi
cannam@85: 			if test "x$ac_cv_sys_largefile_LDFLAGS" = "xno" ; then
cannam@85: 				ac_cv_sys_largefile_LDFLAGS=""
cannam@85: 				fi
cannam@85: 			if test "x$ac_cv_sys_largefile_LIBS" = "xno" ; then
cannam@85: 				ac_cv_sys_largefile_LIBS=""
cannam@85: 				fi
cannam@85: 
cannam@85: 			AC_CHECK_SIZEOF(off_t,1)	# Fake default value.
cannam@85: 
cannam@85: 			if test "x$ac_cv_sizeof_off_t" = "x8" ; then
cannam@85: 				TYPEOF_SF_COUNT_T="int64_t"
cannam@85: 				SF_COUNT_MAX="0x7FFFFFFFFFFFFFFFLL"
cannam@85: 			elif test "x$ac_cv_sizeof_off_t" = "x$pre_largefile_sizeof_off_t" ; then
cannam@85: 				AC_MSG_WARN([[This machine does not seem to support 64 bit file offsets.]])
cannam@85: 				TYPEOF_SF_COUNT_T="off_t"
cannam@85: 				SIZEOF_SF_COUNT_T=$ac_cv_sizeof_off_t
cannam@85: 			elif test "x$TYPEOF_SF_COUNT_T" = "xunknown" ; then
cannam@85: 				echo
cannam@85: 				echo "*** The configure process has determined that this system is capable"
cannam@85: 				echo "*** of Large File Support but has not been able to find a type which"
cannam@85: 				echo "*** is an unambiguous 64 bit file offset."
cannam@85: 				echo "*** Please contact the author to help resolve this problem."
cannam@85: 				echo
cannam@85: 				AC_MSG_ERROR([[Bad file offset type.]])
cannam@85: 				fi
cannam@85: 			fi
cannam@85: 		;;
cannam@85: 	esac
cannam@85: 
cannam@85: if test $SIZEOF_SF_COUNT_T = 4 ; then
cannam@85: 	SF_COUNT_MAX="0x7FFFFFFF"
cannam@85: 	fi
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([TYPEOF_SF_COUNT_T],${TYPEOF_SF_COUNT_T}, [Set to long if unknown.])
cannam@85: AC_SUBST(TYPEOF_SF_COUNT_T)
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([SIZEOF_SF_COUNT_T],${SIZEOF_SF_COUNT_T}, [Set to sizeof (long) if unknown.])
cannam@85: AC_SUBST(SIZEOF_SF_COUNT_T)
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([SF_COUNT_MAX],${SF_COUNT_MAX}, [Set to maximum allowed value of sf_count_t type.])
cannam@85: AC_SUBST(SF_COUNT_MAX)
cannam@85: 
cannam@85: AC_CHECK_TYPES(ssize_t)
cannam@85: AC_CHECK_SIZEOF(ssize_t,4)
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Determine endian-ness of target processor.
cannam@85: 
cannam@85: MN_C_FIND_ENDIAN
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED(CPU_IS_BIG_ENDIAN, ${ac_cv_c_big_endian},
cannam@85: 	[Target processor is big endian.])
cannam@85: AC_DEFINE_UNQUOTED(CPU_IS_LITTLE_ENDIAN, ${ac_cv_c_little_endian},
cannam@85: 	[Target processor is little endian.])
cannam@85: AC_DEFINE_UNQUOTED(WORDS_BIGENDIAN, ${ac_cv_c_big_endian},
cannam@85: 	[Target processor is big endian.])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for functions.
cannam@85: 
cannam@85: AC_CHECK_FUNCS(malloc calloc realloc free)
cannam@85: AC_CHECK_FUNCS(open read write lseek pread pwrite)
cannam@85: AC_CHECK_FUNCS(fstat ftruncate fsync)
cannam@85: AC_CHECK_FUNCS(snprintf vsnprintf)
cannam@85: AC_CHECK_FUNCS(gmtime gmtime_r localtime localtime_r gettimeofday)
cannam@85: AC_CHECK_FUNCS(mmap getpagesize)
cannam@85: AC_CHECK_FUNCS(setlocale)
cannam@85: AC_CHECK_FUNCS(pipe waitpid)
cannam@85: 
cannam@85: AC_CHECK_LIB([m],floor)
cannam@85: AC_CHECK_FUNCS(floor ceil fmod)
cannam@85: 
cannam@85: MN_C99_FUNC_LRINT
cannam@85: MN_C99_FUNC_LRINTF
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for requirements for building plugins for other languages/enviroments.
cannam@85: 
cannam@85: dnl Octave maths environment http://www.octave.org/
cannam@85: if test x$cross_compiling = xno ; then
cannam@85: 	if test x$enable_octave = xno ; then
cannam@85: 		AM_CONDITIONAL(BUILD_OCTAVE_MOD, false)
cannam@85: 	else
cannam@85: 		AC_OCTAVE_BUILD
cannam@85: 		fi
cannam@85: else
cannam@85: 	AM_CONDITIONAL(BUILD_OCTAVE_MOD, false)
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for Ogg, Vorbis and FLAC.
cannam@85: 
cannam@85: HAVE_EXTERNAL_LIBS=0
cannam@85: EXTERNAL_CFLAGS=""
cannam@85: EXTERNAL_LIBS=""
cannam@85: 
cannam@85: # Check for pkg-config outside the if statement.
cannam@85: PKG_PROG_PKG_CONFIG
cannam@85: 
cannam@85: if test -n "$PKG_CONFIG" ; then
cannam@85: 	if test x$enable_external_libs = xno ; then
cannam@85: 		AC_MSG_WARN([[*** External libs (FLAC, Ogg, Vorbis) disabled. ***]])
cannam@85: 	else
cannam@85: 		PKG_CHECK_MOD_VERSION(FLAC, flac >= 1.2.1, ac_cv_flac=yes, ac_cv_flac=no)
cannam@85: 
cannam@85: 		# Make sure the FLAC_CFLAGS value is sane.
cannam@85: 		FLAC_CFLAGS=`echo $FLAC_CLFAGS | $SED "s/FLAC$//"`
cannam@85: 
cannam@85: 		PKG_CHECK_MOD_VERSION(OGG, ogg >= 1.1.3, ac_cv_ogg=yes, ac_cv_ogg=no)
cannam@85: 
cannam@85: 		if test x$enable_experimental = xyes ; then
cannam@85: 			PKG_CHECK_MOD_VERSION(SPEEX, speex >= 1.2, ac_cv_speex=yes, ac_cv_speex=no)
cannam@85: 		else
cannam@85: 			SPEEX_CFLAGS=""
cannam@85: 			SPEEX_LIBS=""
cannam@85: 			fi
cannam@85: 
cannam@85: 		# Vorbis versions earlier than 1.2.3 have bugs that cause the libsndfile
cannam@85: 		# test suite to fail on MIPS, PowerPC and others.
cannam@85: 		# See: http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=549899
cannam@85: 		PKG_CHECK_MOD_VERSION(VORBIS, vorbis >= 1.2.3, ac_cv_vorbis=yes, ac_cv_vorbis=no)
cannam@85: 		PKG_CHECK_MOD_VERSION(VORBISENC, vorbisenc >= 1.2.3, ac_cv_vorbisenc=yes, ac_cv_vorbisenc=no)
cannam@85: 		enable_external_libs=yes
cannam@85: 		fi
cannam@85: 
cannam@85: 	if test x$ac_cv_flac$ac_cv_ogg$ac_cv_vorbis$ac_cv_vorbisenc = "xyesyesyesyes" ; then
cannam@85: 		HAVE_EXTERNAL_LIBS=1
cannam@85: 		enable_external_libs=yes
cannam@85: 
cannam@85: 		EXTERNAL_CFLAGS="$FLAC_CFLAGS $OGG_CFLAGS $VORBISENC_CFLAGS $SPEEX_CFLAGS"
cannam@85: 		EXTERNAL_LIBS="$FLAC_LIBS $VORBISENC_LIBS $SPEEX_LIBS"
cannam@85: 	else
cannam@85: 		echo
cannam@85: 		AC_MSG_WARN([[*** One or more of the external libraries (ie libflac, libogg and]])
cannam@85: 		AC_MSG_WARN([[*** libvorbis) is either missing (possibly only the development]])
cannam@85: 		AC_MSG_WARN([[*** headers) or is of an unsupported version.]])
cannam@85: 		AC_MSG_WARN([[***]])
cannam@85: 		AC_MSG_WARN([[*** Unfortunately, for ease of maintenance, the external libs]])
cannam@85: 		AC_MSG_WARN([[*** are an all or nothing affair.]])
cannam@85: 		echo
cannam@85: 		enable_external_libs=no
cannam@85: 		fi
cannam@85: 	fi
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([HAVE_EXTERNAL_LIBS], $HAVE_EXTERNAL_LIBS, [Will be set to 1 if flac, ogg and vorbis are available.])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for libsqlite3 (only used in regtest).
cannam@85: 
cannam@85: ac_cv_sqlite3=no
cannam@85: if test x$enable_sqlite != xno ; then
cannam@85: 	PKG_CHECK_MOD_VERSION(SQLITE3, sqlite3 >= 3.2, ac_cv_sqlite3=yes, ac_cv_sqlite3=no)
cannam@85: 	fi
cannam@85: 
cannam@85: if test x$ac_cv_sqlite3 = "xyes" ; then
cannam@85: 	HAVE_SQLITE3=1
cannam@85: else
cannam@85: 	HAVE_SQLITE3=0
cannam@85: 	fi
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([HAVE_SQLITE3],$HAVE_SQLITE3,[Set to 1 if you have libsqlite3.])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Determine if the processor can do clipping on float to int conversions.
cannam@85: 
cannam@85: if test x$enable_cpu_clip != "xno" ; then
cannam@85: 	MN_C_CLIP_MODE
cannam@85: else
cannam@85: 	echo "checking processor clipping capabilities... disabled"
cannam@85: 	ac_cv_c_clip_positive=0
cannam@85: 	ac_cv_c_clip_negative=0
cannam@85: 	fi
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED(CPU_CLIPS_POSITIVE, ${ac_cv_c_clip_positive},
cannam@85: 	[Target processor clips on positive float to int conversion.])
cannam@85: AC_DEFINE_UNQUOTED(CPU_CLIPS_NEGATIVE, ${ac_cv_c_clip_negative},
cannam@85: 	[Target processor clips on negative float to int conversion.])
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Target OS specific stuff.
cannam@85: 
cannam@85: OS_SPECIFIC_CFLAGS=""
cannam@85: OS_SPECIFIC_LINKS=""
cannam@85: os_is_win32=0
cannam@85: os_is_macosx=0
cannam@85: use_windows_api=0
cannam@85: 
cannam@85: case "$host_os" in
cannam@85: 	darwin* | rhapsody*)
cannam@85: 		os_is_macosx=1
cannam@85: 		OS_SPECIFIC_CFLAGS="-I/Developer/Headers/FlatCarbon"
cannam@85: 		OS_SPECIFIC_LINKS="-framework CoreAudio"
cannam@85: 		;;
cannam@85: 	mingw*)
cannam@85: 		os_is_win32=1
cannam@85: 		use_windows_api=1
cannam@85: 		OS_SPECIFIC_LINKS="-lwinmm"
cannam@85: 		;;
cannam@85: 	esac
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED(OS_IS_WIN32, ${os_is_win32}, [Set to 1 if compiling for Win32])
cannam@85: AC_DEFINE_UNQUOTED(OS_IS_MACOSX, ${os_is_macosx}, [Set to 1 if compiling for MacOSX])
cannam@85: AC_DEFINE_UNQUOTED(USE_WINDOWS_API, ${use_windows_api}, [Set to 1 to use the native windows API])
cannam@85: 
cannam@85: AM_CONDITIONAL(USE_WIN_VERSION_FILE, test ${use_windows_api} -eq 1)
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for ALSA.
cannam@85: 
cannam@85: ALSA_LIBS=""
cannam@85: 
cannam@85: if test x$enable_alsa != xno ; then
cannam@85: 	AC_CHECK_HEADERS(alsa/asoundlib.h)
cannam@85: 	if test x$ac_cv_header_alsa_asoundlib_h = xyes ; then
cannam@85: 		ALSA_LIBS="-lasound"
cannam@85: 		enable_alsa=yes
cannam@85: 		fi
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Check for OpenBSD's sndio.
cannam@85: 
cannam@85: SNDIO_LIBS=""
cannam@85: AC_CHECK_HEADERS(sndio.h)
cannam@85: if test x$ac_cv_header_sndio_h = xyes ; then
cannam@85: 	SNDIO_LIBS="-lsndio"
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Test for sanity when cross-compiling.
cannam@85: 
cannam@85: if test x$cross_compiling = xyes ; then
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	AC_MSG_WARN([[*** We are cross-compiling, so have to assume sizeof (short) == 2 ]])
cannam@85: 	AC_MSG_WARN([[*** and sizeof (int) == 4. If this is not the case there is no    ]])
cannam@85: 	AC_MSG_WARN([[*** chance of this working. Please contact the mantainer.         ]])
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	fi
cannam@85: 
cannam@85: if test $ac_cv_sizeof_short != 2 ; then
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	AC_MSG_WARN([[*** sizeof (short) != 2.                                          ]])
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	fi
cannam@85: 
cannam@85: if test $ac_cv_sizeof_int != 4 ; then
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	AC_MSG_WARN([[*** sizeof (int) != 4                                             ]])
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	fi
cannam@85: 
cannam@85: if test $ac_cv_sizeof_float != 4 ; then
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	AC_MSG_WARN([[*** sizeof (float) != 4.                                          ]])
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	fi
cannam@85: 
cannam@85: if test $ac_cv_sizeof_double != 8 ; then
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	AC_MSG_WARN([[*** sizeof (double) != 8.                                         ]])
cannam@85: 	AC_MSG_WARN([[******************************************************************]])
cannam@85: 	fi
cannam@85: 
cannam@85: if test x"$ac_cv_prog_HAVE_AUTOGEN" = "xno" ; then
cannam@85: 	AC_MSG_WARN([[Touching files in directory tests/.]])
cannam@85: 	touch tests/*.c tests/*.h
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Settings for the HTML documentation.
cannam@85: 
cannam@85: htmldocdir=$prefix/share/doc/libsndfile1-dev/html
cannam@85: 
cannam@85: if test $prefix = "NONE" ; then
cannam@85: 	htmldocdir=/usr/local/share/doc/libsndfile1-dev/html
cannam@85: else
cannam@85: 	htmldocdir=$prefix/share/doc/libsndfile1-dev/html
cannam@85: 	fi
cannam@85: 
cannam@85: if test x$enable_bow_docs = "xyes" ; then
cannam@85: 	HTML_BGCOLOUR="white"
cannam@85: 	HTML_FGCOLOUR="black"
cannam@85: else
cannam@85: 	HTML_BGCOLOUR="black"
cannam@85: 	HTML_FGCOLOUR="white"
cannam@85: 	fi
cannam@85: 
cannam@85: #====================================================================================
cannam@85: # Now use the information from the checking stage.
cannam@85: 
cannam@85: win32_target_dll=0
cannam@85: COMPILER_IS_GCC=0
cannam@85: 
cannam@85: if test x$ac_cv_c_compiler_gnu = xyes ; then
cannam@85: 	MN_ADD_CFLAGS(-std=gnu99)
cannam@85: 
cannam@85: 	MN_GCC_VERSION
cannam@85: 
cannam@85: 	if test "x$GCC_MAJOR_VERSION$GCC_MINOR_VERSION" = "x42" ; then
cannam@85: 		AC_MSG_WARN([****************************************************************])
cannam@85: 		AC_MSG_WARN([** GCC version 4.2 warns about the inline keyword for no good **])
cannam@85: 		AC_MSG_WARN([** reason but the maintainers do not see it as a bug.         **])
cannam@85: 		AC_MSG_WARN([** See http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33995      **])
cannam@85: 		AC_MSG_WARN([** Using -fgnu-inline to avoid this stupidity.                **])
cannam@85: 		AC_MSG_WARN([****************************************************************])
cannam@85: 		MN_ADD_CFLAGS([-fgnu89-inline])
cannam@85: 		fi
cannam@85: 
cannam@85: 	CFLAGS="$CFLAGS -Wall"
cannam@85: 	CXXFLAGS="$CXXFLAGS -Wall"
cannam@85: 
cannam@85: 	MN_ADD_CFLAGS([-Wextra])
cannam@85: 
cannam@85: 	AC_LANG_PUSH([C++])
cannam@85: 	MN_ADD_CXXFLAGS([-Wextra])
cannam@85: 	AC_LANG_POP([C++])
cannam@85: 
cannam@85: 	MN_ADD_CFLAGS([-Wdeclaration-after-statement])
cannam@85: 	MN_ADD_CFLAGS([-Wpointer-arith])
cannam@85: 	MN_ADD_CFLAGS([-funsigned-char])
cannam@85: 
cannam@85: 	if test x$enable_gcc_werror = "xyes" ; then
cannam@85: 		CFLAGS="-Werror $CFLAGS"
cannam@85: 		CXXFLAGS="-Werror $CXXFLAGS"
cannam@85: 		fi
cannam@85: 
cannam@85: 	if test x$enable_test_coverage = "xyes" ; then
cannam@85: 		# MN_ADD_CFLAGS([-ftest-coverage])
cannam@85: 		MN_ADD_CFLAGS([-coverage])
cannam@85: 		fi
cannam@85: 
cannam@85: 	CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Waggregate-return -Wcast-align -Wcast-qual -Wnested-externs -Wshadow -Wbad-function-cast -Wwrite-strings -Wundef "
cannam@85: 	# -Wundef -Wmissing-declarations -Winline -Wconversion"
cannam@85: 	CXXFLAGS="$CXXFLAGS -Wcast-align -Wcast-qual -Wshadow -Wwrite-strings -Wctor-dtor-privacy -Wnon-virtual-dtor -Woverloaded-virtual -Wreorder -Wsign-promo -Wundef "
cannam@85: 
cannam@85: 	if test "x$enable_gcc_opt" = "xno" ; then
cannam@85: 		temp_CFLAGS=`echo $CFLAGS | $SED "s/O2/O0/"`
cannam@85: 		CFLAGS=$temp_CFLAGS
cannam@85: 		AC_MSG_WARN([[*** Compiler optimisations switched off. ***]])
cannam@85: 		fi
cannam@85: 
cannam@85: 	# OS specific tweaks.
cannam@85: 	case "$host_os" in
cannam@85: 		darwin* | rhapsody*)
cannam@85: 			# Disable -Wall, -pedantic and -Wshadow for Apple Darwin/Rhapsody.
cannam@85: 			# System headers on these systems are broken.
cannam@85: 			temp_CFLAGS=`echo $CFLAGS | $SED "s/-Wall -pedantic//" | $SED "s/-Wshadow//" | $SED "s/-Waggregate-return//"`
cannam@85: 			CFLAGS=$temp_CFLAGS
cannam@85: 			SHLIB_VERSION_ARG="-Wl,-exported_symbols_list -Wl,\$(srcdir)/Symbols.darwin"
cannam@85: 			;;
cannam@85: 		linux*|kfreebsd*-gnu*|gnu*)
cannam@85: 			SHLIB_VERSION_ARG="-Wl,--version-script=\$(srcdir)/Symbols.gnu-binutils"
cannam@85: 			;;
cannam@85: 		mingw*)
cannam@85: 			# Linker flag '-Wl,--out-implib' does not work with mingw cross compiler
cannam@85: 			# so we don't use it here.
cannam@85: 			SHLIB_VERSION_ARG="-Wl,\$(srcdir)/libsndfile-1.def"
cannam@85: 			win32_target_dll=1
cannam@85: 			if test x"$enable_shared" = xno ; then
cannam@85: 				win32_target_dll=0
cannam@85: 				fi
cannam@85: 			;;
cannam@85: 		os2*)
cannam@85: 			SHLIB_VERSION_ARG="-Wl,-export-symbols \$(srcdir)/Symbols.os2"
cannam@85: 			;;
cannam@85: 		*)
cannam@85: 			;;
cannam@85: 		esac
cannam@85: 	if test x$enable_gcc_pipe != "xno" ; then
cannam@85: 	 	CFLAGS="$CFLAGS -pipe"
cannam@85: 	 	fi
cannam@85: 
cannam@85: 	COMPILER_IS_GCC=1
cannam@85: 	fi
cannam@85: 
cannam@85: AC_DEFINE_UNQUOTED([WIN32_TARGET_DLL], ${win32_target_dll}, [Set to 1 if windows DLL is being built.])
cannam@85: AC_DEFINE_UNQUOTED([COMPILER_IS_GCC], ${COMPILER_IS_GCC}, [Set to 1 if the compile is GNU GCC.])
cannam@85: 
cannam@85: CFLAGS="$CFLAGS $OS_SPECIFIC_CFLAGS"
cannam@85: 
cannam@85: if test x"$CFLAGS" = x ; then
cannam@85: 	echo "Error in configure script. CFLAGS has been screwed up."
cannam@85: 	exit
cannam@85: 	fi
cannam@85: 
cannam@85: HOST_TRIPLET="${host_cpu}-${host_vendor}-${host_os}"
cannam@85: 
cannam@85: if test "$HOST_TRIPLET" = "x86_64-w64-mingw32" ; then
cannam@85: 	OS_SPECIFIC_LINKS=" -static-libgcc $OS_SPECIFIC_LINKS"
cannam@85: 	fi
cannam@85: 
cannam@85: WIN_RC_VERSION=`echo $PACKAGE_VERSION | $SED -e "s/p.*//" -e "s/\./,/g"`
cannam@85: 
cannam@85: #-------------------------------------------------------------------------------
cannam@85: 
cannam@85: AC_SUBST(HOST_TRIPLET)
cannam@85: 
cannam@85: AC_SUBST(htmldocdir)
cannam@85: AC_SUBST(HTML_BGCOLOUR)
cannam@85: AC_SUBST(HTML_FGCOLOUR)
cannam@85: 
cannam@85: AC_SUBST(SHLIB_VERSION_ARG)
cannam@85: AC_SUBST(SHARED_VERSION_INFO)
cannam@85: AC_SUBST(CLEAN_VERSION)
cannam@85: AC_SUBST(WIN_RC_VERSION)
cannam@85: 
cannam@85: AC_SUBST(OS_SPECIFIC_CFLAGS)
cannam@85: AC_SUBST(OS_SPECIFIC_LINKS)
cannam@85: AC_SUBST(ALSA_LIBS)
cannam@85: AC_SUBST(SNDIO_LIBS)
cannam@85: 
cannam@85: AC_SUBST(EXTERNAL_CFLAGS)
cannam@85: AC_SUBST(EXTERNAL_LIBS)
cannam@85: 
cannam@85: dnl The following line causes the libtool distributed with the source
cannam@85: dnl to be replaced if the build system has a more recent version.
cannam@85: AC_SUBST(LIBTOOL_DEPS)
cannam@85: 
cannam@85: AC_CONFIG_FILES([ \
cannam@85: 	src/Makefile man/Makefile examples/Makefile tests/Makefile regtest/Makefile \
cannam@85: 	M4/Makefile doc/Makefile Win32/Makefile Octave/Makefile programs/Makefile \
cannam@85: 	Makefile \
cannam@85: 	src/version-metadata.rc tests/test_wrapper.sh tests/pedantic-header-test.sh \
cannam@85: 	doc/libsndfile.css build-test-tarball.mk libsndfile.spec sndfile.pc \
cannam@85: 	src/sndfile.h \
cannam@85: 	])
cannam@85: AC_OUTPUT
cannam@85: 
cannam@85: # Make sure these are executable.
cannam@85: chmod u+x tests/test_wrapper.sh build-test-tarball.mk
cannam@85: 
cannam@85: #====================================================================================
cannam@85: 
cannam@85: AC_MSG_RESULT([
cannam@85: -=-=-=-=-=-=-=-=-=-= Configuration Complete =-=-=-=-=-=-=-=-=-=-
cannam@85: 
cannam@85:   Configuration summary :
cannam@85: 
cannam@85:     libsndfile version : .................. ${VERSION}
cannam@85: 
cannam@85:     Host CPU : ............................ ${host_cpu}
cannam@85:     Host Vendor : ......................... ${host_vendor}
cannam@85:     Host OS : ............................. ${host_os}
cannam@85: 
cannam@85:     Experimental code : ................... ${enable_experimental:-no}
cannam@85:     Using ALSA in example programs : ...... ${enable_alsa:-no}
cannam@85:     External FLAC/Ogg/Vorbis : ............ ${enable_external_libs:-no}
cannam@85: ])
cannam@85: 
cannam@85: if test -z "$PKG_CONFIG" ; then
cannam@85: 	echo "    *****************************************************************"
cannam@85: 	echo "    ***          The pkg-config program is missing.               ***"
cannam@85: 	echo "    *** External FLAC/Ogg/Vorbis libs cannot be found without it. ***"
cannam@85: 	echo "    ***       http://pkg-config.freedesktop.org/wiki/             ***"
cannam@85: 	echo "    *****************************************************************"
cannam@85: 	echo
cannam@85: 	fi
cannam@85: 
cannam@85: if test x$ac_cv_c_compiler_gnu = xyes ; then
cannam@85: 	echo "  Tools :"
cannam@85: 	echo
cannam@85: 	echo "    Compiler is GCC : ..................... ${ac_cv_c_compiler_gnu}"
cannam@85: 	echo "    GCC version : ......................... ${GCC_VERSION}"
cannam@85: 	if test $GCC_MAJOR_VERSION -lt 3 ; then
cannam@85: 		echo "\n"
cannam@85: 		echo "    ** This compiler version allows applications to write"
cannam@85: 		echo "    ** to static strings within the library."
cannam@85: 		echo "    ** Compile with GCC version 3.X or above to avoid this problem."
cannam@85: 		fi
cannam@85: 	fi
cannam@85: 
cannam@85: if test $libdir = "\${exec_prefix}/lib" ; then
cannam@85: 	libdir="$prefix/lib"
cannam@85: 	fi
cannam@85: 
cannam@85: if test $bindir = "\${exec_prefix}/bin" ; then
cannam@85: 	bindir="$prefix/bin"
cannam@85: 	fi
cannam@85: 
cannam@85: AC_MSG_RESULT([[
cannam@85:   Installation directories :
cannam@85: 
cannam@85:     Library directory : ................... $libdir
cannam@85:     Program directory : ................... $bindir
cannam@85:     Pkgconfig directory : ................. $libdir/pkgconfig
cannam@85:     HTML docs directory : ................. $htmldocdir
cannam@85: ]])
cannam@85: 
cannam@85: if test x$prefix != "x/usr" ; then
cannam@85: 	echo "Compiling some other packages against libsndfile may require"
cannam@85: 	echo "the addition of '$libdir/pkgconfig' to the"
cannam@85: 	echo "PKG_CONFIG_PATH environment variable."
cannam@85: 	echo
cannam@85: 	fi
cannam@85: 
cannam@85: (cd src && make genfiles)
cannam@85: (cd tests && make genfiles)