cannam@128: /*
cannam@128: ;uInt longest_match_x64(
cannam@128: ;    deflate_state *s,
cannam@128: ;    IPos cur_match);                             // current match 
cannam@128: 
cannam@128: ; gvmat64.S -- Asm portion of the optimized longest_match for 32 bits x86_64
cannam@128: ;  (AMD64 on Athlon 64, Opteron, Phenom
cannam@128: ;     and Intel EM64T on Pentium 4 with EM64T, Pentium D, Core 2 Duo, Core I5/I7)
cannam@128: ; this file is translation from gvmat64.asm to GCC 4.x (for Linux, Mac XCode)
cannam@128: ; Copyright (C) 1995-2010 Jean-loup Gailly, Brian Raiter and Gilles Vollant.
cannam@128: ;
cannam@128: ; File written by Gilles Vollant, by converting to assembly the longest_match
cannam@128: ;  from Jean-loup Gailly in deflate.c of zLib and infoZip zip.
cannam@128: ;  and by taking inspiration on asm686 with masm, optimised assembly code
cannam@128: ;        from Brian Raiter, written 1998
cannam@128: ;
cannam@128: ;  This software is provided 'as-is', without any express or implied
cannam@128: ;  warranty.  In no event will the authors be held liable for any damages
cannam@128: ;  arising from the use of this software.
cannam@128: ;
cannam@128: ;  Permission is granted to anyone to use this software for any purpose,
cannam@128: ;  including commercial applications, and to alter it and redistribute it
cannam@128: ;  freely, subject to the following restrictions:
cannam@128: ;
cannam@128: ;  1. The origin of this software must not be misrepresented; you must not
cannam@128: ;     claim that you wrote the original software. If you use this software
cannam@128: ;     in a product, an acknowledgment in the product documentation would be
cannam@128: ;     appreciated but is not required.
cannam@128: ;  2. Altered source versions must be plainly marked as such, and must not be
cannam@128: ;     misrepresented as being the original software
cannam@128: ;  3. This notice may not be removed or altered from any source distribution.
cannam@128: ;
cannam@128: ;         http://www.zlib.net
cannam@128: ;         http://www.winimage.com/zLibDll
cannam@128: ;         http://www.muppetlabs.com/~breadbox/software/assembly.html
cannam@128: ;
cannam@128: ; to compile this file for zLib, I use option:
cannam@128: ;   gcc -c -arch x86_64 gvmat64.S
cannam@128: 
cannam@128: 
cannam@128: ;uInt longest_match(s, cur_match)
cannam@128: ;    deflate_state *s;
cannam@128: ;    IPos cur_match;                             // current match /
cannam@128: ;
cannam@128: ; with XCode for Mac, I had strange error with some jump on intel syntax
cannam@128: ; this is why BEFORE_JMP and AFTER_JMP are used
cannam@128:  */
cannam@128: 
cannam@128: 
cannam@128: #define BEFORE_JMP .att_syntax
cannam@128: #define AFTER_JMP .intel_syntax noprefix
cannam@128: 
cannam@128: #ifndef NO_UNDERLINE
cannam@128: #	define	match_init	_match_init
cannam@128: #	define	longest_match	_longest_match
cannam@128: #endif
cannam@128: 
cannam@128: .intel_syntax noprefix
cannam@128: 
cannam@128: .globl	match_init, longest_match
cannam@128: .text
cannam@128: longest_match:
cannam@128: 
cannam@128: 
cannam@128: 
cannam@128: #define LocalVarsSize 96
cannam@128: /*
cannam@128: ; register used : rax,rbx,rcx,rdx,rsi,rdi,r8,r9,r10,r11,r12
cannam@128: ; free register :  r14,r15
cannam@128: ; register can be saved : rsp
cannam@128: */
cannam@128: 
cannam@128: #define chainlenwmask     (rsp + 8 - LocalVarsSize)
cannam@128: #define nicematch         (rsp + 16 - LocalVarsSize)
cannam@128: 
cannam@128: #define save_rdi        (rsp + 24 - LocalVarsSize)
cannam@128: #define save_rsi        (rsp + 32 - LocalVarsSize)
cannam@128: #define save_rbx        (rsp + 40 - LocalVarsSize)
cannam@128: #define save_rbp        (rsp + 48 - LocalVarsSize)
cannam@128: #define save_r12        (rsp + 56 - LocalVarsSize)
cannam@128: #define save_r13        (rsp + 64 - LocalVarsSize)
cannam@128: #define save_r14        (rsp + 72 - LocalVarsSize)
cannam@128: #define save_r15        (rsp + 80 - LocalVarsSize)
cannam@128: 
cannam@128: 
cannam@128: /*
cannam@128: ;  all the +4 offsets are due to the addition of pending_buf_size (in zlib
cannam@128: ;  in the deflate_state structure since the asm code was first written
cannam@128: ;  (if you compile with zlib 1.0.4 or older, remove the +4).
cannam@128: ;  Note : these value are good with a 8 bytes boundary pack structure
cannam@128: */
cannam@128: 
cannam@128: #define    MAX_MATCH              258
cannam@128: #define    MIN_MATCH              3
cannam@128: #define    MIN_LOOKAHEAD          (MAX_MATCH+MIN_MATCH+1)
cannam@128: 
cannam@128: /*
cannam@128: ;;; Offsets for fields in the deflate_state structure. These numbers
cannam@128: ;;; are calculated from the definition of deflate_state, with the
cannam@128: ;;; assumption that the compiler will dword-align the fields. (Thus,
cannam@128: ;;; changing the definition of deflate_state could easily cause this
cannam@128: ;;; program to crash horribly, without so much as a warning at
cannam@128: ;;; compile time. Sigh.)
cannam@128: 
cannam@128: ;  all the +zlib1222add offsets are due to the addition of fields
cannam@128: ;  in zlib in the deflate_state structure since the asm code was first written
cannam@128: ;  (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").
cannam@128: ;  (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").
cannam@128: ;  if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").
cannam@128: */
cannam@128: 
cannam@128: 
cannam@128: 
cannam@128: /* you can check the structure offset by running
cannam@128: 
cannam@128: #include <stdlib.h>
cannam@128: #include <stdio.h>
cannam@128: #include "deflate.h"
cannam@128: 
cannam@128: void print_depl()
cannam@128: {
cannam@128: deflate_state ds;
cannam@128: deflate_state *s=&ds;
cannam@128: printf("size pointer=%u\n",(int)sizeof(void*));
cannam@128: 
cannam@128: printf("#define dsWSize         %u\n",(int)(((char*)&(s->w_size))-((char*)s)));
cannam@128: printf("#define dsWMask         %u\n",(int)(((char*)&(s->w_mask))-((char*)s)));
cannam@128: printf("#define dsWindow        %u\n",(int)(((char*)&(s->window))-((char*)s)));
cannam@128: printf("#define dsPrev          %u\n",(int)(((char*)&(s->prev))-((char*)s)));
cannam@128: printf("#define dsMatchLen      %u\n",(int)(((char*)&(s->match_length))-((char*)s)));
cannam@128: printf("#define dsPrevMatch     %u\n",(int)(((char*)&(s->prev_match))-((char*)s)));
cannam@128: printf("#define dsStrStart      %u\n",(int)(((char*)&(s->strstart))-((char*)s)));
cannam@128: printf("#define dsMatchStart    %u\n",(int)(((char*)&(s->match_start))-((char*)s)));
cannam@128: printf("#define dsLookahead     %u\n",(int)(((char*)&(s->lookahead))-((char*)s)));
cannam@128: printf("#define dsPrevLen       %u\n",(int)(((char*)&(s->prev_length))-((char*)s)));
cannam@128: printf("#define dsMaxChainLen   %u\n",(int)(((char*)&(s->max_chain_length))-((char*)s)));
cannam@128: printf("#define dsGoodMatch     %u\n",(int)(((char*)&(s->good_match))-((char*)s)));
cannam@128: printf("#define dsNiceMatch     %u\n",(int)(((char*)&(s->nice_match))-((char*)s)));
cannam@128: }
cannam@128: */
cannam@128: 
cannam@128: #define dsWSize          68
cannam@128: #define dsWMask          76
cannam@128: #define dsWindow         80
cannam@128: #define dsPrev           96
cannam@128: #define dsMatchLen       144
cannam@128: #define dsPrevMatch      148
cannam@128: #define dsStrStart       156
cannam@128: #define dsMatchStart     160
cannam@128: #define dsLookahead      164
cannam@128: #define dsPrevLen        168
cannam@128: #define dsMaxChainLen    172
cannam@128: #define dsGoodMatch      188
cannam@128: #define dsNiceMatch      192
cannam@128: 
cannam@128: #define window_size      [ rcx + dsWSize]
cannam@128: #define WMask            [ rcx + dsWMask]
cannam@128: #define window_ad        [ rcx + dsWindow]
cannam@128: #define prev_ad          [ rcx + dsPrev]
cannam@128: #define strstart         [ rcx + dsStrStart]
cannam@128: #define match_start      [ rcx + dsMatchStart]
cannam@128: #define Lookahead        [ rcx + dsLookahead] //; 0ffffffffh on infozip
cannam@128: #define prev_length      [ rcx + dsPrevLen]
cannam@128: #define max_chain_length [ rcx + dsMaxChainLen]
cannam@128: #define good_match       [ rcx + dsGoodMatch]
cannam@128: #define nice_match       [ rcx + dsNiceMatch]
cannam@128: 
cannam@128: /*
cannam@128: ; windows:
cannam@128: ; parameter 1 in rcx(deflate state s), param 2 in rdx (cur match)
cannam@128: 
cannam@128: ; see http://weblogs.asp.net/oldnewthing/archive/2004/01/14/58579.aspx and
cannam@128: ; http://msdn.microsoft.com/library/en-us/kmarch/hh/kmarch/64bitAMD_8e951dd2-ee77-4728-8702-55ce4b5dd24a.xml.asp
cannam@128: ;
cannam@128: ; All registers must be preserved across the call, except for
cannam@128: ;   rax, rcx, rdx, r8, r9, r10, and r11, which are scratch.
cannam@128: 
cannam@128: ;
cannam@128: ; gcc on macosx-linux:
cannam@128: ; see http://www.x86-64.org/documentation/abi-0.99.pdf
cannam@128: ; param 1 in rdi, param 2 in rsi
cannam@128: ; rbx, rsp, rbp, r12 to r15 must be preserved
cannam@128: 
cannam@128: ;;; Save registers that the compiler may be using, and adjust esp to
cannam@128: ;;; make room for our stack frame.
cannam@128: 
cannam@128: 
cannam@128: ;;; Retrieve the function arguments. r8d will hold cur_match
cannam@128: ;;; throughout the entire function. edx will hold the pointer to the
cannam@128: ;;; deflate_state structure during the function's setup (before
cannam@128: ;;; entering the main loop.
cannam@128: 
cannam@128: ; ms: parameter 1 in rcx (deflate_state* s), param 2 in edx -> r8 (cur match)
cannam@128: ; mac: param 1 in rdi, param 2 rsi
cannam@128: ; this clear high 32 bits of r8, which can be garbage in both r8 and rdx
cannam@128: */
cannam@128:         mov [save_rbx],rbx
cannam@128:         mov [save_rbp],rbp
cannam@128: 
cannam@128: 
cannam@128:         mov rcx,rdi
cannam@128: 
cannam@128:         mov r8d,esi
cannam@128: 
cannam@128: 
cannam@128:         mov [save_r12],r12
cannam@128:         mov [save_r13],r13
cannam@128:         mov [save_r14],r14
cannam@128:         mov [save_r15],r15
cannam@128: 
cannam@128: 
cannam@128: //;;; uInt wmask = s->w_mask;
cannam@128: //;;; unsigned chain_length = s->max_chain_length;
cannam@128: //;;; if (s->prev_length >= s->good_match) {
cannam@128: //;;;     chain_length >>= 2;
cannam@128: //;;; }
cannam@128: 
cannam@128: 
cannam@128:         mov edi, prev_length
cannam@128:         mov esi, good_match
cannam@128:         mov eax, WMask
cannam@128:         mov ebx, max_chain_length
cannam@128:         cmp edi, esi
cannam@128:         jl  LastMatchGood
cannam@128:         shr ebx, 2
cannam@128: LastMatchGood:
cannam@128: 
cannam@128: //;;; chainlen is decremented once beforehand so that the function can
cannam@128: //;;; use the sign flag instead of the zero flag for the exit test.
cannam@128: //;;; It is then shifted into the high word, to make room for the wmask
cannam@128: //;;; value, which it will always accompany.
cannam@128: 
cannam@128:         dec ebx
cannam@128:         shl ebx, 16
cannam@128:         or  ebx, eax
cannam@128: 
cannam@128: //;;; on zlib only
cannam@128: //;;; if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead;
cannam@128: 
cannam@128: 
cannam@128: 
cannam@128:         mov eax, nice_match
cannam@128:         mov [chainlenwmask], ebx
cannam@128:         mov r10d, Lookahead
cannam@128:         cmp r10d, eax
cannam@128:         cmovnl r10d, eax
cannam@128:         mov [nicematch],r10d
cannam@128: 
cannam@128: 
cannam@128: 
cannam@128: //;;; register Bytef *scan = s->window + s->strstart;
cannam@128:         mov r10, window_ad
cannam@128:         mov ebp, strstart
cannam@128:         lea r13, [r10 + rbp]
cannam@128: 
cannam@128: //;;; Determine how many bytes the scan ptr is off from being
cannam@128: //;;; dword-aligned.
cannam@128: 
cannam@128:          mov r9,r13
cannam@128:          neg r13
cannam@128:          and r13,3
cannam@128: 
cannam@128: //;;; IPos limit = s->strstart > (IPos)MAX_DIST(s) ?
cannam@128: //;;;     s->strstart - (IPos)MAX_DIST(s) : NIL;
cannam@128: 
cannam@128: 
cannam@128:         mov eax, window_size
cannam@128:         sub eax, MIN_LOOKAHEAD
cannam@128: 
cannam@128: 
cannam@128:         xor edi,edi
cannam@128:         sub ebp, eax
cannam@128: 
cannam@128:         mov r11d, prev_length
cannam@128: 
cannam@128:         cmovng ebp,edi
cannam@128: 
cannam@128: //;;; int best_len = s->prev_length;
cannam@128: 
cannam@128: 
cannam@128: //;;; Store the sum of s->window + best_len in esi locally, and in esi.
cannam@128: 
cannam@128:        lea  rsi,[r10+r11]
cannam@128: 
cannam@128: //;;; register ush scan_start = *(ushf*)scan;
cannam@128: //;;; register ush scan_end   = *(ushf*)(scan+best_len-1);
cannam@128: //;;; Posf *prev = s->prev;
cannam@128: 
cannam@128:         movzx r12d,word ptr [r9]
cannam@128:         movzx ebx, word ptr [r9 + r11 - 1]
cannam@128: 
cannam@128:         mov rdi, prev_ad
cannam@128: 
cannam@128: //;;; Jump into the main loop.
cannam@128: 
cannam@128:         mov edx, [chainlenwmask]
cannam@128: 
cannam@128:         cmp bx,word ptr [rsi + r8 - 1]
cannam@128:         jz  LookupLoopIsZero
cannam@128: 				
cannam@128: 						
cannam@128: 						
cannam@128: LookupLoop1:
cannam@128:         and r8d, edx
cannam@128: 
cannam@128:         movzx   r8d, word ptr [rdi + r8*2]
cannam@128:         cmp r8d, ebp
cannam@128:         jbe LeaveNow
cannam@128: 		
cannam@128: 		
cannam@128: 		
cannam@128:         sub edx, 0x00010000
cannam@128: 		BEFORE_JMP
cannam@128:         js  LeaveNow
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LoopEntry1:
cannam@128:         cmp bx,word ptr [rsi + r8 - 1]
cannam@128: 		BEFORE_JMP
cannam@128:         jz  LookupLoopIsZero
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LookupLoop2:
cannam@128:         and r8d, edx
cannam@128: 
cannam@128:         movzx   r8d, word ptr [rdi + r8*2]
cannam@128:         cmp r8d, ebp
cannam@128: 		BEFORE_JMP
cannam@128:         jbe LeaveNow
cannam@128: 		AFTER_JMP
cannam@128:         sub edx, 0x00010000
cannam@128: 		BEFORE_JMP
cannam@128:         js  LeaveNow
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LoopEntry2:
cannam@128:         cmp bx,word ptr [rsi + r8 - 1]
cannam@128: 		BEFORE_JMP
cannam@128:         jz  LookupLoopIsZero
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LookupLoop4:
cannam@128:         and r8d, edx
cannam@128: 
cannam@128:         movzx   r8d, word ptr [rdi + r8*2]
cannam@128:         cmp r8d, ebp
cannam@128: 		BEFORE_JMP
cannam@128:         jbe LeaveNow
cannam@128: 		AFTER_JMP
cannam@128:         sub edx, 0x00010000
cannam@128: 		BEFORE_JMP
cannam@128:         js  LeaveNow
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LoopEntry4:
cannam@128: 
cannam@128:         cmp bx,word ptr [rsi + r8 - 1]
cannam@128: 		BEFORE_JMP
cannam@128:         jnz LookupLoop1
cannam@128:         jmp LookupLoopIsZero
cannam@128: 		AFTER_JMP
cannam@128: /*
cannam@128: ;;; do {
cannam@128: ;;;     match = s->window + cur_match;
cannam@128: ;;;     if (*(ushf*)(match+best_len-1) != scan_end ||
cannam@128: ;;;         *(ushf*)match != scan_start) continue;
cannam@128: ;;;     [...]
cannam@128: ;;; } while ((cur_match = prev[cur_match & wmask]) > limit
cannam@128: ;;;          && --chain_length != 0);
cannam@128: ;;;
cannam@128: ;;; Here is the inner loop of the function. The function will spend the
cannam@128: ;;; majority of its time in this loop, and majority of that time will
cannam@128: ;;; be spent in the first ten instructions.
cannam@128: ;;;
cannam@128: ;;; Within this loop:
cannam@128: ;;; ebx = scanend
cannam@128: ;;; r8d = curmatch
cannam@128: ;;; edx = chainlenwmask - i.e., ((chainlen << 16) | wmask)
cannam@128: ;;; esi = windowbestlen - i.e., (window + bestlen)
cannam@128: ;;; edi = prev
cannam@128: ;;; ebp = limit
cannam@128: */
cannam@128: .balign 16
cannam@128: LookupLoop:
cannam@128:         and r8d, edx
cannam@128: 
cannam@128:         movzx   r8d, word ptr [rdi + r8*2]
cannam@128:         cmp r8d, ebp
cannam@128: 		BEFORE_JMP
cannam@128:         jbe LeaveNow
cannam@128: 		AFTER_JMP
cannam@128:         sub edx, 0x00010000
cannam@128: 		BEFORE_JMP
cannam@128:         js  LeaveNow
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LoopEntry:
cannam@128: 
cannam@128:         cmp bx,word ptr [rsi + r8 - 1]
cannam@128: 		BEFORE_JMP
cannam@128:         jnz LookupLoop1
cannam@128: 		AFTER_JMP
cannam@128: LookupLoopIsZero:
cannam@128:         cmp     r12w, word ptr [r10 + r8]
cannam@128: 		BEFORE_JMP
cannam@128:         jnz LookupLoop1
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: 
cannam@128: //;;; Store the current value of chainlen.
cannam@128:         mov [chainlenwmask], edx
cannam@128: /*
cannam@128: ;;; Point edi to the string under scrutiny, and esi to the string we
cannam@128: ;;; are hoping to match it up with. In actuality, esi and edi are
cannam@128: ;;; both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and edx is
cannam@128: ;;; initialized to -(MAX_MATCH_8 - scanalign).
cannam@128: */
cannam@128:         lea rsi,[r8+r10]
cannam@128:         mov rdx, 0xfffffffffffffef8 //; -(MAX_MATCH_8)
cannam@128:         lea rsi, [rsi + r13 + 0x0108] //;MAX_MATCH_8]
cannam@128:         lea rdi, [r9 + r13 + 0x0108] //;MAX_MATCH_8]
cannam@128: 
cannam@128:         prefetcht1 [rsi+rdx]
cannam@128:         prefetcht1 [rdi+rdx]
cannam@128: 
cannam@128: /*
cannam@128: ;;; Test the strings for equality, 8 bytes at a time. At the end,
cannam@128: ;;; adjust rdx so that it is offset to the exact byte that mismatched.
cannam@128: ;;;
cannam@128: ;;; We already know at this point that the first three bytes of the
cannam@128: ;;; strings match each other, and they can be safely passed over before
cannam@128: ;;; starting the compare loop. So what this code does is skip over 0-3
cannam@128: ;;; bytes, as much as necessary in order to dword-align the edi
cannam@128: ;;; pointer. (rsi will still be misaligned three times out of four.)
cannam@128: ;;;
cannam@128: ;;; It should be confessed that this loop usually does not represent
cannam@128: ;;; much of the total running time. Replacing it with a more
cannam@128: ;;; straightforward "rep cmpsb" would not drastically degrade
cannam@128: ;;; performance.
cannam@128: */
cannam@128: 
cannam@128: LoopCmps:
cannam@128:         mov rax, [rsi + rdx]
cannam@128:         xor rax, [rdi + rdx]
cannam@128:         jnz LeaveLoopCmps
cannam@128: 
cannam@128:         mov rax, [rsi + rdx + 8]
cannam@128:         xor rax, [rdi + rdx + 8]
cannam@128:         jnz LeaveLoopCmps8
cannam@128: 
cannam@128: 
cannam@128:         mov rax, [rsi + rdx + 8+8]
cannam@128:         xor rax, [rdi + rdx + 8+8]
cannam@128:         jnz LeaveLoopCmps16
cannam@128: 
cannam@128:         add rdx,8+8+8
cannam@128: 
cannam@128: 		BEFORE_JMP
cannam@128:         jnz  LoopCmps
cannam@128:         jmp  LenMaximum
cannam@128: 		AFTER_JMP
cannam@128: 		
cannam@128: LeaveLoopCmps16: add rdx,8
cannam@128: LeaveLoopCmps8: add rdx,8
cannam@128: LeaveLoopCmps:
cannam@128: 
cannam@128:         test    eax, 0x0000FFFF
cannam@128:         jnz LenLower
cannam@128: 
cannam@128:         test eax,0xffffffff
cannam@128: 
cannam@128:         jnz LenLower32
cannam@128: 
cannam@128:         add rdx,4
cannam@128:         shr rax,32
cannam@128:         or ax,ax
cannam@128: 		BEFORE_JMP
cannam@128:         jnz LenLower
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: LenLower32:
cannam@128:         shr eax,16
cannam@128:         add rdx,2
cannam@128: 		
cannam@128: LenLower:		
cannam@128:         sub al, 1
cannam@128:         adc rdx, 0
cannam@128: //;;; Calculate the length of the match. If it is longer than MAX_MATCH,
cannam@128: //;;; then automatically accept it as the best possible match and leave.
cannam@128: 
cannam@128:         lea rax, [rdi + rdx]
cannam@128:         sub rax, r9
cannam@128:         cmp eax, MAX_MATCH
cannam@128: 		BEFORE_JMP
cannam@128:         jge LenMaximum
cannam@128: 		AFTER_JMP
cannam@128: /*
cannam@128: ;;; If the length of the match is not longer than the best match we
cannam@128: ;;; have so far, then forget it and return to the lookup loop.
cannam@128: ;///////////////////////////////////
cannam@128: */
cannam@128:         cmp eax, r11d
cannam@128:         jg  LongerMatch
cannam@128: 
cannam@128:         lea rsi,[r10+r11]
cannam@128: 
cannam@128:         mov rdi, prev_ad
cannam@128:         mov edx, [chainlenwmask]
cannam@128: 		BEFORE_JMP
cannam@128:         jmp LookupLoop
cannam@128: 		AFTER_JMP
cannam@128: /*
cannam@128: ;;;         s->match_start = cur_match;
cannam@128: ;;;         best_len = len;
cannam@128: ;;;         if (len >= nice_match) break;
cannam@128: ;;;         scan_end = *(ushf*)(scan+best_len-1);
cannam@128: */
cannam@128: LongerMatch:
cannam@128:         mov r11d, eax
cannam@128:         mov match_start, r8d
cannam@128:         cmp eax, [nicematch]
cannam@128: 		BEFORE_JMP
cannam@128:         jge LeaveNow
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128:         lea rsi,[r10+rax]
cannam@128: 
cannam@128:         movzx   ebx, word ptr [r9 + rax - 1]
cannam@128:         mov rdi, prev_ad
cannam@128:         mov edx, [chainlenwmask]
cannam@128: 		BEFORE_JMP
cannam@128:         jmp LookupLoop
cannam@128: 		AFTER_JMP
cannam@128: 
cannam@128: //;;; Accept the current string, with the maximum possible length.
cannam@128: 
cannam@128: LenMaximum:
cannam@128:         mov r11d,MAX_MATCH
cannam@128:         mov match_start, r8d
cannam@128: 
cannam@128: //;;; if ((uInt)best_len <= s->lookahead) return (uInt)best_len;
cannam@128: //;;; return s->lookahead;
cannam@128: 
cannam@128: LeaveNow:
cannam@128:         mov eax, Lookahead
cannam@128:         cmp r11d, eax
cannam@128:         cmovng eax, r11d
cannam@128: 
cannam@128: 
cannam@128: 
cannam@128: //;;; Restore the stack and return from whence we came.
cannam@128: 
cannam@128: 
cannam@128: //        mov rsi,[save_rsi]
cannam@128: //        mov rdi,[save_rdi]
cannam@128:         mov rbx,[save_rbx]
cannam@128:         mov rbp,[save_rbp]
cannam@128:         mov r12,[save_r12]
cannam@128:         mov r13,[save_r13]
cannam@128:         mov r14,[save_r14]
cannam@128:         mov r15,[save_r15]
cannam@128: 
cannam@128: 
cannam@128:         ret 0
cannam@128: //; please don't remove this string !
cannam@128: //; Your can freely use gvmat64 in any free or commercial app
cannam@128: //; but it is far better don't remove the string in the binary!
cannam@128:  //   db     0dh,0ah,"asm686 with masm, optimised assembly code from Brian Raiter, written 1998, converted to amd 64 by Gilles Vollant 2005",0dh,0ah,0
cannam@128: 
cannam@128: 
cannam@128: match_init:
cannam@128:   ret 0
cannam@128: 
cannam@128: