cannam@127: # Helper functions for option handling.                    -*- Autoconf -*-
cannam@127: #
cannam@127: #   Copyright (C) 2004, 2005, 2007, 2008, 2009 Free Software Foundation,
cannam@127: #   Inc.
cannam@127: #   Written by Gary V. Vaughan, 2004
cannam@127: #
cannam@127: # This file is free software; the Free Software Foundation gives
cannam@127: # unlimited permission to copy and/or distribute it, with or without
cannam@127: # modifications, as long as this notice is preserved.
cannam@127: 
cannam@127: # serial 7 ltoptions.m4
cannam@127: 
cannam@127: # This is to help aclocal find these macros, as it can't see m4_define.
cannam@127: AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
cannam@127: 
cannam@127: 
cannam@127: # _LT_MANGLE_OPTION(MACRO-NAME, OPTION-NAME)
cannam@127: # ------------------------------------------
cannam@127: m4_define([_LT_MANGLE_OPTION],
cannam@127: [[_LT_OPTION_]m4_bpatsubst($1__$2, [[^a-zA-Z0-9_]], [_])])
cannam@127: 
cannam@127: 
cannam@127: # _LT_SET_OPTION(MACRO-NAME, OPTION-NAME)
cannam@127: # ---------------------------------------
cannam@127: # Set option OPTION-NAME for macro MACRO-NAME, and if there is a
cannam@127: # matching handler defined, dispatch to it.  Other OPTION-NAMEs are
cannam@127: # saved as a flag.
cannam@127: m4_define([_LT_SET_OPTION],
cannam@127: [m4_define(_LT_MANGLE_OPTION([$1], [$2]))dnl
cannam@127: m4_ifdef(_LT_MANGLE_DEFUN([$1], [$2]),
cannam@127:         _LT_MANGLE_DEFUN([$1], [$2]),
cannam@127:     [m4_warning([Unknown $1 option `$2'])])[]dnl
cannam@127: ])
cannam@127: 
cannam@127: 
cannam@127: # _LT_IF_OPTION(MACRO-NAME, OPTION-NAME, IF-SET, [IF-NOT-SET])
cannam@127: # ------------------------------------------------------------
cannam@127: # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
cannam@127: m4_define([_LT_IF_OPTION],
cannam@127: [m4_ifdef(_LT_MANGLE_OPTION([$1], [$2]), [$3], [$4])])
cannam@127: 
cannam@127: 
cannam@127: # _LT_UNLESS_OPTIONS(MACRO-NAME, OPTION-LIST, IF-NOT-SET)
cannam@127: # -------------------------------------------------------
cannam@127: # Execute IF-NOT-SET unless all options in OPTION-LIST for MACRO-NAME
cannam@127: # are set.
cannam@127: m4_define([_LT_UNLESS_OPTIONS],
cannam@127: [m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
cannam@127: 	    [m4_ifdef(_LT_MANGLE_OPTION([$1], _LT_Option),
cannam@127: 		      [m4_define([$0_found])])])[]dnl
cannam@127: m4_ifdef([$0_found], [m4_undefine([$0_found])], [$3
cannam@127: ])[]dnl
cannam@127: ])
cannam@127: 
cannam@127: 
cannam@127: # _LT_SET_OPTIONS(MACRO-NAME, OPTION-LIST)
cannam@127: # ----------------------------------------
cannam@127: # OPTION-LIST is a space-separated list of Libtool options associated
cannam@127: # with MACRO-NAME.  If any OPTION has a matching handler declared with
cannam@127: # LT_OPTION_DEFINE, dispatch to that macro; otherwise complain about
cannam@127: # the unknown option and exit.
cannam@127: m4_defun([_LT_SET_OPTIONS],
cannam@127: [# Set options
cannam@127: m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
cannam@127:     [_LT_SET_OPTION([$1], _LT_Option)])
cannam@127: 
cannam@127: m4_if([$1],[LT_INIT],[
cannam@127:   dnl
cannam@127:   dnl Simply set some default values (i.e off) if boolean options were not
cannam@127:   dnl specified:
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
cannam@127:   ])
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
cannam@127:   ])
cannam@127:   dnl
cannam@127:   dnl If no reference was made to various pairs of opposing options, then
cannam@127:   dnl we run the default mode handler for the pair.  For example, if neither
cannam@127:   dnl `shared' nor `disable-shared' was passed, we enable building of shared
cannam@127:   dnl archives by default:
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
cannam@127:   _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
cannam@127:   		   [_LT_ENABLE_FAST_INSTALL])
cannam@127:   ])
cannam@127: ])# _LT_SET_OPTIONS
cannam@127: 
cannam@127: 
cannam@127: ## --------------------------------- ##
cannam@127: ## Macros to handle LT_INIT options. ##
cannam@127: ## --------------------------------- ##
cannam@127: 
cannam@127: # _LT_MANGLE_DEFUN(MACRO-NAME, OPTION-NAME)
cannam@127: # -----------------------------------------
cannam@127: m4_define([_LT_MANGLE_DEFUN],
cannam@127: [[_LT_OPTION_DEFUN_]m4_bpatsubst(m4_toupper([$1__$2]), [[^A-Z0-9_]], [_])])
cannam@127: 
cannam@127: 
cannam@127: # LT_OPTION_DEFINE(MACRO-NAME, OPTION-NAME, CODE)
cannam@127: # -----------------------------------------------
cannam@127: m4_define([LT_OPTION_DEFINE],
cannam@127: [m4_define(_LT_MANGLE_DEFUN([$1], [$2]), [$3])[]dnl
cannam@127: ])# LT_OPTION_DEFINE
cannam@127: 
cannam@127: 
cannam@127: # dlopen
cannam@127: # ------
cannam@127: LT_OPTION_DEFINE([LT_INIT], [dlopen], [enable_dlopen=yes
cannam@127: ])
cannam@127: 
cannam@127: AU_DEFUN([AC_LIBTOOL_DLOPEN],
cannam@127: [_LT_SET_OPTION([LT_INIT], [dlopen])
cannam@127: AC_DIAGNOSE([obsolete],
cannam@127: [$0: Remove this warning and the call to _LT_SET_OPTION when you
cannam@127: put the `dlopen' option into LT_INIT's first parameter.])
cannam@127: ])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AC_LIBTOOL_DLOPEN], [])
cannam@127: 
cannam@127: 
cannam@127: # win32-dll
cannam@127: # ---------
cannam@127: # Declare package support for building win32 dll's.
cannam@127: LT_OPTION_DEFINE([LT_INIT], [win32-dll],
cannam@127: [enable_win32_dll=yes
cannam@127: 
cannam@127: case $host in
cannam@127: *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-cegcc*)
cannam@127:   AC_CHECK_TOOL(AS, as, false)
cannam@127:   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
cannam@127:   AC_CHECK_TOOL(OBJDUMP, objdump, false)
cannam@127:   ;;
cannam@127: esac
cannam@127: 
cannam@127: test -z "$AS" && AS=as
cannam@127: _LT_DECL([], [AS],      [1], [Assembler program])dnl
cannam@127: 
cannam@127: test -z "$DLLTOOL" && DLLTOOL=dlltool
cannam@127: _LT_DECL([], [DLLTOOL], [1], [DLL creation program])dnl
cannam@127: 
cannam@127: test -z "$OBJDUMP" && OBJDUMP=objdump
cannam@127: _LT_DECL([], [OBJDUMP], [1], [Object dumper program])dnl
cannam@127: ])# win32-dll
cannam@127: 
cannam@127: AU_DEFUN([AC_LIBTOOL_WIN32_DLL],
cannam@127: [AC_REQUIRE([AC_CANONICAL_HOST])dnl
cannam@127: _LT_SET_OPTION([LT_INIT], [win32-dll])
cannam@127: AC_DIAGNOSE([obsolete],
cannam@127: [$0: Remove this warning and the call to _LT_SET_OPTION when you
cannam@127: put the `win32-dll' option into LT_INIT's first parameter.])
cannam@127: ])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AC_LIBTOOL_WIN32_DLL], [])
cannam@127: 
cannam@127: 
cannam@127: # _LT_ENABLE_SHARED([DEFAULT])
cannam@127: # ----------------------------
cannam@127: # implement the --enable-shared flag, and supports the `shared' and
cannam@127: # `disable-shared' LT_INIT options.
cannam@127: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
cannam@127: m4_define([_LT_ENABLE_SHARED],
cannam@127: [m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
cannam@127: AC_ARG_ENABLE([shared],
cannam@127:     [AS_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
cannam@127: 	[build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
cannam@127:     [p=${PACKAGE-default}
cannam@127:     case $enableval in
cannam@127:     yes) enable_shared=yes ;;
cannam@127:     no) enable_shared=no ;;
cannam@127:     *)
cannam@127:       enable_shared=no
cannam@127:       # Look at the argument we got.  We use all the common list separators.
cannam@127:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
cannam@127:       for pkg in $enableval; do
cannam@127: 	IFS="$lt_save_ifs"
cannam@127: 	if test "X$pkg" = "X$p"; then
cannam@127: 	  enable_shared=yes
cannam@127: 	fi
cannam@127:       done
cannam@127:       IFS="$lt_save_ifs"
cannam@127:       ;;
cannam@127:     esac],
cannam@127:     [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
cannam@127: 
cannam@127:     _LT_DECL([build_libtool_libs], [enable_shared], [0],
cannam@127: 	[Whether or not to build shared libraries])
cannam@127: ])# _LT_ENABLE_SHARED
cannam@127: 
cannam@127: LT_OPTION_DEFINE([LT_INIT], [shared], [_LT_ENABLE_SHARED([yes])])
cannam@127: LT_OPTION_DEFINE([LT_INIT], [disable-shared], [_LT_ENABLE_SHARED([no])])
cannam@127: 
cannam@127: # Old names:
cannam@127: AC_DEFUN([AC_ENABLE_SHARED],
cannam@127: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[shared])
cannam@127: ])
cannam@127: 
cannam@127: AC_DEFUN([AC_DISABLE_SHARED],
cannam@127: [_LT_SET_OPTION([LT_INIT], [disable-shared])
cannam@127: ])
cannam@127: 
cannam@127: AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
cannam@127: AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AM_ENABLE_SHARED], [])
cannam@127: dnl AC_DEFUN([AM_DISABLE_SHARED], [])
cannam@127: 
cannam@127: 
cannam@127: 
cannam@127: # _LT_ENABLE_STATIC([DEFAULT])
cannam@127: # ----------------------------
cannam@127: # implement the --enable-static flag, and support the `static' and
cannam@127: # `disable-static' LT_INIT options.
cannam@127: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
cannam@127: m4_define([_LT_ENABLE_STATIC],
cannam@127: [m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
cannam@127: AC_ARG_ENABLE([static],
cannam@127:     [AS_HELP_STRING([--enable-static@<:@=PKGS@:>@],
cannam@127: 	[build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
cannam@127:     [p=${PACKAGE-default}
cannam@127:     case $enableval in
cannam@127:     yes) enable_static=yes ;;
cannam@127:     no) enable_static=no ;;
cannam@127:     *)
cannam@127:      enable_static=no
cannam@127:       # Look at the argument we got.  We use all the common list separators.
cannam@127:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
cannam@127:       for pkg in $enableval; do
cannam@127: 	IFS="$lt_save_ifs"
cannam@127: 	if test "X$pkg" = "X$p"; then
cannam@127: 	  enable_static=yes
cannam@127: 	fi
cannam@127:       done
cannam@127:       IFS="$lt_save_ifs"
cannam@127:       ;;
cannam@127:     esac],
cannam@127:     [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
cannam@127: 
cannam@127:     _LT_DECL([build_old_libs], [enable_static], [0],
cannam@127: 	[Whether or not to build static libraries])
cannam@127: ])# _LT_ENABLE_STATIC
cannam@127: 
cannam@127: LT_OPTION_DEFINE([LT_INIT], [static], [_LT_ENABLE_STATIC([yes])])
cannam@127: LT_OPTION_DEFINE([LT_INIT], [disable-static], [_LT_ENABLE_STATIC([no])])
cannam@127: 
cannam@127: # Old names:
cannam@127: AC_DEFUN([AC_ENABLE_STATIC],
cannam@127: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[static])
cannam@127: ])
cannam@127: 
cannam@127: AC_DEFUN([AC_DISABLE_STATIC],
cannam@127: [_LT_SET_OPTION([LT_INIT], [disable-static])
cannam@127: ])
cannam@127: 
cannam@127: AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
cannam@127: AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AM_ENABLE_STATIC], [])
cannam@127: dnl AC_DEFUN([AM_DISABLE_STATIC], [])
cannam@127: 
cannam@127: 
cannam@127: 
cannam@127: # _LT_ENABLE_FAST_INSTALL([DEFAULT])
cannam@127: # ----------------------------------
cannam@127: # implement the --enable-fast-install flag, and support the `fast-install'
cannam@127: # and `disable-fast-install' LT_INIT options.
cannam@127: # DEFAULT is either `yes' or `no'.  If omitted, it defaults to `yes'.
cannam@127: m4_define([_LT_ENABLE_FAST_INSTALL],
cannam@127: [m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
cannam@127: AC_ARG_ENABLE([fast-install],
cannam@127:     [AS_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
cannam@127:     [optimize for fast installation @<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
cannam@127:     [p=${PACKAGE-default}
cannam@127:     case $enableval in
cannam@127:     yes) enable_fast_install=yes ;;
cannam@127:     no) enable_fast_install=no ;;
cannam@127:     *)
cannam@127:       enable_fast_install=no
cannam@127:       # Look at the argument we got.  We use all the common list separators.
cannam@127:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
cannam@127:       for pkg in $enableval; do
cannam@127: 	IFS="$lt_save_ifs"
cannam@127: 	if test "X$pkg" = "X$p"; then
cannam@127: 	  enable_fast_install=yes
cannam@127: 	fi
cannam@127:       done
cannam@127:       IFS="$lt_save_ifs"
cannam@127:       ;;
cannam@127:     esac],
cannam@127:     [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
cannam@127: 
cannam@127: _LT_DECL([fast_install], [enable_fast_install], [0],
cannam@127: 	 [Whether or not to optimize for fast installation])dnl
cannam@127: ])# _LT_ENABLE_FAST_INSTALL
cannam@127: 
cannam@127: LT_OPTION_DEFINE([LT_INIT], [fast-install], [_LT_ENABLE_FAST_INSTALL([yes])])
cannam@127: LT_OPTION_DEFINE([LT_INIT], [disable-fast-install], [_LT_ENABLE_FAST_INSTALL([no])])
cannam@127: 
cannam@127: # Old names:
cannam@127: AU_DEFUN([AC_ENABLE_FAST_INSTALL],
cannam@127: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[fast-install])
cannam@127: AC_DIAGNOSE([obsolete],
cannam@127: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
cannam@127: the `fast-install' option into LT_INIT's first parameter.])
cannam@127: ])
cannam@127: 
cannam@127: AU_DEFUN([AC_DISABLE_FAST_INSTALL],
cannam@127: [_LT_SET_OPTION([LT_INIT], [disable-fast-install])
cannam@127: AC_DIAGNOSE([obsolete],
cannam@127: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
cannam@127: the `disable-fast-install' option into LT_INIT's first parameter.])
cannam@127: ])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AC_ENABLE_FAST_INSTALL], [])
cannam@127: dnl AC_DEFUN([AM_DISABLE_FAST_INSTALL], [])
cannam@127: 
cannam@127: 
cannam@127: # _LT_WITH_PIC([MODE])
cannam@127: # --------------------
cannam@127: # implement the --with-pic flag, and support the `pic-only' and `no-pic'
cannam@127: # LT_INIT options.
cannam@127: # MODE is either `yes' or `no'.  If omitted, it defaults to `both'.
cannam@127: m4_define([_LT_WITH_PIC],
cannam@127: [AC_ARG_WITH([pic],
cannam@127:     [AS_HELP_STRING([--with-pic@<:@=PKGS@:>@],
cannam@127: 	[try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
cannam@127:     [lt_p=${PACKAGE-default}
cannam@127:     case $withval in
cannam@127:     yes|no) pic_mode=$withval ;;
cannam@127:     *)
cannam@127:       pic_mode=default
cannam@127:       # Look at the argument we got.  We use all the common list separators.
cannam@127:       lt_save_ifs="$IFS"; IFS="${IFS}$PATH_SEPARATOR,"
cannam@127:       for lt_pkg in $withval; do
cannam@127: 	IFS="$lt_save_ifs"
cannam@127: 	if test "X$lt_pkg" = "X$lt_p"; then
cannam@127: 	  pic_mode=yes
cannam@127: 	fi
cannam@127:       done
cannam@127:       IFS="$lt_save_ifs"
cannam@127:       ;;
cannam@127:     esac],
cannam@127:     [pic_mode=default])
cannam@127: 
cannam@127: test -z "$pic_mode" && pic_mode=m4_default([$1], [default])
cannam@127: 
cannam@127: _LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
cannam@127: ])# _LT_WITH_PIC
cannam@127: 
cannam@127: LT_OPTION_DEFINE([LT_INIT], [pic-only], [_LT_WITH_PIC([yes])])
cannam@127: LT_OPTION_DEFINE([LT_INIT], [no-pic], [_LT_WITH_PIC([no])])
cannam@127: 
cannam@127: # Old name:
cannam@127: AU_DEFUN([AC_LIBTOOL_PICMODE],
cannam@127: [_LT_SET_OPTION([LT_INIT], [pic-only])
cannam@127: AC_DIAGNOSE([obsolete],
cannam@127: [$0: Remove this warning and the call to _LT_SET_OPTION when you
cannam@127: put the `pic-only' option into LT_INIT's first parameter.])
cannam@127: ])
cannam@127: 
cannam@127: dnl aclocal-1.4 backwards compatibility:
cannam@127: dnl AC_DEFUN([AC_LIBTOOL_PICMODE], [])
cannam@127: 
cannam@127: ## ----------------- ##
cannam@127: ## LTDL_INIT Options ##
cannam@127: ## ----------------- ##
cannam@127: 
cannam@127: m4_define([_LTDL_MODE], [])
cannam@127: LT_OPTION_DEFINE([LTDL_INIT], [nonrecursive],
cannam@127: 		 [m4_define([_LTDL_MODE], [nonrecursive])])
cannam@127: LT_OPTION_DEFINE([LTDL_INIT], [recursive],
cannam@127: 		 [m4_define([_LTDL_MODE], [recursive])])
cannam@127: LT_OPTION_DEFINE([LTDL_INIT], [subproject],
cannam@127: 		 [m4_define([_LTDL_MODE], [subproject])])
cannam@127: 
cannam@127: m4_define([_LTDL_TYPE], [])
cannam@127: LT_OPTION_DEFINE([LTDL_INIT], [installable],
cannam@127: 		 [m4_define([_LTDL_TYPE], [installable])])
cannam@127: LT_OPTION_DEFINE([LTDL_INIT], [convenience],
cannam@127: 		 [m4_define([_LTDL_TYPE], [convenience])])