Chris@4: /*
Chris@4: ;uInt longest_match_x64(
Chris@4: ;    deflate_state *s,
Chris@4: ;    IPos cur_match);                             // current match 
Chris@4: 
Chris@4: ; gvmat64.S -- Asm portion of the optimized longest_match for 32 bits x86_64
Chris@4: ;  (AMD64 on Athlon 64, Opteron, Phenom
Chris@4: ;     and Intel EM64T on Pentium 4 with EM64T, Pentium D, Core 2 Duo, Core I5/I7)
Chris@4: ; this file is translation from gvmat64.asm to GCC 4.x (for Linux, Mac XCode)
Chris@4: ; Copyright (C) 1995-2010 Jean-loup Gailly, Brian Raiter and Gilles Vollant.
Chris@4: ;
Chris@4: ; File written by Gilles Vollant, by converting to assembly the longest_match
Chris@4: ;  from Jean-loup Gailly in deflate.c of zLib and infoZip zip.
Chris@4: ;  and by taking inspiration on asm686 with masm, optimised assembly code
Chris@4: ;        from Brian Raiter, written 1998
Chris@4: ;
Chris@4: ;  This software is provided 'as-is', without any express or implied
Chris@4: ;  warranty.  In no event will the authors be held liable for any damages
Chris@4: ;  arising from the use of this software.
Chris@4: ;
Chris@4: ;  Permission is granted to anyone to use this software for any purpose,
Chris@4: ;  including commercial applications, and to alter it and redistribute it
Chris@4: ;  freely, subject to the following restrictions:
Chris@4: ;
Chris@4: ;  1. The origin of this software must not be misrepresented; you must not
Chris@4: ;     claim that you wrote the original software. If you use this software
Chris@4: ;     in a product, an acknowledgment in the product documentation would be
Chris@4: ;     appreciated but is not required.
Chris@4: ;  2. Altered source versions must be plainly marked as such, and must not be
Chris@4: ;     misrepresented as being the original software
Chris@4: ;  3. This notice may not be removed or altered from any source distribution.
Chris@4: ;
Chris@4: ;         http://www.zlib.net
Chris@4: ;         http://www.winimage.com/zLibDll
Chris@4: ;         http://www.muppetlabs.com/~breadbox/software/assembly.html
Chris@4: ;
Chris@4: ; to compile this file for zLib, I use option:
Chris@4: ;   gcc -c -arch x86_64 gvmat64.S
Chris@4: 
Chris@4: 
Chris@4: ;uInt longest_match(s, cur_match)
Chris@4: ;    deflate_state *s;
Chris@4: ;    IPos cur_match;                             // current match /
Chris@4: ;
Chris@4: ; with XCode for Mac, I had strange error with some jump on intel syntax
Chris@4: ; this is why BEFORE_JMP and AFTER_JMP are used
Chris@4:  */
Chris@4: 
Chris@4: 
Chris@4: #define BEFORE_JMP .att_syntax
Chris@4: #define AFTER_JMP .intel_syntax noprefix
Chris@4: 
Chris@4: #ifndef NO_UNDERLINE
Chris@4: #	define	match_init	_match_init
Chris@4: #	define	longest_match	_longest_match
Chris@4: #endif
Chris@4: 
Chris@4: .intel_syntax noprefix
Chris@4: 
Chris@4: .globl	match_init, longest_match
Chris@4: .text
Chris@4: longest_match:
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4: #define LocalVarsSize 96
Chris@4: /*
Chris@4: ; register used : rax,rbx,rcx,rdx,rsi,rdi,r8,r9,r10,r11,r12
Chris@4: ; free register :  r14,r15
Chris@4: ; register can be saved : rsp
Chris@4: */
Chris@4: 
Chris@4: #define chainlenwmask     (rsp + 8 - LocalVarsSize)
Chris@4: #define nicematch         (rsp + 16 - LocalVarsSize)
Chris@4: 
Chris@4: #define save_rdi        (rsp + 24 - LocalVarsSize)
Chris@4: #define save_rsi        (rsp + 32 - LocalVarsSize)
Chris@4: #define save_rbx        (rsp + 40 - LocalVarsSize)
Chris@4: #define save_rbp        (rsp + 48 - LocalVarsSize)
Chris@4: #define save_r12        (rsp + 56 - LocalVarsSize)
Chris@4: #define save_r13        (rsp + 64 - LocalVarsSize)
Chris@4: #define save_r14        (rsp + 72 - LocalVarsSize)
Chris@4: #define save_r15        (rsp + 80 - LocalVarsSize)
Chris@4: 
Chris@4: 
Chris@4: /*
Chris@4: ;  all the +4 offsets are due to the addition of pending_buf_size (in zlib
Chris@4: ;  in the deflate_state structure since the asm code was first written
Chris@4: ;  (if you compile with zlib 1.0.4 or older, remove the +4).
Chris@4: ;  Note : these value are good with a 8 bytes boundary pack structure
Chris@4: */
Chris@4: 
Chris@4: #define    MAX_MATCH              258
Chris@4: #define    MIN_MATCH              3
Chris@4: #define    MIN_LOOKAHEAD          (MAX_MATCH+MIN_MATCH+1)
Chris@4: 
Chris@4: /*
Chris@4: ;;; Offsets for fields in the deflate_state structure. These numbers
Chris@4: ;;; are calculated from the definition of deflate_state, with the
Chris@4: ;;; assumption that the compiler will dword-align the fields. (Thus,
Chris@4: ;;; changing the definition of deflate_state could easily cause this
Chris@4: ;;; program to crash horribly, without so much as a warning at
Chris@4: ;;; compile time. Sigh.)
Chris@4: 
Chris@4: ;  all the +zlib1222add offsets are due to the addition of fields
Chris@4: ;  in zlib in the deflate_state structure since the asm code was first written
Chris@4: ;  (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").
Chris@4: ;  (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").
Chris@4: ;  if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").
Chris@4: */
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4: /* you can check the structure offset by running
Chris@4: 
Chris@4: #include <stdlib.h>
Chris@4: #include <stdio.h>
Chris@4: #include "deflate.h"
Chris@4: 
Chris@4: void print_depl()
Chris@4: {
Chris@4: deflate_state ds;
Chris@4: deflate_state *s=&ds;
Chris@4: printf("size pointer=%u\n",(int)sizeof(void*));
Chris@4: 
Chris@4: printf("#define dsWSize         %u\n",(int)(((char*)&(s->w_size))-((char*)s)));
Chris@4: printf("#define dsWMask         %u\n",(int)(((char*)&(s->w_mask))-((char*)s)));
Chris@4: printf("#define dsWindow        %u\n",(int)(((char*)&(s->window))-((char*)s)));
Chris@4: printf("#define dsPrev          %u\n",(int)(((char*)&(s->prev))-((char*)s)));
Chris@4: printf("#define dsMatchLen      %u\n",(int)(((char*)&(s->match_length))-((char*)s)));
Chris@4: printf("#define dsPrevMatch     %u\n",(int)(((char*)&(s->prev_match))-((char*)s)));
Chris@4: printf("#define dsStrStart      %u\n",(int)(((char*)&(s->strstart))-((char*)s)));
Chris@4: printf("#define dsMatchStart    %u\n",(int)(((char*)&(s->match_start))-((char*)s)));
Chris@4: printf("#define dsLookahead     %u\n",(int)(((char*)&(s->lookahead))-((char*)s)));
Chris@4: printf("#define dsPrevLen       %u\n",(int)(((char*)&(s->prev_length))-((char*)s)));
Chris@4: printf("#define dsMaxChainLen   %u\n",(int)(((char*)&(s->max_chain_length))-((char*)s)));
Chris@4: printf("#define dsGoodMatch     %u\n",(int)(((char*)&(s->good_match))-((char*)s)));
Chris@4: printf("#define dsNiceMatch     %u\n",(int)(((char*)&(s->nice_match))-((char*)s)));
Chris@4: }
Chris@4: */
Chris@4: 
Chris@4: #define dsWSize          68
Chris@4: #define dsWMask          76
Chris@4: #define dsWindow         80
Chris@4: #define dsPrev           96
Chris@4: #define dsMatchLen       144
Chris@4: #define dsPrevMatch      148
Chris@4: #define dsStrStart       156
Chris@4: #define dsMatchStart     160
Chris@4: #define dsLookahead      164
Chris@4: #define dsPrevLen        168
Chris@4: #define dsMaxChainLen    172
Chris@4: #define dsGoodMatch      188
Chris@4: #define dsNiceMatch      192
Chris@4: 
Chris@4: #define window_size      [ rcx + dsWSize]
Chris@4: #define WMask            [ rcx + dsWMask]
Chris@4: #define window_ad        [ rcx + dsWindow]
Chris@4: #define prev_ad          [ rcx + dsPrev]
Chris@4: #define strstart         [ rcx + dsStrStart]
Chris@4: #define match_start      [ rcx + dsMatchStart]
Chris@4: #define Lookahead        [ rcx + dsLookahead] //; 0ffffffffh on infozip
Chris@4: #define prev_length      [ rcx + dsPrevLen]
Chris@4: #define max_chain_length [ rcx + dsMaxChainLen]
Chris@4: #define good_match       [ rcx + dsGoodMatch]
Chris@4: #define nice_match       [ rcx + dsNiceMatch]
Chris@4: 
Chris@4: /*
Chris@4: ; windows:
Chris@4: ; parameter 1 in rcx(deflate state s), param 2 in rdx (cur match)
Chris@4: 
Chris@4: ; see http://weblogs.asp.net/oldnewthing/archive/2004/01/14/58579.aspx and
Chris@4: ; http://msdn.microsoft.com/library/en-us/kmarch/hh/kmarch/64bitAMD_8e951dd2-ee77-4728-8702-55ce4b5dd24a.xml.asp
Chris@4: ;
Chris@4: ; All registers must be preserved across the call, except for
Chris@4: ;   rax, rcx, rdx, r8, r9, r10, and r11, which are scratch.
Chris@4: 
Chris@4: ;
Chris@4: ; gcc on macosx-linux:
Chris@4: ; see http://www.x86-64.org/documentation/abi-0.99.pdf
Chris@4: ; param 1 in rdi, param 2 in rsi
Chris@4: ; rbx, rsp, rbp, r12 to r15 must be preserved
Chris@4: 
Chris@4: ;;; Save registers that the compiler may be using, and adjust esp to
Chris@4: ;;; make room for our stack frame.
Chris@4: 
Chris@4: 
Chris@4: ;;; Retrieve the function arguments. r8d will hold cur_match
Chris@4: ;;; throughout the entire function. edx will hold the pointer to the
Chris@4: ;;; deflate_state structure during the function's setup (before
Chris@4: ;;; entering the main loop.
Chris@4: 
Chris@4: ; ms: parameter 1 in rcx (deflate_state* s), param 2 in edx -> r8 (cur match)
Chris@4: ; mac: param 1 in rdi, param 2 rsi
Chris@4: ; this clear high 32 bits of r8, which can be garbage in both r8 and rdx
Chris@4: */
Chris@4:         mov [save_rbx],rbx
Chris@4:         mov [save_rbp],rbp
Chris@4: 
Chris@4: 
Chris@4:         mov rcx,rdi
Chris@4: 
Chris@4:         mov r8d,esi
Chris@4: 
Chris@4: 
Chris@4:         mov [save_r12],r12
Chris@4:         mov [save_r13],r13
Chris@4:         mov [save_r14],r14
Chris@4:         mov [save_r15],r15
Chris@4: 
Chris@4: 
Chris@4: //;;; uInt wmask = s->w_mask;
Chris@4: //;;; unsigned chain_length = s->max_chain_length;
Chris@4: //;;; if (s->prev_length >= s->good_match) {
Chris@4: //;;;     chain_length >>= 2;
Chris@4: //;;; }
Chris@4: 
Chris@4: 
Chris@4:         mov edi, prev_length
Chris@4:         mov esi, good_match
Chris@4:         mov eax, WMask
Chris@4:         mov ebx, max_chain_length
Chris@4:         cmp edi, esi
Chris@4:         jl  LastMatchGood
Chris@4:         shr ebx, 2
Chris@4: LastMatchGood:
Chris@4: 
Chris@4: //;;; chainlen is decremented once beforehand so that the function can
Chris@4: //;;; use the sign flag instead of the zero flag for the exit test.
Chris@4: //;;; It is then shifted into the high word, to make room for the wmask
Chris@4: //;;; value, which it will always accompany.
Chris@4: 
Chris@4:         dec ebx
Chris@4:         shl ebx, 16
Chris@4:         or  ebx, eax
Chris@4: 
Chris@4: //;;; on zlib only
Chris@4: //;;; if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead;
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4:         mov eax, nice_match
Chris@4:         mov [chainlenwmask], ebx
Chris@4:         mov r10d, Lookahead
Chris@4:         cmp r10d, eax
Chris@4:         cmovnl r10d, eax
Chris@4:         mov [nicematch],r10d
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4: //;;; register Bytef *scan = s->window + s->strstart;
Chris@4:         mov r10, window_ad
Chris@4:         mov ebp, strstart
Chris@4:         lea r13, [r10 + rbp]
Chris@4: 
Chris@4: //;;; Determine how many bytes the scan ptr is off from being
Chris@4: //;;; dword-aligned.
Chris@4: 
Chris@4:          mov r9,r13
Chris@4:          neg r13
Chris@4:          and r13,3
Chris@4: 
Chris@4: //;;; IPos limit = s->strstart > (IPos)MAX_DIST(s) ?
Chris@4: //;;;     s->strstart - (IPos)MAX_DIST(s) : NIL;
Chris@4: 
Chris@4: 
Chris@4:         mov eax, window_size
Chris@4:         sub eax, MIN_LOOKAHEAD
Chris@4: 
Chris@4: 
Chris@4:         xor edi,edi
Chris@4:         sub ebp, eax
Chris@4: 
Chris@4:         mov r11d, prev_length
Chris@4: 
Chris@4:         cmovng ebp,edi
Chris@4: 
Chris@4: //;;; int best_len = s->prev_length;
Chris@4: 
Chris@4: 
Chris@4: //;;; Store the sum of s->window + best_len in esi locally, and in esi.
Chris@4: 
Chris@4:        lea  rsi,[r10+r11]
Chris@4: 
Chris@4: //;;; register ush scan_start = *(ushf*)scan;
Chris@4: //;;; register ush scan_end   = *(ushf*)(scan+best_len-1);
Chris@4: //;;; Posf *prev = s->prev;
Chris@4: 
Chris@4:         movzx r12d,word ptr [r9]
Chris@4:         movzx ebx, word ptr [r9 + r11 - 1]
Chris@4: 
Chris@4:         mov rdi, prev_ad
Chris@4: 
Chris@4: //;;; Jump into the main loop.
Chris@4: 
Chris@4:         mov edx, [chainlenwmask]
Chris@4: 
Chris@4:         cmp bx,word ptr [rsi + r8 - 1]
Chris@4:         jz  LookupLoopIsZero
Chris@4: 				
Chris@4: 						
Chris@4: 						
Chris@4: LookupLoop1:
Chris@4:         and r8d, edx
Chris@4: 
Chris@4:         movzx   r8d, word ptr [rdi + r8*2]
Chris@4:         cmp r8d, ebp
Chris@4:         jbe LeaveNow
Chris@4: 		
Chris@4: 		
Chris@4: 		
Chris@4:         sub edx, 0x00010000
Chris@4: 		BEFORE_JMP
Chris@4:         js  LeaveNow
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LoopEntry1:
Chris@4:         cmp bx,word ptr [rsi + r8 - 1]
Chris@4: 		BEFORE_JMP
Chris@4:         jz  LookupLoopIsZero
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LookupLoop2:
Chris@4:         and r8d, edx
Chris@4: 
Chris@4:         movzx   r8d, word ptr [rdi + r8*2]
Chris@4:         cmp r8d, ebp
Chris@4: 		BEFORE_JMP
Chris@4:         jbe LeaveNow
Chris@4: 		AFTER_JMP
Chris@4:         sub edx, 0x00010000
Chris@4: 		BEFORE_JMP
Chris@4:         js  LeaveNow
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LoopEntry2:
Chris@4:         cmp bx,word ptr [rsi + r8 - 1]
Chris@4: 		BEFORE_JMP
Chris@4:         jz  LookupLoopIsZero
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LookupLoop4:
Chris@4:         and r8d, edx
Chris@4: 
Chris@4:         movzx   r8d, word ptr [rdi + r8*2]
Chris@4:         cmp r8d, ebp
Chris@4: 		BEFORE_JMP
Chris@4:         jbe LeaveNow
Chris@4: 		AFTER_JMP
Chris@4:         sub edx, 0x00010000
Chris@4: 		BEFORE_JMP
Chris@4:         js  LeaveNow
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LoopEntry4:
Chris@4: 
Chris@4:         cmp bx,word ptr [rsi + r8 - 1]
Chris@4: 		BEFORE_JMP
Chris@4:         jnz LookupLoop1
Chris@4:         jmp LookupLoopIsZero
Chris@4: 		AFTER_JMP
Chris@4: /*
Chris@4: ;;; do {
Chris@4: ;;;     match = s->window + cur_match;
Chris@4: ;;;     if (*(ushf*)(match+best_len-1) != scan_end ||
Chris@4: ;;;         *(ushf*)match != scan_start) continue;
Chris@4: ;;;     [...]
Chris@4: ;;; } while ((cur_match = prev[cur_match & wmask]) > limit
Chris@4: ;;;          && --chain_length != 0);
Chris@4: ;;;
Chris@4: ;;; Here is the inner loop of the function. The function will spend the
Chris@4: ;;; majority of its time in this loop, and majority of that time will
Chris@4: ;;; be spent in the first ten instructions.
Chris@4: ;;;
Chris@4: ;;; Within this loop:
Chris@4: ;;; ebx = scanend
Chris@4: ;;; r8d = curmatch
Chris@4: ;;; edx = chainlenwmask - i.e., ((chainlen << 16) | wmask)
Chris@4: ;;; esi = windowbestlen - i.e., (window + bestlen)
Chris@4: ;;; edi = prev
Chris@4: ;;; ebp = limit
Chris@4: */
Chris@4: .balign 16
Chris@4: LookupLoop:
Chris@4:         and r8d, edx
Chris@4: 
Chris@4:         movzx   r8d, word ptr [rdi + r8*2]
Chris@4:         cmp r8d, ebp
Chris@4: 		BEFORE_JMP
Chris@4:         jbe LeaveNow
Chris@4: 		AFTER_JMP
Chris@4:         sub edx, 0x00010000
Chris@4: 		BEFORE_JMP
Chris@4:         js  LeaveNow
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LoopEntry:
Chris@4: 
Chris@4:         cmp bx,word ptr [rsi + r8 - 1]
Chris@4: 		BEFORE_JMP
Chris@4:         jnz LookupLoop1
Chris@4: 		AFTER_JMP
Chris@4: LookupLoopIsZero:
Chris@4:         cmp     r12w, word ptr [r10 + r8]
Chris@4: 		BEFORE_JMP
Chris@4:         jnz LookupLoop1
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: 
Chris@4: //;;; Store the current value of chainlen.
Chris@4:         mov [chainlenwmask], edx
Chris@4: /*
Chris@4: ;;; Point edi to the string under scrutiny, and esi to the string we
Chris@4: ;;; are hoping to match it up with. In actuality, esi and edi are
Chris@4: ;;; both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and edx is
Chris@4: ;;; initialized to -(MAX_MATCH_8 - scanalign).
Chris@4: */
Chris@4:         lea rsi,[r8+r10]
Chris@4:         mov rdx, 0xfffffffffffffef8 //; -(MAX_MATCH_8)
Chris@4:         lea rsi, [rsi + r13 + 0x0108] //;MAX_MATCH_8]
Chris@4:         lea rdi, [r9 + r13 + 0x0108] //;MAX_MATCH_8]
Chris@4: 
Chris@4:         prefetcht1 [rsi+rdx]
Chris@4:         prefetcht1 [rdi+rdx]
Chris@4: 
Chris@4: /*
Chris@4: ;;; Test the strings for equality, 8 bytes at a time. At the end,
Chris@4: ;;; adjust rdx so that it is offset to the exact byte that mismatched.
Chris@4: ;;;
Chris@4: ;;; We already know at this point that the first three bytes of the
Chris@4: ;;; strings match each other, and they can be safely passed over before
Chris@4: ;;; starting the compare loop. So what this code does is skip over 0-3
Chris@4: ;;; bytes, as much as necessary in order to dword-align the edi
Chris@4: ;;; pointer. (rsi will still be misaligned three times out of four.)
Chris@4: ;;;
Chris@4: ;;; It should be confessed that this loop usually does not represent
Chris@4: ;;; much of the total running time. Replacing it with a more
Chris@4: ;;; straightforward "rep cmpsb" would not drastically degrade
Chris@4: ;;; performance.
Chris@4: */
Chris@4: 
Chris@4: LoopCmps:
Chris@4:         mov rax, [rsi + rdx]
Chris@4:         xor rax, [rdi + rdx]
Chris@4:         jnz LeaveLoopCmps
Chris@4: 
Chris@4:         mov rax, [rsi + rdx + 8]
Chris@4:         xor rax, [rdi + rdx + 8]
Chris@4:         jnz LeaveLoopCmps8
Chris@4: 
Chris@4: 
Chris@4:         mov rax, [rsi + rdx + 8+8]
Chris@4:         xor rax, [rdi + rdx + 8+8]
Chris@4:         jnz LeaveLoopCmps16
Chris@4: 
Chris@4:         add rdx,8+8+8
Chris@4: 
Chris@4: 		BEFORE_JMP
Chris@4:         jnz  LoopCmps
Chris@4:         jmp  LenMaximum
Chris@4: 		AFTER_JMP
Chris@4: 		
Chris@4: LeaveLoopCmps16: add rdx,8
Chris@4: LeaveLoopCmps8: add rdx,8
Chris@4: LeaveLoopCmps:
Chris@4: 
Chris@4:         test    eax, 0x0000FFFF
Chris@4:         jnz LenLower
Chris@4: 
Chris@4:         test eax,0xffffffff
Chris@4: 
Chris@4:         jnz LenLower32
Chris@4: 
Chris@4:         add rdx,4
Chris@4:         shr rax,32
Chris@4:         or ax,ax
Chris@4: 		BEFORE_JMP
Chris@4:         jnz LenLower
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: LenLower32:
Chris@4:         shr eax,16
Chris@4:         add rdx,2
Chris@4: 		
Chris@4: LenLower:		
Chris@4:         sub al, 1
Chris@4:         adc rdx, 0
Chris@4: //;;; Calculate the length of the match. If it is longer than MAX_MATCH,
Chris@4: //;;; then automatically accept it as the best possible match and leave.
Chris@4: 
Chris@4:         lea rax, [rdi + rdx]
Chris@4:         sub rax, r9
Chris@4:         cmp eax, MAX_MATCH
Chris@4: 		BEFORE_JMP
Chris@4:         jge LenMaximum
Chris@4: 		AFTER_JMP
Chris@4: /*
Chris@4: ;;; If the length of the match is not longer than the best match we
Chris@4: ;;; have so far, then forget it and return to the lookup loop.
Chris@4: ;///////////////////////////////////
Chris@4: */
Chris@4:         cmp eax, r11d
Chris@4:         jg  LongerMatch
Chris@4: 
Chris@4:         lea rsi,[r10+r11]
Chris@4: 
Chris@4:         mov rdi, prev_ad
Chris@4:         mov edx, [chainlenwmask]
Chris@4: 		BEFORE_JMP
Chris@4:         jmp LookupLoop
Chris@4: 		AFTER_JMP
Chris@4: /*
Chris@4: ;;;         s->match_start = cur_match;
Chris@4: ;;;         best_len = len;
Chris@4: ;;;         if (len >= nice_match) break;
Chris@4: ;;;         scan_end = *(ushf*)(scan+best_len-1);
Chris@4: */
Chris@4: LongerMatch:
Chris@4:         mov r11d, eax
Chris@4:         mov match_start, r8d
Chris@4:         cmp eax, [nicematch]
Chris@4: 		BEFORE_JMP
Chris@4:         jge LeaveNow
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4:         lea rsi,[r10+rax]
Chris@4: 
Chris@4:         movzx   ebx, word ptr [r9 + rax - 1]
Chris@4:         mov rdi, prev_ad
Chris@4:         mov edx, [chainlenwmask]
Chris@4: 		BEFORE_JMP
Chris@4:         jmp LookupLoop
Chris@4: 		AFTER_JMP
Chris@4: 
Chris@4: //;;; Accept the current string, with the maximum possible length.
Chris@4: 
Chris@4: LenMaximum:
Chris@4:         mov r11d,MAX_MATCH
Chris@4:         mov match_start, r8d
Chris@4: 
Chris@4: //;;; if ((uInt)best_len <= s->lookahead) return (uInt)best_len;
Chris@4: //;;; return s->lookahead;
Chris@4: 
Chris@4: LeaveNow:
Chris@4:         mov eax, Lookahead
Chris@4:         cmp r11d, eax
Chris@4:         cmovng eax, r11d
Chris@4: 
Chris@4: 
Chris@4: 
Chris@4: //;;; Restore the stack and return from whence we came.
Chris@4: 
Chris@4: 
Chris@4: //        mov rsi,[save_rsi]
Chris@4: //        mov rdi,[save_rdi]
Chris@4:         mov rbx,[save_rbx]
Chris@4:         mov rbp,[save_rbp]
Chris@4:         mov r12,[save_r12]
Chris@4:         mov r13,[save_r13]
Chris@4:         mov r14,[save_r14]
Chris@4:         mov r15,[save_r15]
Chris@4: 
Chris@4: 
Chris@4:         ret 0
Chris@4: //; please don't remove this string !
Chris@4: //; Your can freely use gvmat64 in any free or commercial app
Chris@4: //; but it is far better don't remove the string in the binary!
Chris@4:  //   db     0dh,0ah,"asm686 with masm, optimised assembly code from Brian Raiter, written 1998, converted to amd 64 by Gilles Vollant 2005",0dh,0ah,0
Chris@4: 
Chris@4: 
Chris@4: match_init:
Chris@4:   ret 0
Chris@4: 
Chris@4: