Chris@0: # ltsugar.m4 -- libtool m4 base layer.                         -*-Autoconf-*-
Chris@0: #
Chris@0: # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
Chris@0: # Written by Gary V. Vaughan, 2004
Chris@0: #
Chris@0: # This file is free software; the Free Software Foundation gives
Chris@0: # unlimited permission to copy and/or distribute it, with or without
Chris@0: # modifications, as long as this notice is preserved.
Chris@0: 
Chris@0: # serial 6 ltsugar.m4
Chris@0: 
Chris@0: # This is to help aclocal find these macros, as it can't see m4_define.
Chris@0: AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
Chris@0: 
Chris@0: 
Chris@0: # lt_join(SEP, ARG1, [ARG2...])
Chris@0: # -----------------------------
Chris@0: # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
Chris@0: # associated separator.
Chris@0: # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
Chris@0: # versions in m4sugar had bugs.
Chris@0: m4_define([lt_join],
Chris@0: [m4_if([$#], [1], [],
Chris@0:        [$#], [2], [[$2]],
Chris@0:        [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
Chris@0: m4_define([_lt_join],
Chris@0: [m4_if([$#$2], [2], [],
Chris@0:        [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
Chris@0: 
Chris@0: 
Chris@0: # lt_car(LIST)
Chris@0: # lt_cdr(LIST)
Chris@0: # ------------
Chris@0: # Manipulate m4 lists.
Chris@0: # These macros are necessary as long as will still need to support
Chris@0: # Autoconf-2.59 which quotes differently.
Chris@0: m4_define([lt_car], [[$1]])
Chris@0: m4_define([lt_cdr],
Chris@0: [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
Chris@0:        [$#], 1, [],
Chris@0:        [m4_dquote(m4_shift($@))])])
Chris@0: m4_define([lt_unquote], $1)
Chris@0: 
Chris@0: 
Chris@0: # lt_append(MACRO-NAME, STRING, [SEPARATOR])
Chris@0: # ------------------------------------------
Chris@0: # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
Chris@0: # Note that neither SEPARATOR nor STRING are expanded; they are appended
Chris@0: # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
Chris@0: # No SEPARATOR is output if MACRO-NAME was previously undefined (different
Chris@0: # than defined and empty).
Chris@0: #
Chris@0: # This macro is needed until we can rely on Autoconf 2.62, since earlier
Chris@0: # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
Chris@0: m4_define([lt_append],
Chris@0: [m4_define([$1],
Chris@0: 	   m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
Chris@0: 
Chris@0: 
Chris@0: 
Chris@0: # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
Chris@0: # ----------------------------------------------------------
Chris@0: # Produce a SEP delimited list of all paired combinations of elements of
Chris@0: # PREFIX-LIST with SUFFIX1 through SUFFIXn.  Each element of the list
Chris@0: # has the form PREFIXmINFIXSUFFIXn.
Chris@0: # Needed until we can rely on m4_combine added in Autoconf 2.62.
Chris@0: m4_define([lt_combine],
Chris@0: [m4_if(m4_eval([$# > 3]), [1],
Chris@0:        [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
Chris@0: [[m4_foreach([_Lt_prefix], [$2],
Chris@0: 	     [m4_foreach([_Lt_suffix],
Chris@0: 		]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
Chris@0: 	[_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
Chris@0: 
Chris@0: 
Chris@0: # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
Chris@0: # -----------------------------------------------------------------------
Chris@0: # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
Chris@0: # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
Chris@0: m4_define([lt_if_append_uniq],
Chris@0: [m4_ifdef([$1],
Chris@0: 	  [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
Chris@0: 		 [lt_append([$1], [$2], [$3])$4],
Chris@0: 		 [$5])],
Chris@0: 	  [lt_append([$1], [$2], [$3])$4])])
Chris@0: 
Chris@0: 
Chris@0: # lt_dict_add(DICT, KEY, VALUE)
Chris@0: # -----------------------------
Chris@0: m4_define([lt_dict_add],
Chris@0: [m4_define([$1($2)], [$3])])
Chris@0: 
Chris@0: 
Chris@0: # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
Chris@0: # --------------------------------------------
Chris@0: m4_define([lt_dict_add_subkey],
Chris@0: [m4_define([$1($2:$3)], [$4])])
Chris@0: 
Chris@0: 
Chris@0: # lt_dict_fetch(DICT, KEY, [SUBKEY])
Chris@0: # ----------------------------------
Chris@0: m4_define([lt_dict_fetch],
Chris@0: [m4_ifval([$3],
Chris@0: 	m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
Chris@0:     m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
Chris@0: 
Chris@0: 
Chris@0: # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
Chris@0: # -----------------------------------------------------------------
Chris@0: m4_define([lt_if_dict_fetch],
Chris@0: [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
Chris@0: 	[$5],
Chris@0:     [$6])])
Chris@0: 
Chris@0: 
Chris@0: # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
Chris@0: # --------------------------------------------------------------
Chris@0: m4_define([lt_dict_filter],
Chris@0: [m4_if([$5], [], [],
Chris@0:   [lt_join(m4_quote(m4_default([$4], [[, ]])),
Chris@0:            lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
Chris@0: 		      [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
Chris@0: ])