Chris@41: # Helper functions for option handling.                    -*- Autoconf -*-
Chris@41: #
Chris@41: #   Copyright (C) 2004-2005, 2007-2009, 2011-2015 Free Software
Chris@41: #   Foundation, Inc.
Chris@41: #   Written by Gary V. Vaughan, 2004
Chris@41: #
Chris@41: # This file is free software; the Free Software Foundation gives
Chris@41: # unlimited permission to copy and/or distribute it, with or without
Chris@41: # modifications, as long as this notice is preserved.
Chris@41: 
Chris@41: # serial 8 ltoptions.m4
Chris@41: 
Chris@41: # This is to help aclocal find these macros, as it can't see m4_define.
Chris@41: AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
Chris@41: 
Chris@41: 
Chris@41: # _LT_MANGLE_OPTION(MACRO-NAME, OPTION-NAME)
Chris@41: # ------------------------------------------
Chris@41: m4_define([_LT_MANGLE_OPTION],
Chris@41: [[_LT_OPTION_]m4_bpatsubst($1__$2, [[^a-zA-Z0-9_]], [_])])
Chris@41: 
Chris@41: 
Chris@41: # _LT_SET_OPTION(MACRO-NAME, OPTION-NAME)
Chris@41: # ---------------------------------------
Chris@41: # Set option OPTION-NAME for macro MACRO-NAME, and if there is a
Chris@41: # matching handler defined, dispatch to it.  Other OPTION-NAMEs are
Chris@41: # saved as a flag.
Chris@41: m4_define([_LT_SET_OPTION],
Chris@41: [m4_define(_LT_MANGLE_OPTION([$1], [$2]))dnl
Chris@41: m4_ifdef(_LT_MANGLE_DEFUN([$1], [$2]),
Chris@41:         _LT_MANGLE_DEFUN([$1], [$2]),
Chris@41:     [m4_warning([Unknown $1 option '$2'])])[]dnl
Chris@41: ])
Chris@41: 
Chris@41: 
Chris@41: # _LT_IF_OPTION(MACRO-NAME, OPTION-NAME, IF-SET, [IF-NOT-SET])
Chris@41: # ------------------------------------------------------------
Chris@41: # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
Chris@41: m4_define([_LT_IF_OPTION],
Chris@41: [m4_ifdef(_LT_MANGLE_OPTION([$1], [$2]), [$3], [$4])])
Chris@41: 
Chris@41: 
Chris@41: # _LT_UNLESS_OPTIONS(MACRO-NAME, OPTION-LIST, IF-NOT-SET)
Chris@41: # -------------------------------------------------------
Chris@41: # Execute IF-NOT-SET unless all options in OPTION-LIST for MACRO-NAME
Chris@41: # are set.
Chris@41: m4_define([_LT_UNLESS_OPTIONS],
Chris@41: [m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
Chris@41: 	    [m4_ifdef(_LT_MANGLE_OPTION([$1], _LT_Option),
Chris@41: 		      [m4_define([$0_found])])])[]dnl
Chris@41: m4_ifdef([$0_found], [m4_undefine([$0_found])], [$3
Chris@41: ])[]dnl
Chris@41: ])
Chris@41: 
Chris@41: 
Chris@41: # _LT_SET_OPTIONS(MACRO-NAME, OPTION-LIST)
Chris@41: # ----------------------------------------
Chris@41: # OPTION-LIST is a space-separated list of Libtool options associated
Chris@41: # with MACRO-NAME.  If any OPTION has a matching handler declared with
Chris@41: # LT_OPTION_DEFINE, dispatch to that macro; otherwise complain about
Chris@41: # the unknown option and exit.
Chris@41: m4_defun([_LT_SET_OPTIONS],
Chris@41: [# Set options
Chris@41: m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
Chris@41:     [_LT_SET_OPTION([$1], _LT_Option)])
Chris@41: 
Chris@41: m4_if([$1],[LT_INIT],[
Chris@41:   dnl
Chris@41:   dnl Simply set some default values (i.e off) if boolean options were not
Chris@41:   dnl specified:
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
Chris@41:   ])
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
Chris@41:   ])
Chris@41:   dnl
Chris@41:   dnl If no reference was made to various pairs of opposing options, then
Chris@41:   dnl we run the default mode handler for the pair.  For example, if neither
Chris@41:   dnl 'shared' nor 'disable-shared' was passed, we enable building of shared
Chris@41:   dnl archives by default:
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
Chris@41: 		   [_LT_ENABLE_FAST_INSTALL])
Chris@41:   _LT_UNLESS_OPTIONS([LT_INIT], [aix-soname=aix aix-soname=both aix-soname=svr4],
Chris@41: 		   [_LT_WITH_AIX_SONAME([aix])])
Chris@41:   ])
Chris@41: ])# _LT_SET_OPTIONS
Chris@41: 
Chris@41: 
Chris@41: ## --------------------------------- ##
Chris@41: ## Macros to handle LT_INIT options. ##
Chris@41: ## --------------------------------- ##
Chris@41: 
Chris@41: # _LT_MANGLE_DEFUN(MACRO-NAME, OPTION-NAME)
Chris@41: # -----------------------------------------
Chris@41: m4_define([_LT_MANGLE_DEFUN],
Chris@41: [[_LT_OPTION_DEFUN_]m4_bpatsubst(m4_toupper([$1__$2]), [[^A-Z0-9_]], [_])])
Chris@41: 
Chris@41: 
Chris@41: # LT_OPTION_DEFINE(MACRO-NAME, OPTION-NAME, CODE)
Chris@41: # -----------------------------------------------
Chris@41: m4_define([LT_OPTION_DEFINE],
Chris@41: [m4_define(_LT_MANGLE_DEFUN([$1], [$2]), [$3])[]dnl
Chris@41: ])# LT_OPTION_DEFINE
Chris@41: 
Chris@41: 
Chris@41: # dlopen
Chris@41: # ------
Chris@41: LT_OPTION_DEFINE([LT_INIT], [dlopen], [enable_dlopen=yes
Chris@41: ])
Chris@41: 
Chris@41: AU_DEFUN([AC_LIBTOOL_DLOPEN],
Chris@41: [_LT_SET_OPTION([LT_INIT], [dlopen])
Chris@41: AC_DIAGNOSE([obsolete],
Chris@41: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@41: put the 'dlopen' option into LT_INIT's first parameter.])
Chris@41: ])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AC_LIBTOOL_DLOPEN], [])
Chris@41: 
Chris@41: 
Chris@41: # win32-dll
Chris@41: # ---------
Chris@41: # Declare package support for building win32 dll's.
Chris@41: LT_OPTION_DEFINE([LT_INIT], [win32-dll],
Chris@41: [enable_win32_dll=yes
Chris@41: 
Chris@41: case $host in
Chris@41: *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-cegcc*)
Chris@41:   AC_CHECK_TOOL(AS, as, false)
Chris@41:   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
Chris@41:   AC_CHECK_TOOL(OBJDUMP, objdump, false)
Chris@41:   ;;
Chris@41: esac
Chris@41: 
Chris@41: test -z "$AS" && AS=as
Chris@41: _LT_DECL([], [AS],      [1], [Assembler program])dnl
Chris@41: 
Chris@41: test -z "$DLLTOOL" && DLLTOOL=dlltool
Chris@41: _LT_DECL([], [DLLTOOL], [1], [DLL creation program])dnl
Chris@41: 
Chris@41: test -z "$OBJDUMP" && OBJDUMP=objdump
Chris@41: _LT_DECL([], [OBJDUMP], [1], [Object dumper program])dnl
Chris@41: ])# win32-dll
Chris@41: 
Chris@41: AU_DEFUN([AC_LIBTOOL_WIN32_DLL],
Chris@41: [AC_REQUIRE([AC_CANONICAL_HOST])dnl
Chris@41: _LT_SET_OPTION([LT_INIT], [win32-dll])
Chris@41: AC_DIAGNOSE([obsolete],
Chris@41: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@41: put the 'win32-dll' option into LT_INIT's first parameter.])
Chris@41: ])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AC_LIBTOOL_WIN32_DLL], [])
Chris@41: 
Chris@41: 
Chris@41: # _LT_ENABLE_SHARED([DEFAULT])
Chris@41: # ----------------------------
Chris@41: # implement the --enable-shared flag, and supports the 'shared' and
Chris@41: # 'disable-shared' LT_INIT options.
Chris@41: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@41: m4_define([_LT_ENABLE_SHARED],
Chris@41: [m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@41: AC_ARG_ENABLE([shared],
Chris@41:     [AS_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
Chris@41: 	[build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
Chris@41:     [p=${PACKAGE-default}
Chris@41:     case $enableval in
Chris@41:     yes) enable_shared=yes ;;
Chris@41:     no) enable_shared=no ;;
Chris@41:     *)
Chris@41:       enable_shared=no
Chris@41:       # Look at the argument we got.  We use all the common list separators.
Chris@41:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@41:       for pkg in $enableval; do
Chris@41: 	IFS=$lt_save_ifs
Chris@41: 	if test "X$pkg" = "X$p"; then
Chris@41: 	  enable_shared=yes
Chris@41: 	fi
Chris@41:       done
Chris@41:       IFS=$lt_save_ifs
Chris@41:       ;;
Chris@41:     esac],
Chris@41:     [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
Chris@41: 
Chris@41:     _LT_DECL([build_libtool_libs], [enable_shared], [0],
Chris@41: 	[Whether or not to build shared libraries])
Chris@41: ])# _LT_ENABLE_SHARED
Chris@41: 
Chris@41: LT_OPTION_DEFINE([LT_INIT], [shared], [_LT_ENABLE_SHARED([yes])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [disable-shared], [_LT_ENABLE_SHARED([no])])
Chris@41: 
Chris@41: # Old names:
Chris@41: AC_DEFUN([AC_ENABLE_SHARED],
Chris@41: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[shared])
Chris@41: ])
Chris@41: 
Chris@41: AC_DEFUN([AC_DISABLE_SHARED],
Chris@41: [_LT_SET_OPTION([LT_INIT], [disable-shared])
Chris@41: ])
Chris@41: 
Chris@41: AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
Chris@41: AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AM_ENABLE_SHARED], [])
Chris@41: dnl AC_DEFUN([AM_DISABLE_SHARED], [])
Chris@41: 
Chris@41: 
Chris@41: 
Chris@41: # _LT_ENABLE_STATIC([DEFAULT])
Chris@41: # ----------------------------
Chris@41: # implement the --enable-static flag, and support the 'static' and
Chris@41: # 'disable-static' LT_INIT options.
Chris@41: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@41: m4_define([_LT_ENABLE_STATIC],
Chris@41: [m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@41: AC_ARG_ENABLE([static],
Chris@41:     [AS_HELP_STRING([--enable-static@<:@=PKGS@:>@],
Chris@41: 	[build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
Chris@41:     [p=${PACKAGE-default}
Chris@41:     case $enableval in
Chris@41:     yes) enable_static=yes ;;
Chris@41:     no) enable_static=no ;;
Chris@41:     *)
Chris@41:      enable_static=no
Chris@41:       # Look at the argument we got.  We use all the common list separators.
Chris@41:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@41:       for pkg in $enableval; do
Chris@41: 	IFS=$lt_save_ifs
Chris@41: 	if test "X$pkg" = "X$p"; then
Chris@41: 	  enable_static=yes
Chris@41: 	fi
Chris@41:       done
Chris@41:       IFS=$lt_save_ifs
Chris@41:       ;;
Chris@41:     esac],
Chris@41:     [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
Chris@41: 
Chris@41:     _LT_DECL([build_old_libs], [enable_static], [0],
Chris@41: 	[Whether or not to build static libraries])
Chris@41: ])# _LT_ENABLE_STATIC
Chris@41: 
Chris@41: LT_OPTION_DEFINE([LT_INIT], [static], [_LT_ENABLE_STATIC([yes])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [disable-static], [_LT_ENABLE_STATIC([no])])
Chris@41: 
Chris@41: # Old names:
Chris@41: AC_DEFUN([AC_ENABLE_STATIC],
Chris@41: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[static])
Chris@41: ])
Chris@41: 
Chris@41: AC_DEFUN([AC_DISABLE_STATIC],
Chris@41: [_LT_SET_OPTION([LT_INIT], [disable-static])
Chris@41: ])
Chris@41: 
Chris@41: AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
Chris@41: AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AM_ENABLE_STATIC], [])
Chris@41: dnl AC_DEFUN([AM_DISABLE_STATIC], [])
Chris@41: 
Chris@41: 
Chris@41: 
Chris@41: # _LT_ENABLE_FAST_INSTALL([DEFAULT])
Chris@41: # ----------------------------------
Chris@41: # implement the --enable-fast-install flag, and support the 'fast-install'
Chris@41: # and 'disable-fast-install' LT_INIT options.
Chris@41: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@41: m4_define([_LT_ENABLE_FAST_INSTALL],
Chris@41: [m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@41: AC_ARG_ENABLE([fast-install],
Chris@41:     [AS_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
Chris@41:     [optimize for fast installation @<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
Chris@41:     [p=${PACKAGE-default}
Chris@41:     case $enableval in
Chris@41:     yes) enable_fast_install=yes ;;
Chris@41:     no) enable_fast_install=no ;;
Chris@41:     *)
Chris@41:       enable_fast_install=no
Chris@41:       # Look at the argument we got.  We use all the common list separators.
Chris@41:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@41:       for pkg in $enableval; do
Chris@41: 	IFS=$lt_save_ifs
Chris@41: 	if test "X$pkg" = "X$p"; then
Chris@41: 	  enable_fast_install=yes
Chris@41: 	fi
Chris@41:       done
Chris@41:       IFS=$lt_save_ifs
Chris@41:       ;;
Chris@41:     esac],
Chris@41:     [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
Chris@41: 
Chris@41: _LT_DECL([fast_install], [enable_fast_install], [0],
Chris@41: 	 [Whether or not to optimize for fast installation])dnl
Chris@41: ])# _LT_ENABLE_FAST_INSTALL
Chris@41: 
Chris@41: LT_OPTION_DEFINE([LT_INIT], [fast-install], [_LT_ENABLE_FAST_INSTALL([yes])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [disable-fast-install], [_LT_ENABLE_FAST_INSTALL([no])])
Chris@41: 
Chris@41: # Old names:
Chris@41: AU_DEFUN([AC_ENABLE_FAST_INSTALL],
Chris@41: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[fast-install])
Chris@41: AC_DIAGNOSE([obsolete],
Chris@41: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
Chris@41: the 'fast-install' option into LT_INIT's first parameter.])
Chris@41: ])
Chris@41: 
Chris@41: AU_DEFUN([AC_DISABLE_FAST_INSTALL],
Chris@41: [_LT_SET_OPTION([LT_INIT], [disable-fast-install])
Chris@41: AC_DIAGNOSE([obsolete],
Chris@41: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
Chris@41: the 'disable-fast-install' option into LT_INIT's first parameter.])
Chris@41: ])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AC_ENABLE_FAST_INSTALL], [])
Chris@41: dnl AC_DEFUN([AM_DISABLE_FAST_INSTALL], [])
Chris@41: 
Chris@41: 
Chris@41: # _LT_WITH_AIX_SONAME([DEFAULT])
Chris@41: # ----------------------------------
Chris@41: # implement the --with-aix-soname flag, and support the `aix-soname=aix'
Chris@41: # and `aix-soname=both' and `aix-soname=svr4' LT_INIT options. DEFAULT
Chris@41: # is either `aix', `both' or `svr4'.  If omitted, it defaults to `aix'.
Chris@41: m4_define([_LT_WITH_AIX_SONAME],
Chris@41: [m4_define([_LT_WITH_AIX_SONAME_DEFAULT], [m4_if($1, svr4, svr4, m4_if($1, both, both, aix))])dnl
Chris@41: shared_archive_member_spec=
Chris@41: case $host,$enable_shared in
Chris@41: power*-*-aix[[5-9]]*,yes)
Chris@41:   AC_MSG_CHECKING([which variant of shared library versioning to provide])
Chris@41:   AC_ARG_WITH([aix-soname],
Chris@41:     [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
Chris@41:       [shared library versioning (aka "SONAME") variant to provide on AIX, @<:@default=]_LT_WITH_AIX_SONAME_DEFAULT[@:>@.])],
Chris@41:     [case $withval in
Chris@41:     aix|svr4|both)
Chris@41:       ;;
Chris@41:     *)
Chris@41:       AC_MSG_ERROR([Unknown argument to --with-aix-soname])
Chris@41:       ;;
Chris@41:     esac
Chris@41:     lt_cv_with_aix_soname=$with_aix_soname],
Chris@41:     [AC_CACHE_VAL([lt_cv_with_aix_soname],
Chris@41:       [lt_cv_with_aix_soname=]_LT_WITH_AIX_SONAME_DEFAULT)
Chris@41:     with_aix_soname=$lt_cv_with_aix_soname])
Chris@41:   AC_MSG_RESULT([$with_aix_soname])
Chris@41:   if test aix != "$with_aix_soname"; then
Chris@41:     # For the AIX way of multilib, we name the shared archive member
Chris@41:     # based on the bitwidth used, traditionally 'shr.o' or 'shr_64.o',
Chris@41:     # and 'shr.imp' or 'shr_64.imp', respectively, for the Import File.
Chris@41:     # Even when GNU compilers ignore OBJECT_MODE but need '-maix64' flag,
Chris@41:     # the AIX toolchain works better with OBJECT_MODE set (default 32).
Chris@41:     if test 64 = "${OBJECT_MODE-32}"; then
Chris@41:       shared_archive_member_spec=shr_64
Chris@41:     else
Chris@41:       shared_archive_member_spec=shr
Chris@41:     fi
Chris@41:   fi
Chris@41:   ;;
Chris@41: *)
Chris@41:   with_aix_soname=aix
Chris@41:   ;;
Chris@41: esac
Chris@41: 
Chris@41: _LT_DECL([], [shared_archive_member_spec], [0],
Chris@41:     [Shared archive member basename, for filename based shared library versioning on AIX])dnl
Chris@41: ])# _LT_WITH_AIX_SONAME
Chris@41: 
Chris@41: LT_OPTION_DEFINE([LT_INIT], [aix-soname=aix], [_LT_WITH_AIX_SONAME([aix])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [aix-soname=both], [_LT_WITH_AIX_SONAME([both])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [aix-soname=svr4], [_LT_WITH_AIX_SONAME([svr4])])
Chris@41: 
Chris@41: 
Chris@41: # _LT_WITH_PIC([MODE])
Chris@41: # --------------------
Chris@41: # implement the --with-pic flag, and support the 'pic-only' and 'no-pic'
Chris@41: # LT_INIT options.
Chris@41: # MODE is either 'yes' or 'no'.  If omitted, it defaults to 'both'.
Chris@41: m4_define([_LT_WITH_PIC],
Chris@41: [AC_ARG_WITH([pic],
Chris@41:     [AS_HELP_STRING([--with-pic@<:@=PKGS@:>@],
Chris@41: 	[try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
Chris@41:     [lt_p=${PACKAGE-default}
Chris@41:     case $withval in
Chris@41:     yes|no) pic_mode=$withval ;;
Chris@41:     *)
Chris@41:       pic_mode=default
Chris@41:       # Look at the argument we got.  We use all the common list separators.
Chris@41:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@41:       for lt_pkg in $withval; do
Chris@41: 	IFS=$lt_save_ifs
Chris@41: 	if test "X$lt_pkg" = "X$lt_p"; then
Chris@41: 	  pic_mode=yes
Chris@41: 	fi
Chris@41:       done
Chris@41:       IFS=$lt_save_ifs
Chris@41:       ;;
Chris@41:     esac],
Chris@41:     [pic_mode=m4_default([$1], [default])])
Chris@41: 
Chris@41: _LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
Chris@41: ])# _LT_WITH_PIC
Chris@41: 
Chris@41: LT_OPTION_DEFINE([LT_INIT], [pic-only], [_LT_WITH_PIC([yes])])
Chris@41: LT_OPTION_DEFINE([LT_INIT], [no-pic], [_LT_WITH_PIC([no])])
Chris@41: 
Chris@41: # Old name:
Chris@41: AU_DEFUN([AC_LIBTOOL_PICMODE],
Chris@41: [_LT_SET_OPTION([LT_INIT], [pic-only])
Chris@41: AC_DIAGNOSE([obsolete],
Chris@41: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@41: put the 'pic-only' option into LT_INIT's first parameter.])
Chris@41: ])
Chris@41: 
Chris@41: dnl aclocal-1.4 backwards compatibility:
Chris@41: dnl AC_DEFUN([AC_LIBTOOL_PICMODE], [])
Chris@41: 
Chris@41: ## ----------------- ##
Chris@41: ## LTDL_INIT Options ##
Chris@41: ## ----------------- ##
Chris@41: 
Chris@41: m4_define([_LTDL_MODE], [])
Chris@41: LT_OPTION_DEFINE([LTDL_INIT], [nonrecursive],
Chris@41: 		 [m4_define([_LTDL_MODE], [nonrecursive])])
Chris@41: LT_OPTION_DEFINE([LTDL_INIT], [recursive],
Chris@41: 		 [m4_define([_LTDL_MODE], [recursive])])
Chris@41: LT_OPTION_DEFINE([LTDL_INIT], [subproject],
Chris@41: 		 [m4_define([_LTDL_MODE], [subproject])])
Chris@41: 
Chris@41: m4_define([_LTDL_TYPE], [])
Chris@41: LT_OPTION_DEFINE([LTDL_INIT], [installable],
Chris@41: 		 [m4_define([_LTDL_TYPE], [installable])])
Chris@41: LT_OPTION_DEFINE([LTDL_INIT], [convenience],
Chris@41: 		 [m4_define([_LTDL_TYPE], [convenience])])