Chris@4: ; inffasx64.asm is a hand tuned assembler version of inffast.c - fast decoding
Chris@4: ; version for AMD64 on Windows using Microsoft C compiler
Chris@4: ;
Chris@4: ; inffasx64.asm is automatically convert from AMD64 portion of inffas86.c
Chris@4: ; inffasx64.asm is called by inffas8664.c, which contain more info.
Chris@4: 
Chris@4: 
Chris@4: ; to compile this file, I use option
Chris@4: ;   ml64.exe /Flinffasx64 /c /Zi inffasx64.asm
Chris@4: ;   with Microsoft Macro Assembler (x64) for AMD64
Chris@4: ;
Chris@4: 
Chris@4: ; This file compile with Microsoft Macro Assembler (x64) for AMD64
Chris@4: ;
Chris@4: ;   ml64.exe is given with Visual Studio 2005/2008/2010 and Windows WDK
Chris@4: ;
Chris@4: ;   (you can get Windows WDK with ml64 for AMD64 from
Chris@4: ;      http://www.microsoft.com/whdc/Devtools/wdk/default.mspx for low price)
Chris@4: ;
Chris@4: 
Chris@4: 
Chris@4: .code
Chris@4: inffas8664fnc PROC
Chris@4: 
Chris@4: ; see http://weblogs.asp.net/oldnewthing/archive/2004/01/14/58579.aspx and
Chris@4: ; http://msdn.microsoft.com/library/en-us/kmarch/hh/kmarch/64bitAMD_8e951dd2-ee77-4728-8702-55ce4b5dd24a.xml.asp
Chris@4: ;
Chris@4: ; All registers must be preserved across the call, except for
Chris@4: ;   rax, rcx, rdx, r8, r-9, r10, and r11, which are scratch.
Chris@4: 
Chris@4: 
Chris@4: 	mov [rsp-8],rsi
Chris@4: 	mov [rsp-16],rdi
Chris@4: 	mov [rsp-24],r12
Chris@4: 	mov [rsp-32],r13
Chris@4: 	mov [rsp-40],r14
Chris@4: 	mov [rsp-48],r15
Chris@4: 	mov [rsp-56],rbx
Chris@4: 
Chris@4: 	mov rax,rcx
Chris@4: 
Chris@4: 	mov	[rax+8], rbp       ; /* save regs rbp and rsp */
Chris@4: 	mov	[rax], rsp
Chris@4: 
Chris@4: 	mov	rsp, rax          ; /* make rsp point to &ar */
Chris@4: 
Chris@4: 	mov	rsi, [rsp+16]      ; /* rsi  = in */
Chris@4: 	mov	rdi, [rsp+32]      ; /* rdi  = out */
Chris@4: 	mov	r9, [rsp+24]       ; /* r9   = last */
Chris@4: 	mov	r10, [rsp+48]      ; /* r10  = end */
Chris@4: 	mov	rbp, [rsp+64]      ; /* rbp  = lcode */
Chris@4: 	mov	r11, [rsp+72]      ; /* r11  = dcode */
Chris@4: 	mov	rdx, [rsp+80]      ; /* rdx  = hold */
Chris@4: 	mov	ebx, [rsp+88]      ; /* ebx  = bits */
Chris@4: 	mov	r12d, [rsp+100]    ; /* r12d = lmask */
Chris@4: 	mov	r13d, [rsp+104]    ; /* r13d = dmask */
Chris@4:                                           ; /* r14d = len */
Chris@4:                                           ; /* r15d = dist */
Chris@4: 
Chris@4: 
Chris@4: 	cld
Chris@4: 	cmp	r10, rdi
Chris@4: 	je	L_one_time           ; /* if only one decode left */
Chris@4: 	cmp	r9, rsi
Chris@4: 
Chris@4:     jne L_do_loop
Chris@4: 
Chris@4: 
Chris@4: L_one_time:
Chris@4: 	mov	r8, r12           ; /* r8 = lmask */
Chris@4: 	cmp	bl, 32
Chris@4: 	ja	L_get_length_code_one_time
Chris@4: 
Chris@4: 	lodsd                         ; /* eax = *(uint *)in++ */
Chris@4: 	mov	cl, bl            ; /* cl = bits, needs it for shifting */
Chris@4: 	add	bl, 32             ; /* bits += 32 */
Chris@4: 	shl	rax, cl
Chris@4: 	or	rdx, rax          ; /* hold |= *((uint *)in)++ << bits */
Chris@4: 	jmp	L_get_length_code_one_time
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_while_test:
Chris@4: 	cmp	r10, rdi
Chris@4: 	jbe	L_break_loop
Chris@4: 	cmp	r9, rsi
Chris@4: 	jbe	L_break_loop
Chris@4: 
Chris@4: L_do_loop:
Chris@4: 	mov	r8, r12           ; /* r8 = lmask */
Chris@4: 	cmp	bl, 32
Chris@4: 	ja	L_get_length_code    ; /* if (32 < bits) */
Chris@4: 
Chris@4: 	lodsd                         ; /* eax = *(uint *)in++ */
Chris@4: 	mov	cl, bl            ; /* cl = bits, needs it for shifting */
Chris@4: 	add	bl, 32             ; /* bits += 32 */
Chris@4: 	shl	rax, cl
Chris@4: 	or	rdx, rax          ; /* hold |= *((uint *)in)++ << bits */
Chris@4: 
Chris@4: L_get_length_code:
Chris@4: 	and	r8, rdx            ; /* r8 &= hold */
Chris@4: 	mov	eax, [rbp+r8*4]  ; /* eax = lcode[hold & lmask] */
Chris@4: 
Chris@4: 	mov	cl, ah            ; /* cl = this.bits */
Chris@4: 	sub	bl, ah            ; /* bits -= this.bits */
Chris@4: 	shr	rdx, cl           ; /* hold >>= this.bits */
Chris@4: 
Chris@4: 	test	al, al
Chris@4: 	jnz	L_test_for_length_base ; /* if (op != 0) 45.7% */
Chris@4: 
Chris@4: 	mov	r8, r12            ; /* r8 = lmask */
Chris@4: 	shr	eax, 16            ; /* output this.val char */
Chris@4: 	stosb
Chris@4: 
Chris@4: L_get_length_code_one_time:
Chris@4: 	and	r8, rdx            ; /* r8 &= hold */
Chris@4: 	mov	eax, [rbp+r8*4] ; /* eax = lcode[hold & lmask] */
Chris@4: 
Chris@4: L_dolen:
Chris@4: 	mov	cl, ah            ; /* cl = this.bits */
Chris@4: 	sub	bl, ah            ; /* bits -= this.bits */
Chris@4: 	shr	rdx, cl           ; /* hold >>= this.bits */
Chris@4: 
Chris@4: 	test	al, al
Chris@4: 	jnz	L_test_for_length_base ; /* if (op != 0) 45.7% */
Chris@4: 
Chris@4: 	shr	eax, 16            ; /* output this.val char */
Chris@4: 	stosb
Chris@4: 	jmp	L_while_test
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_test_for_length_base:
Chris@4: 	mov	r14d, eax         ; /* len = this */
Chris@4: 	shr	r14d, 16           ; /* len = this.val */
Chris@4: 	mov	cl, al
Chris@4: 
Chris@4: 	test	al, 16
Chris@4: 	jz	L_test_for_second_level_length ; /* if ((op & 16) == 0) 8% */
Chris@4: 	and	cl, 15             ; /* op &= 15 */
Chris@4: 	jz	L_decode_distance    ; /* if (!op) */
Chris@4: 
Chris@4: L_add_bits_to_len:
Chris@4: 	sub	bl, cl
Chris@4: 	xor	eax, eax
Chris@4: 	inc	eax
Chris@4: 	shl	eax, cl
Chris@4: 	dec	eax
Chris@4: 	and	eax, edx          ; /* eax &= hold */
Chris@4: 	shr	rdx, cl
Chris@4: 	add	r14d, eax         ; /* len += hold & mask[op] */
Chris@4: 
Chris@4: L_decode_distance:
Chris@4: 	mov	r8, r13           ; /* r8 = dmask */
Chris@4: 	cmp	bl, 32
Chris@4: 	ja	L_get_distance_code  ; /* if (32 < bits) */
Chris@4: 
Chris@4: 	lodsd                         ; /* eax = *(uint *)in++ */
Chris@4: 	mov	cl, bl            ; /* cl = bits, needs it for shifting */
Chris@4: 	add	bl, 32             ; /* bits += 32 */
Chris@4: 	shl	rax, cl
Chris@4: 	or	rdx, rax          ; /* hold |= *((uint *)in)++ << bits */
Chris@4: 
Chris@4: L_get_distance_code:
Chris@4: 	and	r8, rdx           ; /* r8 &= hold */
Chris@4: 	mov	eax, [r11+r8*4] ; /* eax = dcode[hold & dmask] */
Chris@4: 
Chris@4: L_dodist:
Chris@4: 	mov	r15d, eax         ; /* dist = this */
Chris@4: 	shr	r15d, 16           ; /* dist = this.val */
Chris@4: 	mov	cl, ah
Chris@4: 	sub	bl, ah            ; /* bits -= this.bits */
Chris@4: 	shr	rdx, cl           ; /* hold >>= this.bits */
Chris@4: 	mov	cl, al            ; /* cl = this.op */
Chris@4: 
Chris@4: 	test	al, 16             ; /* if ((op & 16) == 0) */
Chris@4: 	jz	L_test_for_second_level_dist
Chris@4: 	and	cl, 15             ; /* op &= 15 */
Chris@4: 	jz	L_check_dist_one
Chris@4: 
Chris@4: L_add_bits_to_dist:
Chris@4: 	sub	bl, cl
Chris@4: 	xor	eax, eax
Chris@4: 	inc	eax
Chris@4: 	shl	eax, cl
Chris@4: 	dec	eax                 ; /* (1 << op) - 1 */
Chris@4: 	and	eax, edx          ; /* eax &= hold */
Chris@4: 	shr	rdx, cl
Chris@4: 	add	r15d, eax         ; /* dist += hold & ((1 << op) - 1) */
Chris@4: 
Chris@4: L_check_window:
Chris@4: 	mov	r8, rsi           ; /* save in so from can use it's reg */
Chris@4: 	mov	rax, rdi
Chris@4: 	sub	rax, [rsp+40]      ; /* nbytes = out - beg */
Chris@4: 
Chris@4: 	cmp	eax, r15d
Chris@4: 	jb	L_clip_window        ; /* if (dist > nbytes) 4.2% */
Chris@4: 
Chris@4: 	mov	ecx, r14d         ; /* ecx = len */
Chris@4: 	mov	rsi, rdi
Chris@4: 	sub	rsi, r15          ; /* from = out - dist */
Chris@4: 
Chris@4: 	sar	ecx, 1
Chris@4: 	jnc	L_copy_two           ; /* if len % 2 == 0 */
Chris@4: 
Chris@4: 	rep     movsw
Chris@4: 	mov	al, [rsi]
Chris@4: 	mov	[rdi], al
Chris@4: 	inc	rdi
Chris@4: 
Chris@4: 	mov	rsi, r8           ; /* move in back to %rsi, toss from */
Chris@4: 	jmp	L_while_test
Chris@4: 
Chris@4: L_copy_two:
Chris@4: 	rep     movsw
Chris@4: 	mov	rsi, r8           ; /* move in back to %rsi, toss from */
Chris@4: 	jmp	L_while_test
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_check_dist_one:
Chris@4: 	cmp	r15d, 1            ; /* if dist 1, is a memset */
Chris@4: 	jne	L_check_window
Chris@4: 	cmp	[rsp+40], rdi      ; /* if out == beg, outside window */
Chris@4: 	je	L_check_window
Chris@4: 
Chris@4: 	mov	ecx, r14d         ; /* ecx = len */
Chris@4: 	mov	al, [rdi-1]
Chris@4: 	mov	ah, al
Chris@4: 
Chris@4: 	sar	ecx, 1
Chris@4: 	jnc	L_set_two
Chris@4: 	mov	[rdi], al
Chris@4: 	inc	rdi
Chris@4: 
Chris@4: L_set_two:
Chris@4: 	rep     stosw
Chris@4: 	jmp	L_while_test
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_test_for_second_level_length:
Chris@4: 	test	al, 64
Chris@4: 	jnz	L_test_for_end_of_block ; /* if ((op & 64) != 0) */
Chris@4: 
Chris@4: 	xor	eax, eax
Chris@4: 	inc	eax
Chris@4: 	shl	eax, cl
Chris@4: 	dec	eax
Chris@4: 	and	eax, edx         ; /* eax &= hold */
Chris@4: 	add	eax, r14d        ; /* eax += len */
Chris@4: 	mov	eax, [rbp+rax*4] ; /* eax = lcode[val+(hold&mask[op])]*/
Chris@4: 	jmp	L_dolen
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_test_for_second_level_dist:
Chris@4: 	test	al, 64
Chris@4: 	jnz	L_invalid_distance_code ; /* if ((op & 64) != 0) */
Chris@4: 
Chris@4: 	xor	eax, eax
Chris@4: 	inc	eax
Chris@4: 	shl	eax, cl
Chris@4: 	dec	eax
Chris@4: 	and	eax, edx         ; /* eax &= hold */
Chris@4: 	add	eax, r15d        ; /* eax += dist */
Chris@4: 	mov	eax, [r11+rax*4] ; /* eax = dcode[val+(hold&mask[op])]*/
Chris@4: 	jmp	L_dodist
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_clip_window:
Chris@4: 	mov	ecx, eax         ; /* ecx = nbytes */
Chris@4: 	mov	eax, [rsp+92]     ; /* eax = wsize, prepare for dist cmp */
Chris@4: 	neg	ecx                ; /* nbytes = -nbytes */
Chris@4: 
Chris@4: 	cmp	eax, r15d
Chris@4: 	jb	L_invalid_distance_too_far ; /* if (dist > wsize) */
Chris@4: 
Chris@4: 	add	ecx, r15d         ; /* nbytes = dist - nbytes */
Chris@4: 	cmp	dword ptr [rsp+96], 0
Chris@4: 	jne	L_wrap_around_window ; /* if (write != 0) */
Chris@4: 
Chris@4: 	mov	rsi, [rsp+56]     ; /* from  = window */
Chris@4: 	sub	eax, ecx         ; /* eax  -= nbytes */
Chris@4: 	add	rsi, rax         ; /* from += wsize - nbytes */
Chris@4: 
Chris@4: 	mov	eax, r14d        ; /* eax = len */
Chris@4: 	cmp	r14d, ecx
Chris@4: 	jbe	L_do_copy           ; /* if (nbytes >= len) */
Chris@4: 
Chris@4: 	sub	eax, ecx         ; /* eax -= nbytes */
Chris@4: 	rep     movsb
Chris@4: 	mov	rsi, rdi
Chris@4: 	sub	rsi, r15         ; /* from = &out[ -dist ] */
Chris@4: 	jmp	L_do_copy
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_wrap_around_window:
Chris@4: 	mov	eax, [rsp+96]     ; /* eax = write */
Chris@4: 	cmp	ecx, eax
Chris@4: 	jbe	L_contiguous_in_window ; /* if (write >= nbytes) */
Chris@4: 
Chris@4: 	mov	esi, [rsp+92]     ; /* from  = wsize */
Chris@4: 	add	rsi, [rsp+56]     ; /* from += window */
Chris@4: 	add	rsi, rax         ; /* from += write */
Chris@4: 	sub	rsi, rcx         ; /* from -= nbytes */
Chris@4: 	sub	ecx, eax         ; /* nbytes -= write */
Chris@4: 
Chris@4: 	mov	eax, r14d        ; /* eax = len */
Chris@4: 	cmp	eax, ecx
Chris@4: 	jbe	L_do_copy           ; /* if (nbytes >= len) */
Chris@4: 
Chris@4: 	sub	eax, ecx         ; /* len -= nbytes */
Chris@4: 	rep     movsb
Chris@4: 	mov	rsi, [rsp+56]     ; /* from = window */
Chris@4: 	mov	ecx, [rsp+96]     ; /* nbytes = write */
Chris@4: 	cmp	eax, ecx
Chris@4: 	jbe	L_do_copy           ; /* if (nbytes >= len) */
Chris@4: 
Chris@4: 	sub	eax, ecx         ; /* len -= nbytes */
Chris@4: 	rep     movsb
Chris@4: 	mov	rsi, rdi
Chris@4: 	sub	rsi, r15         ; /* from = out - dist */
Chris@4: 	jmp	L_do_copy
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_contiguous_in_window:
Chris@4: 	mov	rsi, [rsp+56]     ; /* rsi = window */
Chris@4: 	add	rsi, rax
Chris@4: 	sub	rsi, rcx         ; /* from += write - nbytes */
Chris@4: 
Chris@4: 	mov	eax, r14d        ; /* eax = len */
Chris@4: 	cmp	eax, ecx
Chris@4: 	jbe	L_do_copy           ; /* if (nbytes >= len) */
Chris@4: 
Chris@4: 	sub	eax, ecx         ; /* len -= nbytes */
Chris@4: 	rep     movsb
Chris@4: 	mov	rsi, rdi
Chris@4: 	sub	rsi, r15         ; /* from = out - dist */
Chris@4: 	jmp	L_do_copy           ; /* if (nbytes >= len) */
Chris@4: 
Chris@4: ALIGN 4
Chris@4: L_do_copy:
Chris@4: 	mov	ecx, eax         ; /* ecx = len */
Chris@4: 	rep     movsb
Chris@4: 
Chris@4: 	mov	rsi, r8          ; /* move in back to %esi, toss from */
Chris@4: 	jmp	L_while_test
Chris@4: 
Chris@4: L_test_for_end_of_block:
Chris@4: 	test	al, 32
Chris@4: 	jz	L_invalid_literal_length_code
Chris@4: 	mov	dword ptr [rsp+116], 1
Chris@4: 	jmp	L_break_loop_with_status
Chris@4: 
Chris@4: L_invalid_literal_length_code:
Chris@4: 	mov	dword ptr [rsp+116], 2
Chris@4: 	jmp	L_break_loop_with_status
Chris@4: 
Chris@4: L_invalid_distance_code:
Chris@4: 	mov	dword ptr [rsp+116], 3
Chris@4: 	jmp	L_break_loop_with_status
Chris@4: 
Chris@4: L_invalid_distance_too_far:
Chris@4: 	mov	dword ptr [rsp+116], 4
Chris@4: 	jmp	L_break_loop_with_status
Chris@4: 
Chris@4: L_break_loop:
Chris@4: 	mov	dword ptr [rsp+116], 0
Chris@4: 
Chris@4: L_break_loop_with_status:
Chris@4: ; /* put in, out, bits, and hold back into ar and pop esp */
Chris@4: 	mov	[rsp+16], rsi     ; /* in */
Chris@4: 	mov	[rsp+32], rdi     ; /* out */
Chris@4: 	mov	[rsp+88], ebx     ; /* bits */
Chris@4: 	mov	[rsp+80], rdx     ; /* hold */
Chris@4: 
Chris@4: 	mov	rax, [rsp]       ; /* restore rbp and rsp */
Chris@4: 	mov	rbp, [rsp+8]
Chris@4: 	mov	rsp, rax
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4: 	mov rsi,[rsp-8]
Chris@4: 	mov rdi,[rsp-16]
Chris@4: 	mov r12,[rsp-24]
Chris@4: 	mov r13,[rsp-32]
Chris@4: 	mov r14,[rsp-40]
Chris@4: 	mov r15,[rsp-48]
Chris@4: 	mov rbx,[rsp-56]
Chris@4: 
Chris@4:     ret 0
Chris@4: ;          :
Chris@4: ;          : "m" (ar)
Chris@4: ;          : "memory", "%rax", "%rbx", "%rcx", "%rdx", "%rsi", "%rdi",
Chris@4: ;            "%r8", "%r9", "%r10", "%r11", "%r12", "%r13", "%r14", "%r15"
Chris@4: ;    );
Chris@4: 
Chris@4: inffas8664fnc 	ENDP
Chris@4: ;_TEXT	ENDS
Chris@4: END