Chris@43: /*
Chris@43: ;uInt longest_match_x64(
Chris@43: ;    deflate_state *s,
Chris@43: ;    IPos cur_match);                             // current match 
Chris@43: 
Chris@43: ; gvmat64.S -- Asm portion of the optimized longest_match for 32 bits x86_64
Chris@43: ;  (AMD64 on Athlon 64, Opteron, Phenom
Chris@43: ;     and Intel EM64T on Pentium 4 with EM64T, Pentium D, Core 2 Duo, Core I5/I7)
Chris@43: ; this file is translation from gvmat64.asm to GCC 4.x (for Linux, Mac XCode)
Chris@43: ; Copyright (C) 1995-2010 Jean-loup Gailly, Brian Raiter and Gilles Vollant.
Chris@43: ;
Chris@43: ; File written by Gilles Vollant, by converting to assembly the longest_match
Chris@43: ;  from Jean-loup Gailly in deflate.c of zLib and infoZip zip.
Chris@43: ;  and by taking inspiration on asm686 with masm, optimised assembly code
Chris@43: ;        from Brian Raiter, written 1998
Chris@43: ;
Chris@43: ;  This software is provided 'as-is', without any express or implied
Chris@43: ;  warranty.  In no event will the authors be held liable for any damages
Chris@43: ;  arising from the use of this software.
Chris@43: ;
Chris@43: ;  Permission is granted to anyone to use this software for any purpose,
Chris@43: ;  including commercial applications, and to alter it and redistribute it
Chris@43: ;  freely, subject to the following restrictions:
Chris@43: ;
Chris@43: ;  1. The origin of this software must not be misrepresented; you must not
Chris@43: ;     claim that you wrote the original software. If you use this software
Chris@43: ;     in a product, an acknowledgment in the product documentation would be
Chris@43: ;     appreciated but is not required.
Chris@43: ;  2. Altered source versions must be plainly marked as such, and must not be
Chris@43: ;     misrepresented as being the original software
Chris@43: ;  3. This notice may not be removed or altered from any source distribution.
Chris@43: ;
Chris@43: ;         http://www.zlib.net
Chris@43: ;         http://www.winimage.com/zLibDll
Chris@43: ;         http://www.muppetlabs.com/~breadbox/software/assembly.html
Chris@43: ;
Chris@43: ; to compile this file for zLib, I use option:
Chris@43: ;   gcc -c -arch x86_64 gvmat64.S
Chris@43: 
Chris@43: 
Chris@43: ;uInt longest_match(s, cur_match)
Chris@43: ;    deflate_state *s;
Chris@43: ;    IPos cur_match;                             // current match /
Chris@43: ;
Chris@43: ; with XCode for Mac, I had strange error with some jump on intel syntax
Chris@43: ; this is why BEFORE_JMP and AFTER_JMP are used
Chris@43:  */
Chris@43: 
Chris@43: 
Chris@43: #define BEFORE_JMP .att_syntax
Chris@43: #define AFTER_JMP .intel_syntax noprefix
Chris@43: 
Chris@43: #ifndef NO_UNDERLINE
Chris@43: #	define	match_init	_match_init
Chris@43: #	define	longest_match	_longest_match
Chris@43: #endif
Chris@43: 
Chris@43: .intel_syntax noprefix
Chris@43: 
Chris@43: .globl	match_init, longest_match
Chris@43: .text
Chris@43: longest_match:
Chris@43: 
Chris@43: 
Chris@43: 
Chris@43: #define LocalVarsSize 96
Chris@43: /*
Chris@43: ; register used : rax,rbx,rcx,rdx,rsi,rdi,r8,r9,r10,r11,r12
Chris@43: ; free register :  r14,r15
Chris@43: ; register can be saved : rsp
Chris@43: */
Chris@43: 
Chris@43: #define chainlenwmask     (rsp + 8 - LocalVarsSize)
Chris@43: #define nicematch         (rsp + 16 - LocalVarsSize)
Chris@43: 
Chris@43: #define save_rdi        (rsp + 24 - LocalVarsSize)
Chris@43: #define save_rsi        (rsp + 32 - LocalVarsSize)
Chris@43: #define save_rbx        (rsp + 40 - LocalVarsSize)
Chris@43: #define save_rbp        (rsp + 48 - LocalVarsSize)
Chris@43: #define save_r12        (rsp + 56 - LocalVarsSize)
Chris@43: #define save_r13        (rsp + 64 - LocalVarsSize)
Chris@43: #define save_r14        (rsp + 72 - LocalVarsSize)
Chris@43: #define save_r15        (rsp + 80 - LocalVarsSize)
Chris@43: 
Chris@43: 
Chris@43: /*
Chris@43: ;  all the +4 offsets are due to the addition of pending_buf_size (in zlib
Chris@43: ;  in the deflate_state structure since the asm code was first written
Chris@43: ;  (if you compile with zlib 1.0.4 or older, remove the +4).
Chris@43: ;  Note : these value are good with a 8 bytes boundary pack structure
Chris@43: */
Chris@43: 
Chris@43: #define    MAX_MATCH              258
Chris@43: #define    MIN_MATCH              3
Chris@43: #define    MIN_LOOKAHEAD          (MAX_MATCH+MIN_MATCH+1)
Chris@43: 
Chris@43: /*
Chris@43: ;;; Offsets for fields in the deflate_state structure. These numbers
Chris@43: ;;; are calculated from the definition of deflate_state, with the
Chris@43: ;;; assumption that the compiler will dword-align the fields. (Thus,
Chris@43: ;;; changing the definition of deflate_state could easily cause this
Chris@43: ;;; program to crash horribly, without so much as a warning at
Chris@43: ;;; compile time. Sigh.)
Chris@43: 
Chris@43: ;  all the +zlib1222add offsets are due to the addition of fields
Chris@43: ;  in zlib in the deflate_state structure since the asm code was first written
Chris@43: ;  (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").
Chris@43: ;  (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").
Chris@43: ;  if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").
Chris@43: */
Chris@43: 
Chris@43: 
Chris@43: 
Chris@43: /* you can check the structure offset by running
Chris@43: 
Chris@43: #include <stdlib.h>
Chris@43: #include <stdio.h>
Chris@43: #include "deflate.h"
Chris@43: 
Chris@43: void print_depl()
Chris@43: {
Chris@43: deflate_state ds;
Chris@43: deflate_state *s=&ds;
Chris@43: printf("size pointer=%u\n",(int)sizeof(void*));
Chris@43: 
Chris@43: printf("#define dsWSize         %u\n",(int)(((char*)&(s->w_size))-((char*)s)));
Chris@43: printf("#define dsWMask         %u\n",(int)(((char*)&(s->w_mask))-((char*)s)));
Chris@43: printf("#define dsWindow        %u\n",(int)(((char*)&(s->window))-((char*)s)));
Chris@43: printf("#define dsPrev          %u\n",(int)(((char*)&(s->prev))-((char*)s)));
Chris@43: printf("#define dsMatchLen      %u\n",(int)(((char*)&(s->match_length))-((char*)s)));
Chris@43: printf("#define dsPrevMatch     %u\n",(int)(((char*)&(s->prev_match))-((char*)s)));
Chris@43: printf("#define dsStrStart      %u\n",(int)(((char*)&(s->strstart))-((char*)s)));
Chris@43: printf("#define dsMatchStart    %u\n",(int)(((char*)&(s->match_start))-((char*)s)));
Chris@43: printf("#define dsLookahead     %u\n",(int)(((char*)&(s->lookahead))-((char*)s)));
Chris@43: printf("#define dsPrevLen       %u\n",(int)(((char*)&(s->prev_length))-((char*)s)));
Chris@43: printf("#define dsMaxChainLen   %u\n",(int)(((char*)&(s->max_chain_length))-((char*)s)));
Chris@43: printf("#define dsGoodMatch     %u\n",(int)(((char*)&(s->good_match))-((char*)s)));
Chris@43: printf("#define dsNiceMatch     %u\n",(int)(((char*)&(s->nice_match))-((char*)s)));
Chris@43: }
Chris@43: */
Chris@43: 
Chris@43: #define dsWSize          68
Chris@43: #define dsWMask          76
Chris@43: #define dsWindow         80
Chris@43: #define dsPrev           96
Chris@43: #define dsMatchLen       144
Chris@43: #define dsPrevMatch      148
Chris@43: #define dsStrStart       156
Chris@43: #define dsMatchStart     160
Chris@43: #define dsLookahead      164
Chris@43: #define dsPrevLen        168
Chris@43: #define dsMaxChainLen    172
Chris@43: #define dsGoodMatch      188
Chris@43: #define dsNiceMatch      192
Chris@43: 
Chris@43: #define window_size      [ rcx + dsWSize]
Chris@43: #define WMask            [ rcx + dsWMask]
Chris@43: #define window_ad        [ rcx + dsWindow]
Chris@43: #define prev_ad          [ rcx + dsPrev]
Chris@43: #define strstart         [ rcx + dsStrStart]
Chris@43: #define match_start      [ rcx + dsMatchStart]
Chris@43: #define Lookahead        [ rcx + dsLookahead] //; 0ffffffffh on infozip
Chris@43: #define prev_length      [ rcx + dsPrevLen]
Chris@43: #define max_chain_length [ rcx + dsMaxChainLen]
Chris@43: #define good_match       [ rcx + dsGoodMatch]
Chris@43: #define nice_match       [ rcx + dsNiceMatch]
Chris@43: 
Chris@43: /*
Chris@43: ; windows:
Chris@43: ; parameter 1 in rcx(deflate state s), param 2 in rdx (cur match)
Chris@43: 
Chris@43: ; see http://weblogs.asp.net/oldnewthing/archive/2004/01/14/58579.aspx and
Chris@43: ; http://msdn.microsoft.com/library/en-us/kmarch/hh/kmarch/64bitAMD_8e951dd2-ee77-4728-8702-55ce4b5dd24a.xml.asp
Chris@43: ;
Chris@43: ; All registers must be preserved across the call, except for
Chris@43: ;   rax, rcx, rdx, r8, r9, r10, and r11, which are scratch.
Chris@43: 
Chris@43: ;
Chris@43: ; gcc on macosx-linux:
Chris@43: ; see http://www.x86-64.org/documentation/abi-0.99.pdf
Chris@43: ; param 1 in rdi, param 2 in rsi
Chris@43: ; rbx, rsp, rbp, r12 to r15 must be preserved
Chris@43: 
Chris@43: ;;; Save registers that the compiler may be using, and adjust esp to
Chris@43: ;;; make room for our stack frame.
Chris@43: 
Chris@43: 
Chris@43: ;;; Retrieve the function arguments. r8d will hold cur_match
Chris@43: ;;; throughout the entire function. edx will hold the pointer to the
Chris@43: ;;; deflate_state structure during the function's setup (before
Chris@43: ;;; entering the main loop.
Chris@43: 
Chris@43: ; ms: parameter 1 in rcx (deflate_state* s), param 2 in edx -> r8 (cur match)
Chris@43: ; mac: param 1 in rdi, param 2 rsi
Chris@43: ; this clear high 32 bits of r8, which can be garbage in both r8 and rdx
Chris@43: */
Chris@43:         mov [save_rbx],rbx
Chris@43:         mov [save_rbp],rbp
Chris@43: 
Chris@43: 
Chris@43:         mov rcx,rdi
Chris@43: 
Chris@43:         mov r8d,esi
Chris@43: 
Chris@43: 
Chris@43:         mov [save_r12],r12
Chris@43:         mov [save_r13],r13
Chris@43:         mov [save_r14],r14
Chris@43:         mov [save_r15],r15
Chris@43: 
Chris@43: 
Chris@43: //;;; uInt wmask = s->w_mask;
Chris@43: //;;; unsigned chain_length = s->max_chain_length;
Chris@43: //;;; if (s->prev_length >= s->good_match) {
Chris@43: //;;;     chain_length >>= 2;
Chris@43: //;;; }
Chris@43: 
Chris@43: 
Chris@43:         mov edi, prev_length
Chris@43:         mov esi, good_match
Chris@43:         mov eax, WMask
Chris@43:         mov ebx, max_chain_length
Chris@43:         cmp edi, esi
Chris@43:         jl  LastMatchGood
Chris@43:         shr ebx, 2
Chris@43: LastMatchGood:
Chris@43: 
Chris@43: //;;; chainlen is decremented once beforehand so that the function can
Chris@43: //;;; use the sign flag instead of the zero flag for the exit test.
Chris@43: //;;; It is then shifted into the high word, to make room for the wmask
Chris@43: //;;; value, which it will always accompany.
Chris@43: 
Chris@43:         dec ebx
Chris@43:         shl ebx, 16
Chris@43:         or  ebx, eax
Chris@43: 
Chris@43: //;;; on zlib only
Chris@43: //;;; if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead;
Chris@43: 
Chris@43: 
Chris@43: 
Chris@43:         mov eax, nice_match
Chris@43:         mov [chainlenwmask], ebx
Chris@43:         mov r10d, Lookahead
Chris@43:         cmp r10d, eax
Chris@43:         cmovnl r10d, eax
Chris@43:         mov [nicematch],r10d
Chris@43: 
Chris@43: 
Chris@43: 
Chris@43: //;;; register Bytef *scan = s->window + s->strstart;
Chris@43:         mov r10, window_ad
Chris@43:         mov ebp, strstart
Chris@43:         lea r13, [r10 + rbp]
Chris@43: 
Chris@43: //;;; Determine how many bytes the scan ptr is off from being
Chris@43: //;;; dword-aligned.
Chris@43: 
Chris@43:          mov r9,r13
Chris@43:          neg r13
Chris@43:          and r13,3
Chris@43: 
Chris@43: //;;; IPos limit = s->strstart > (IPos)MAX_DIST(s) ?
Chris@43: //;;;     s->strstart - (IPos)MAX_DIST(s) : NIL;
Chris@43: 
Chris@43: 
Chris@43:         mov eax, window_size
Chris@43:         sub eax, MIN_LOOKAHEAD
Chris@43: 
Chris@43: 
Chris@43:         xor edi,edi
Chris@43:         sub ebp, eax
Chris@43: 
Chris@43:         mov r11d, prev_length
Chris@43: 
Chris@43:         cmovng ebp,edi
Chris@43: 
Chris@43: //;;; int best_len = s->prev_length;
Chris@43: 
Chris@43: 
Chris@43: //;;; Store the sum of s->window + best_len in esi locally, and in esi.
Chris@43: 
Chris@43:        lea  rsi,[r10+r11]
Chris@43: 
Chris@43: //;;; register ush scan_start = *(ushf*)scan;
Chris@43: //;;; register ush scan_end   = *(ushf*)(scan+best_len-1);
Chris@43: //;;; Posf *prev = s->prev;
Chris@43: 
Chris@43:         movzx r12d,word ptr [r9]
Chris@43:         movzx ebx, word ptr [r9 + r11 - 1]
Chris@43: 
Chris@43:         mov rdi, prev_ad
Chris@43: 
Chris@43: //;;; Jump into the main loop.
Chris@43: 
Chris@43:         mov edx, [chainlenwmask]
Chris@43: 
Chris@43:         cmp bx,word ptr [rsi + r8 - 1]
Chris@43:         jz  LookupLoopIsZero
Chris@43: 				
Chris@43: 						
Chris@43: 						
Chris@43: LookupLoop1:
Chris@43:         and r8d, edx
Chris@43: 
Chris@43:         movzx   r8d, word ptr [rdi + r8*2]
Chris@43:         cmp r8d, ebp
Chris@43:         jbe LeaveNow
Chris@43: 		
Chris@43: 		
Chris@43: 		
Chris@43:         sub edx, 0x00010000
Chris@43: 		BEFORE_JMP
Chris@43:         js  LeaveNow
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LoopEntry1:
Chris@43:         cmp bx,word ptr [rsi + r8 - 1]
Chris@43: 		BEFORE_JMP
Chris@43:         jz  LookupLoopIsZero
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LookupLoop2:
Chris@43:         and r8d, edx
Chris@43: 
Chris@43:         movzx   r8d, word ptr [rdi + r8*2]
Chris@43:         cmp r8d, ebp
Chris@43: 		BEFORE_JMP
Chris@43:         jbe LeaveNow
Chris@43: 		AFTER_JMP
Chris@43:         sub edx, 0x00010000
Chris@43: 		BEFORE_JMP
Chris@43:         js  LeaveNow
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LoopEntry2:
Chris@43:         cmp bx,word ptr [rsi + r8 - 1]
Chris@43: 		BEFORE_JMP
Chris@43:         jz  LookupLoopIsZero
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LookupLoop4:
Chris@43:         and r8d, edx
Chris@43: 
Chris@43:         movzx   r8d, word ptr [rdi + r8*2]
Chris@43:         cmp r8d, ebp
Chris@43: 		BEFORE_JMP
Chris@43:         jbe LeaveNow
Chris@43: 		AFTER_JMP
Chris@43:         sub edx, 0x00010000
Chris@43: 		BEFORE_JMP
Chris@43:         js  LeaveNow
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LoopEntry4:
Chris@43: 
Chris@43:         cmp bx,word ptr [rsi + r8 - 1]
Chris@43: 		BEFORE_JMP
Chris@43:         jnz LookupLoop1
Chris@43:         jmp LookupLoopIsZero
Chris@43: 		AFTER_JMP
Chris@43: /*
Chris@43: ;;; do {
Chris@43: ;;;     match = s->window + cur_match;
Chris@43: ;;;     if (*(ushf*)(match+best_len-1) != scan_end ||
Chris@43: ;;;         *(ushf*)match != scan_start) continue;
Chris@43: ;;;     [...]
Chris@43: ;;; } while ((cur_match = prev[cur_match & wmask]) > limit
Chris@43: ;;;          && --chain_length != 0);
Chris@43: ;;;
Chris@43: ;;; Here is the inner loop of the function. The function will spend the
Chris@43: ;;; majority of its time in this loop, and majority of that time will
Chris@43: ;;; be spent in the first ten instructions.
Chris@43: ;;;
Chris@43: ;;; Within this loop:
Chris@43: ;;; ebx = scanend
Chris@43: ;;; r8d = curmatch
Chris@43: ;;; edx = chainlenwmask - i.e., ((chainlen << 16) | wmask)
Chris@43: ;;; esi = windowbestlen - i.e., (window + bestlen)
Chris@43: ;;; edi = prev
Chris@43: ;;; ebp = limit
Chris@43: */
Chris@43: .balign 16
Chris@43: LookupLoop:
Chris@43:         and r8d, edx
Chris@43: 
Chris@43:         movzx   r8d, word ptr [rdi + r8*2]
Chris@43:         cmp r8d, ebp
Chris@43: 		BEFORE_JMP
Chris@43:         jbe LeaveNow
Chris@43: 		AFTER_JMP
Chris@43:         sub edx, 0x00010000
Chris@43: 		BEFORE_JMP
Chris@43:         js  LeaveNow
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LoopEntry:
Chris@43: 
Chris@43:         cmp bx,word ptr [rsi + r8 - 1]
Chris@43: 		BEFORE_JMP
Chris@43:         jnz LookupLoop1
Chris@43: 		AFTER_JMP
Chris@43: LookupLoopIsZero:
Chris@43:         cmp     r12w, word ptr [r10 + r8]
Chris@43: 		BEFORE_JMP
Chris@43:         jnz LookupLoop1
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: 
Chris@43: //;;; Store the current value of chainlen.
Chris@43:         mov [chainlenwmask], edx
Chris@43: /*
Chris@43: ;;; Point edi to the string under scrutiny, and esi to the string we
Chris@43: ;;; are hoping to match it up with. In actuality, esi and edi are
Chris@43: ;;; both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and edx is
Chris@43: ;;; initialized to -(MAX_MATCH_8 - scanalign).
Chris@43: */
Chris@43:         lea rsi,[r8+r10]
Chris@43:         mov rdx, 0xfffffffffffffef8 //; -(MAX_MATCH_8)
Chris@43:         lea rsi, [rsi + r13 + 0x0108] //;MAX_MATCH_8]
Chris@43:         lea rdi, [r9 + r13 + 0x0108] //;MAX_MATCH_8]
Chris@43: 
Chris@43:         prefetcht1 [rsi+rdx]
Chris@43:         prefetcht1 [rdi+rdx]
Chris@43: 
Chris@43: /*
Chris@43: ;;; Test the strings for equality, 8 bytes at a time. At the end,
Chris@43: ;;; adjust rdx so that it is offset to the exact byte that mismatched.
Chris@43: ;;;
Chris@43: ;;; We already know at this point that the first three bytes of the
Chris@43: ;;; strings match each other, and they can be safely passed over before
Chris@43: ;;; starting the compare loop. So what this code does is skip over 0-3
Chris@43: ;;; bytes, as much as necessary in order to dword-align the edi
Chris@43: ;;; pointer. (rsi will still be misaligned three times out of four.)
Chris@43: ;;;
Chris@43: ;;; It should be confessed that this loop usually does not represent
Chris@43: ;;; much of the total running time. Replacing it with a more
Chris@43: ;;; straightforward "rep cmpsb" would not drastically degrade
Chris@43: ;;; performance.
Chris@43: */
Chris@43: 
Chris@43: LoopCmps:
Chris@43:         mov rax, [rsi + rdx]
Chris@43:         xor rax, [rdi + rdx]
Chris@43:         jnz LeaveLoopCmps
Chris@43: 
Chris@43:         mov rax, [rsi + rdx + 8]
Chris@43:         xor rax, [rdi + rdx + 8]
Chris@43:         jnz LeaveLoopCmps8
Chris@43: 
Chris@43: 
Chris@43:         mov rax, [rsi + rdx + 8+8]
Chris@43:         xor rax, [rdi + rdx + 8+8]
Chris@43:         jnz LeaveLoopCmps16
Chris@43: 
Chris@43:         add rdx,8+8+8
Chris@43: 
Chris@43: 		BEFORE_JMP
Chris@43:         jnz  LoopCmps
Chris@43:         jmp  LenMaximum
Chris@43: 		AFTER_JMP
Chris@43: 		
Chris@43: LeaveLoopCmps16: add rdx,8
Chris@43: LeaveLoopCmps8: add rdx,8
Chris@43: LeaveLoopCmps:
Chris@43: 
Chris@43:         test    eax, 0x0000FFFF
Chris@43:         jnz LenLower
Chris@43: 
Chris@43:         test eax,0xffffffff
Chris@43: 
Chris@43:         jnz LenLower32
Chris@43: 
Chris@43:         add rdx,4
Chris@43:         shr rax,32
Chris@43:         or ax,ax
Chris@43: 		BEFORE_JMP
Chris@43:         jnz LenLower
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: LenLower32:
Chris@43:         shr eax,16
Chris@43:         add rdx,2
Chris@43: 		
Chris@43: LenLower:		
Chris@43:         sub al, 1
Chris@43:         adc rdx, 0
Chris@43: //;;; Calculate the length of the match. If it is longer than MAX_MATCH,
Chris@43: //;;; then automatically accept it as the best possible match and leave.
Chris@43: 
Chris@43:         lea rax, [rdi + rdx]
Chris@43:         sub rax, r9
Chris@43:         cmp eax, MAX_MATCH
Chris@43: 		BEFORE_JMP
Chris@43:         jge LenMaximum
Chris@43: 		AFTER_JMP
Chris@43: /*
Chris@43: ;;; If the length of the match is not longer than the best match we
Chris@43: ;;; have so far, then forget it and return to the lookup loop.
Chris@43: ;///////////////////////////////////
Chris@43: */
Chris@43:         cmp eax, r11d
Chris@43:         jg  LongerMatch
Chris@43: 
Chris@43:         lea rsi,[r10+r11]
Chris@43: 
Chris@43:         mov rdi, prev_ad
Chris@43:         mov edx, [chainlenwmask]
Chris@43: 		BEFORE_JMP
Chris@43:         jmp LookupLoop
Chris@43: 		AFTER_JMP
Chris@43: /*
Chris@43: ;;;         s->match_start = cur_match;
Chris@43: ;;;         best_len = len;
Chris@43: ;;;         if (len >= nice_match) break;
Chris@43: ;;;         scan_end = *(ushf*)(scan+best_len-1);
Chris@43: */
Chris@43: LongerMatch:
Chris@43:         mov r11d, eax
Chris@43:         mov match_start, r8d
Chris@43:         cmp eax, [nicematch]
Chris@43: 		BEFORE_JMP
Chris@43:         jge LeaveNow
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43:         lea rsi,[r10+rax]
Chris@43: 
Chris@43:         movzx   ebx, word ptr [r9 + rax - 1]
Chris@43:         mov rdi, prev_ad
Chris@43:         mov edx, [chainlenwmask]
Chris@43: 		BEFORE_JMP
Chris@43:         jmp LookupLoop
Chris@43: 		AFTER_JMP
Chris@43: 
Chris@43: //;;; Accept the current string, with the maximum possible length.
Chris@43: 
Chris@43: LenMaximum:
Chris@43:         mov r11d,MAX_MATCH
Chris@43:         mov match_start, r8d
Chris@43: 
Chris@43: //;;; if ((uInt)best_len <= s->lookahead) return (uInt)best_len;
Chris@43: //;;; return s->lookahead;
Chris@43: 
Chris@43: LeaveNow:
Chris@43:         mov eax, Lookahead
Chris@43:         cmp r11d, eax
Chris@43:         cmovng eax, r11d
Chris@43: 
Chris@43: 
Chris@43: 
Chris@43: //;;; Restore the stack and return from whence we came.
Chris@43: 
Chris@43: 
Chris@43: //        mov rsi,[save_rsi]
Chris@43: //        mov rdi,[save_rdi]
Chris@43:         mov rbx,[save_rbx]
Chris@43:         mov rbp,[save_rbp]
Chris@43:         mov r12,[save_r12]
Chris@43:         mov r13,[save_r13]
Chris@43:         mov r14,[save_r14]
Chris@43:         mov r15,[save_r15]
Chris@43: 
Chris@43: 
Chris@43:         ret 0
Chris@43: //; please don't remove this string !
Chris@43: //; Your can freely use gvmat64 in any free or commercial app
Chris@43: //; but it is far better don't remove the string in the binary!
Chris@43:  //   db     0dh,0ah,"asm686 with masm, optimised assembly code from Brian Raiter, written 1998, converted to amd 64 by Gilles Vollant 2005",0dh,0ah,0
Chris@43: 
Chris@43: 
Chris@43: match_init:
Chris@43:   ret 0
Chris@43: 
Chris@43: