Chris@10: dnl @synopsis ACX_MPI([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
Chris@10: dnl @summary figure out how to compile/link code with MPI
Chris@10: dnl @category InstalledPackages
Chris@10: dnl
Chris@10: dnl This macro tries to find out how to compile programs that
Chris@10: dnl use MPI (Message Passing Interface), a standard API for
Chris@10: dnl parallel process communication (see http://www-unix.mcs.anl.gov/mpi/)
Chris@10: dnl
Chris@10: dnl On success, it sets the MPICC, MPICXX, or MPIF77 output variable to
Chris@10: dnl the name of the MPI compiler, depending upon the current language.
Chris@10: dnl (This may just be $CC/$CXX/$F77, but is more often something like
Chris@10: dnl mpicc/mpiCC/mpif77.)  It also sets MPILIBS to any libraries that are
Chris@10: dnl needed for linking MPI (e.g. -lmpi, if a special MPICC/MPICXX/MPIF77
Chris@10: dnl was not found).
Chris@10: dnl
Chris@10: dnl If you want to compile everything with MPI, you should set:
Chris@10: dnl
Chris@10: dnl     CC="$MPICC" #OR# CXX="$MPICXX" #OR# F77="$MPIF77"
Chris@10: dnl     LIBS="$MPILIBS $LIBS"
Chris@10: dnl
Chris@10: dnl NOTE: The above assumes that you will use $CC (or whatever)
Chris@10: dnl       for linking as well as for compiling.  (This is the
Chris@10: dnl       default for automake and most Makefiles.)
Chris@10: dnl
Chris@10: dnl The user can force a particular library/compiler by setting the
Chris@10: dnl MPICC/MPICXX/MPIF77 and/or MPILIBS environment variables.
Chris@10: dnl
Chris@10: dnl ACTION-IF-FOUND is a list of shell commands to run if an MPI
Chris@10: dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
Chris@10: dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
Chris@10: dnl the default action will define HAVE_MPI.
Chris@10: dnl
Chris@10: dnl @version 2005-09-02
Chris@10: dnl @license GPLWithACException
Chris@10: dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
Chris@10: 
Chris@10: AC_DEFUN([ACX_MPI], [
Chris@10: AC_PREREQ(2.50) dnl for AC_LANG_CASE
Chris@10: 
Chris@10: AC_LANG_CASE([C], [
Chris@10: 	AC_REQUIRE([AC_PROG_CC])
Chris@10: 	AC_ARG_VAR(MPICC,[MPI C compiler command])
Chris@10: 	AC_CHECK_PROGS(MPICC, mpicc hcc mpcc mpcc_r mpxlc cmpicc, $CC)
Chris@10: 	acx_mpi_save_CC="$CC"
Chris@10: 	CC="$MPICC"
Chris@10: 	AC_SUBST(MPICC)
Chris@10: ],
Chris@10: [C++], [
Chris@10: 	AC_REQUIRE([AC_PROG_CXX])
Chris@10: 	AC_ARG_VAR(MPICXX,[MPI C++ compiler command])
Chris@10: 	AC_CHECK_PROGS(MPICXX, mpic++ mpiCC mpicxx mpCC hcp mpxlC mpxlC_r cmpic++, $CXX)
Chris@10: 	acx_mpi_save_CXX="$CXX"
Chris@10: 	CXX="$MPICXX"
Chris@10: 	AC_SUBST(MPICXX)
Chris@10: ],
Chris@10: [Fortran 77], [
Chris@10: 	AC_REQUIRE([AC_PROG_F77])
Chris@10: 	AC_ARG_VAR(MPIF77,[MPI Fortran compiler command])
Chris@10: 	AC_CHECK_PROGS(MPIF77, mpif77 hf77 mpxlf mpf77 mpif90 mpf90 mpxlf90 mpxlf95 mpxlf_r cmpifc cmpif90c, $F77)
Chris@10: 	acx_mpi_save_F77="$F77"
Chris@10: 	F77="$MPIF77"
Chris@10: 	AC_SUBST(MPIF77)
Chris@10: ])
Chris@10: 
Chris@10: if test x = x"$MPILIBS"; then
Chris@10: 	AC_LANG_CASE([C], [AC_CHECK_FUNC(MPI_Init, [MPILIBS=" "])],
Chris@10: 		[C++], [AC_CHECK_FUNC(MPI_Init, [MPILIBS=" "])],
Chris@10: 		[Fortran 77], [AC_MSG_CHECKING([for MPI_Init])
Chris@10: 			AC_TRY_LINK([],[      call MPI_Init], [MPILIBS=" "
Chris@10: 				AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)])])
Chris@10: fi
Chris@10: if test x = x"$MPILIBS"; then
Chris@10: 	AC_CHECK_LIB(mpi, MPI_Init, [MPILIBS="-lmpi"])
Chris@10: fi
Chris@10: if test x = x"$MPILIBS"; then
Chris@10: 	AC_CHECK_LIB(mpich, MPI_Init, [MPILIBS="-lmpich"])
Chris@10: fi
Chris@10: 
Chris@10: dnl We have to use AC_TRY_COMPILE and not AC_CHECK_HEADER because the
Chris@10: dnl latter uses $CPP, not $CC (which may be mpicc).
Chris@10: AC_LANG_CASE([C], [if test x != x"$MPILIBS"; then
Chris@10: 	AC_MSG_CHECKING([for mpi.h])
Chris@10: 	AC_TRY_COMPILE([#include <mpi.h>],[],[AC_MSG_RESULT(yes)], [MPILIBS=""
Chris@10: 		AC_MSG_RESULT(no)])
Chris@10: fi],
Chris@10: [C++], [if test x != x"$MPILIBS"; then
Chris@10: 	AC_MSG_CHECKING([for mpi.h])
Chris@10: 	AC_TRY_COMPILE([#include <mpi.h>],[],[AC_MSG_RESULT(yes)], [MPILIBS=""
Chris@10: 		AC_MSG_RESULT(no)])
Chris@10: fi])
Chris@10: 
Chris@10: AC_LANG_CASE([C], [CC="$acx_mpi_save_CC"],
Chris@10: 	[C++], [CXX="$acx_mpi_save_CXX"],
Chris@10: 	[Fortran 77], [F77="$acx_mpi_save_F77"])
Chris@10: 
Chris@10: AC_SUBST(MPILIBS)
Chris@10: 
Chris@10: # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
Chris@10: if test x = x"$MPILIBS"; then
Chris@10:         $2
Chris@10:         :
Chris@10: else
Chris@10:         ifelse([$1],,[AC_DEFINE(HAVE_MPI,1,[Define if you have the MPI library.])],[$1])
Chris@10:         :
Chris@10: fi
Chris@10: ])dnl ACX_MPI