Chris@82: # Helper functions for option handling.                    -*- Autoconf -*-
Chris@82: #
Chris@82: #   Copyright (C) 2004-2005, 2007-2009, 2011-2015 Free Software
Chris@82: #   Foundation, Inc.
Chris@82: #   Written by Gary V. Vaughan, 2004
Chris@82: #
Chris@82: # This file is free software; the Free Software Foundation gives
Chris@82: # unlimited permission to copy and/or distribute it, with or without
Chris@82: # modifications, as long as this notice is preserved.
Chris@82: 
Chris@82: # serial 8 ltoptions.m4
Chris@82: 
Chris@82: # This is to help aclocal find these macros, as it can't see m4_define.
Chris@82: AC_DEFUN([LTOPTIONS_VERSION], [m4_if([1])])
Chris@82: 
Chris@82: 
Chris@82: # _LT_MANGLE_OPTION(MACRO-NAME, OPTION-NAME)
Chris@82: # ------------------------------------------
Chris@82: m4_define([_LT_MANGLE_OPTION],
Chris@82: [[_LT_OPTION_]m4_bpatsubst($1__$2, [[^a-zA-Z0-9_]], [_])])
Chris@82: 
Chris@82: 
Chris@82: # _LT_SET_OPTION(MACRO-NAME, OPTION-NAME)
Chris@82: # ---------------------------------------
Chris@82: # Set option OPTION-NAME for macro MACRO-NAME, and if there is a
Chris@82: # matching handler defined, dispatch to it.  Other OPTION-NAMEs are
Chris@82: # saved as a flag.
Chris@82: m4_define([_LT_SET_OPTION],
Chris@82: [m4_define(_LT_MANGLE_OPTION([$1], [$2]))dnl
Chris@82: m4_ifdef(_LT_MANGLE_DEFUN([$1], [$2]),
Chris@82:         _LT_MANGLE_DEFUN([$1], [$2]),
Chris@82:     [m4_warning([Unknown $1 option '$2'])])[]dnl
Chris@82: ])
Chris@82: 
Chris@82: 
Chris@82: # _LT_IF_OPTION(MACRO-NAME, OPTION-NAME, IF-SET, [IF-NOT-SET])
Chris@82: # ------------------------------------------------------------
Chris@82: # Execute IF-SET if OPTION is set, IF-NOT-SET otherwise.
Chris@82: m4_define([_LT_IF_OPTION],
Chris@82: [m4_ifdef(_LT_MANGLE_OPTION([$1], [$2]), [$3], [$4])])
Chris@82: 
Chris@82: 
Chris@82: # _LT_UNLESS_OPTIONS(MACRO-NAME, OPTION-LIST, IF-NOT-SET)
Chris@82: # -------------------------------------------------------
Chris@82: # Execute IF-NOT-SET unless all options in OPTION-LIST for MACRO-NAME
Chris@82: # are set.
Chris@82: m4_define([_LT_UNLESS_OPTIONS],
Chris@82: [m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
Chris@82: 	    [m4_ifdef(_LT_MANGLE_OPTION([$1], _LT_Option),
Chris@82: 		      [m4_define([$0_found])])])[]dnl
Chris@82: m4_ifdef([$0_found], [m4_undefine([$0_found])], [$3
Chris@82: ])[]dnl
Chris@82: ])
Chris@82: 
Chris@82: 
Chris@82: # _LT_SET_OPTIONS(MACRO-NAME, OPTION-LIST)
Chris@82: # ----------------------------------------
Chris@82: # OPTION-LIST is a space-separated list of Libtool options associated
Chris@82: # with MACRO-NAME.  If any OPTION has a matching handler declared with
Chris@82: # LT_OPTION_DEFINE, dispatch to that macro; otherwise complain about
Chris@82: # the unknown option and exit.
Chris@82: m4_defun([_LT_SET_OPTIONS],
Chris@82: [# Set options
Chris@82: m4_foreach([_LT_Option], m4_split(m4_normalize([$2])),
Chris@82:     [_LT_SET_OPTION([$1], _LT_Option)])
Chris@82: 
Chris@82: m4_if([$1],[LT_INIT],[
Chris@82:   dnl
Chris@82:   dnl Simply set some default values (i.e off) if boolean options were not
Chris@82:   dnl specified:
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [dlopen], [enable_dlopen=no
Chris@82:   ])
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [win32-dll], [enable_win32_dll=no
Chris@82:   ])
Chris@82:   dnl
Chris@82:   dnl If no reference was made to various pairs of opposing options, then
Chris@82:   dnl we run the default mode handler for the pair.  For example, if neither
Chris@82:   dnl 'shared' nor 'disable-shared' was passed, we enable building of shared
Chris@82:   dnl archives by default:
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [shared disable-shared], [_LT_ENABLE_SHARED])
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [static disable-static], [_LT_ENABLE_STATIC])
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [pic-only no-pic], [_LT_WITH_PIC])
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [fast-install disable-fast-install],
Chris@82: 		   [_LT_ENABLE_FAST_INSTALL])
Chris@82:   _LT_UNLESS_OPTIONS([LT_INIT], [aix-soname=aix aix-soname=both aix-soname=svr4],
Chris@82: 		   [_LT_WITH_AIX_SONAME([aix])])
Chris@82:   ])
Chris@82: ])# _LT_SET_OPTIONS
Chris@82: 
Chris@82: 
Chris@82: ## --------------------------------- ##
Chris@82: ## Macros to handle LT_INIT options. ##
Chris@82: ## --------------------------------- ##
Chris@82: 
Chris@82: # _LT_MANGLE_DEFUN(MACRO-NAME, OPTION-NAME)
Chris@82: # -----------------------------------------
Chris@82: m4_define([_LT_MANGLE_DEFUN],
Chris@82: [[_LT_OPTION_DEFUN_]m4_bpatsubst(m4_toupper([$1__$2]), [[^A-Z0-9_]], [_])])
Chris@82: 
Chris@82: 
Chris@82: # LT_OPTION_DEFINE(MACRO-NAME, OPTION-NAME, CODE)
Chris@82: # -----------------------------------------------
Chris@82: m4_define([LT_OPTION_DEFINE],
Chris@82: [m4_define(_LT_MANGLE_DEFUN([$1], [$2]), [$3])[]dnl
Chris@82: ])# LT_OPTION_DEFINE
Chris@82: 
Chris@82: 
Chris@82: # dlopen
Chris@82: # ------
Chris@82: LT_OPTION_DEFINE([LT_INIT], [dlopen], [enable_dlopen=yes
Chris@82: ])
Chris@82: 
Chris@82: AU_DEFUN([AC_LIBTOOL_DLOPEN],
Chris@82: [_LT_SET_OPTION([LT_INIT], [dlopen])
Chris@82: AC_DIAGNOSE([obsolete],
Chris@82: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@82: put the 'dlopen' option into LT_INIT's first parameter.])
Chris@82: ])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AC_LIBTOOL_DLOPEN], [])
Chris@82: 
Chris@82: 
Chris@82: # win32-dll
Chris@82: # ---------
Chris@82: # Declare package support for building win32 dll's.
Chris@82: LT_OPTION_DEFINE([LT_INIT], [win32-dll],
Chris@82: [enable_win32_dll=yes
Chris@82: 
Chris@82: case $host in
Chris@82: *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-cegcc*)
Chris@82:   AC_CHECK_TOOL(AS, as, false)
Chris@82:   AC_CHECK_TOOL(DLLTOOL, dlltool, false)
Chris@82:   AC_CHECK_TOOL(OBJDUMP, objdump, false)
Chris@82:   ;;
Chris@82: esac
Chris@82: 
Chris@82: test -z "$AS" && AS=as
Chris@82: _LT_DECL([], [AS],      [1], [Assembler program])dnl
Chris@82: 
Chris@82: test -z "$DLLTOOL" && DLLTOOL=dlltool
Chris@82: _LT_DECL([], [DLLTOOL], [1], [DLL creation program])dnl
Chris@82: 
Chris@82: test -z "$OBJDUMP" && OBJDUMP=objdump
Chris@82: _LT_DECL([], [OBJDUMP], [1], [Object dumper program])dnl
Chris@82: ])# win32-dll
Chris@82: 
Chris@82: AU_DEFUN([AC_LIBTOOL_WIN32_DLL],
Chris@82: [AC_REQUIRE([AC_CANONICAL_HOST])dnl
Chris@82: _LT_SET_OPTION([LT_INIT], [win32-dll])
Chris@82: AC_DIAGNOSE([obsolete],
Chris@82: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@82: put the 'win32-dll' option into LT_INIT's first parameter.])
Chris@82: ])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AC_LIBTOOL_WIN32_DLL], [])
Chris@82: 
Chris@82: 
Chris@82: # _LT_ENABLE_SHARED([DEFAULT])
Chris@82: # ----------------------------
Chris@82: # implement the --enable-shared flag, and supports the 'shared' and
Chris@82: # 'disable-shared' LT_INIT options.
Chris@82: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@82: m4_define([_LT_ENABLE_SHARED],
Chris@82: [m4_define([_LT_ENABLE_SHARED_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@82: AC_ARG_ENABLE([shared],
Chris@82:     [AS_HELP_STRING([--enable-shared@<:@=PKGS@:>@],
Chris@82: 	[build shared libraries @<:@default=]_LT_ENABLE_SHARED_DEFAULT[@:>@])],
Chris@82:     [p=${PACKAGE-default}
Chris@82:     case $enableval in
Chris@82:     yes) enable_shared=yes ;;
Chris@82:     no) enable_shared=no ;;
Chris@82:     *)
Chris@82:       enable_shared=no
Chris@82:       # Look at the argument we got.  We use all the common list separators.
Chris@82:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@82:       for pkg in $enableval; do
Chris@82: 	IFS=$lt_save_ifs
Chris@82: 	if test "X$pkg" = "X$p"; then
Chris@82: 	  enable_shared=yes
Chris@82: 	fi
Chris@82:       done
Chris@82:       IFS=$lt_save_ifs
Chris@82:       ;;
Chris@82:     esac],
Chris@82:     [enable_shared=]_LT_ENABLE_SHARED_DEFAULT)
Chris@82: 
Chris@82:     _LT_DECL([build_libtool_libs], [enable_shared], [0],
Chris@82: 	[Whether or not to build shared libraries])
Chris@82: ])# _LT_ENABLE_SHARED
Chris@82: 
Chris@82: LT_OPTION_DEFINE([LT_INIT], [shared], [_LT_ENABLE_SHARED([yes])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [disable-shared], [_LT_ENABLE_SHARED([no])])
Chris@82: 
Chris@82: # Old names:
Chris@82: AC_DEFUN([AC_ENABLE_SHARED],
Chris@82: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[shared])
Chris@82: ])
Chris@82: 
Chris@82: AC_DEFUN([AC_DISABLE_SHARED],
Chris@82: [_LT_SET_OPTION([LT_INIT], [disable-shared])
Chris@82: ])
Chris@82: 
Chris@82: AU_DEFUN([AM_ENABLE_SHARED], [AC_ENABLE_SHARED($@)])
Chris@82: AU_DEFUN([AM_DISABLE_SHARED], [AC_DISABLE_SHARED($@)])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AM_ENABLE_SHARED], [])
Chris@82: dnl AC_DEFUN([AM_DISABLE_SHARED], [])
Chris@82: 
Chris@82: 
Chris@82: 
Chris@82: # _LT_ENABLE_STATIC([DEFAULT])
Chris@82: # ----------------------------
Chris@82: # implement the --enable-static flag, and support the 'static' and
Chris@82: # 'disable-static' LT_INIT options.
Chris@82: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@82: m4_define([_LT_ENABLE_STATIC],
Chris@82: [m4_define([_LT_ENABLE_STATIC_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@82: AC_ARG_ENABLE([static],
Chris@82:     [AS_HELP_STRING([--enable-static@<:@=PKGS@:>@],
Chris@82: 	[build static libraries @<:@default=]_LT_ENABLE_STATIC_DEFAULT[@:>@])],
Chris@82:     [p=${PACKAGE-default}
Chris@82:     case $enableval in
Chris@82:     yes) enable_static=yes ;;
Chris@82:     no) enable_static=no ;;
Chris@82:     *)
Chris@82:      enable_static=no
Chris@82:       # Look at the argument we got.  We use all the common list separators.
Chris@82:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@82:       for pkg in $enableval; do
Chris@82: 	IFS=$lt_save_ifs
Chris@82: 	if test "X$pkg" = "X$p"; then
Chris@82: 	  enable_static=yes
Chris@82: 	fi
Chris@82:       done
Chris@82:       IFS=$lt_save_ifs
Chris@82:       ;;
Chris@82:     esac],
Chris@82:     [enable_static=]_LT_ENABLE_STATIC_DEFAULT)
Chris@82: 
Chris@82:     _LT_DECL([build_old_libs], [enable_static], [0],
Chris@82: 	[Whether or not to build static libraries])
Chris@82: ])# _LT_ENABLE_STATIC
Chris@82: 
Chris@82: LT_OPTION_DEFINE([LT_INIT], [static], [_LT_ENABLE_STATIC([yes])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [disable-static], [_LT_ENABLE_STATIC([no])])
Chris@82: 
Chris@82: # Old names:
Chris@82: AC_DEFUN([AC_ENABLE_STATIC],
Chris@82: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[static])
Chris@82: ])
Chris@82: 
Chris@82: AC_DEFUN([AC_DISABLE_STATIC],
Chris@82: [_LT_SET_OPTION([LT_INIT], [disable-static])
Chris@82: ])
Chris@82: 
Chris@82: AU_DEFUN([AM_ENABLE_STATIC], [AC_ENABLE_STATIC($@)])
Chris@82: AU_DEFUN([AM_DISABLE_STATIC], [AC_DISABLE_STATIC($@)])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AM_ENABLE_STATIC], [])
Chris@82: dnl AC_DEFUN([AM_DISABLE_STATIC], [])
Chris@82: 
Chris@82: 
Chris@82: 
Chris@82: # _LT_ENABLE_FAST_INSTALL([DEFAULT])
Chris@82: # ----------------------------------
Chris@82: # implement the --enable-fast-install flag, and support the 'fast-install'
Chris@82: # and 'disable-fast-install' LT_INIT options.
Chris@82: # DEFAULT is either 'yes' or 'no'.  If omitted, it defaults to 'yes'.
Chris@82: m4_define([_LT_ENABLE_FAST_INSTALL],
Chris@82: [m4_define([_LT_ENABLE_FAST_INSTALL_DEFAULT], [m4_if($1, no, no, yes)])dnl
Chris@82: AC_ARG_ENABLE([fast-install],
Chris@82:     [AS_HELP_STRING([--enable-fast-install@<:@=PKGS@:>@],
Chris@82:     [optimize for fast installation @<:@default=]_LT_ENABLE_FAST_INSTALL_DEFAULT[@:>@])],
Chris@82:     [p=${PACKAGE-default}
Chris@82:     case $enableval in
Chris@82:     yes) enable_fast_install=yes ;;
Chris@82:     no) enable_fast_install=no ;;
Chris@82:     *)
Chris@82:       enable_fast_install=no
Chris@82:       # Look at the argument we got.  We use all the common list separators.
Chris@82:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@82:       for pkg in $enableval; do
Chris@82: 	IFS=$lt_save_ifs
Chris@82: 	if test "X$pkg" = "X$p"; then
Chris@82: 	  enable_fast_install=yes
Chris@82: 	fi
Chris@82:       done
Chris@82:       IFS=$lt_save_ifs
Chris@82:       ;;
Chris@82:     esac],
Chris@82:     [enable_fast_install=]_LT_ENABLE_FAST_INSTALL_DEFAULT)
Chris@82: 
Chris@82: _LT_DECL([fast_install], [enable_fast_install], [0],
Chris@82: 	 [Whether or not to optimize for fast installation])dnl
Chris@82: ])# _LT_ENABLE_FAST_INSTALL
Chris@82: 
Chris@82: LT_OPTION_DEFINE([LT_INIT], [fast-install], [_LT_ENABLE_FAST_INSTALL([yes])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [disable-fast-install], [_LT_ENABLE_FAST_INSTALL([no])])
Chris@82: 
Chris@82: # Old names:
Chris@82: AU_DEFUN([AC_ENABLE_FAST_INSTALL],
Chris@82: [_LT_SET_OPTION([LT_INIT], m4_if([$1], [no], [disable-])[fast-install])
Chris@82: AC_DIAGNOSE([obsolete],
Chris@82: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
Chris@82: the 'fast-install' option into LT_INIT's first parameter.])
Chris@82: ])
Chris@82: 
Chris@82: AU_DEFUN([AC_DISABLE_FAST_INSTALL],
Chris@82: [_LT_SET_OPTION([LT_INIT], [disable-fast-install])
Chris@82: AC_DIAGNOSE([obsolete],
Chris@82: [$0: Remove this warning and the call to _LT_SET_OPTION when you put
Chris@82: the 'disable-fast-install' option into LT_INIT's first parameter.])
Chris@82: ])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AC_ENABLE_FAST_INSTALL], [])
Chris@82: dnl AC_DEFUN([AM_DISABLE_FAST_INSTALL], [])
Chris@82: 
Chris@82: 
Chris@82: # _LT_WITH_AIX_SONAME([DEFAULT])
Chris@82: # ----------------------------------
Chris@82: # implement the --with-aix-soname flag, and support the `aix-soname=aix'
Chris@82: # and `aix-soname=both' and `aix-soname=svr4' LT_INIT options. DEFAULT
Chris@82: # is either `aix', `both' or `svr4'.  If omitted, it defaults to `aix'.
Chris@82: m4_define([_LT_WITH_AIX_SONAME],
Chris@82: [m4_define([_LT_WITH_AIX_SONAME_DEFAULT], [m4_if($1, svr4, svr4, m4_if($1, both, both, aix))])dnl
Chris@82: shared_archive_member_spec=
Chris@82: case $host,$enable_shared in
Chris@82: power*-*-aix[[5-9]]*,yes)
Chris@82:   AC_MSG_CHECKING([which variant of shared library versioning to provide])
Chris@82:   AC_ARG_WITH([aix-soname],
Chris@82:     [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
Chris@82:       [shared library versioning (aka "SONAME") variant to provide on AIX, @<:@default=]_LT_WITH_AIX_SONAME_DEFAULT[@:>@.])],
Chris@82:     [case $withval in
Chris@82:     aix|svr4|both)
Chris@82:       ;;
Chris@82:     *)
Chris@82:       AC_MSG_ERROR([Unknown argument to --with-aix-soname])
Chris@82:       ;;
Chris@82:     esac
Chris@82:     lt_cv_with_aix_soname=$with_aix_soname],
Chris@82:     [AC_CACHE_VAL([lt_cv_with_aix_soname],
Chris@82:       [lt_cv_with_aix_soname=]_LT_WITH_AIX_SONAME_DEFAULT)
Chris@82:     with_aix_soname=$lt_cv_with_aix_soname])
Chris@82:   AC_MSG_RESULT([$with_aix_soname])
Chris@82:   if test aix != "$with_aix_soname"; then
Chris@82:     # For the AIX way of multilib, we name the shared archive member
Chris@82:     # based on the bitwidth used, traditionally 'shr.o' or 'shr_64.o',
Chris@82:     # and 'shr.imp' or 'shr_64.imp', respectively, for the Import File.
Chris@82:     # Even when GNU compilers ignore OBJECT_MODE but need '-maix64' flag,
Chris@82:     # the AIX toolchain works better with OBJECT_MODE set (default 32).
Chris@82:     if test 64 = "${OBJECT_MODE-32}"; then
Chris@82:       shared_archive_member_spec=shr_64
Chris@82:     else
Chris@82:       shared_archive_member_spec=shr
Chris@82:     fi
Chris@82:   fi
Chris@82:   ;;
Chris@82: *)
Chris@82:   with_aix_soname=aix
Chris@82:   ;;
Chris@82: esac
Chris@82: 
Chris@82: _LT_DECL([], [shared_archive_member_spec], [0],
Chris@82:     [Shared archive member basename, for filename based shared library versioning on AIX])dnl
Chris@82: ])# _LT_WITH_AIX_SONAME
Chris@82: 
Chris@82: LT_OPTION_DEFINE([LT_INIT], [aix-soname=aix], [_LT_WITH_AIX_SONAME([aix])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [aix-soname=both], [_LT_WITH_AIX_SONAME([both])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [aix-soname=svr4], [_LT_WITH_AIX_SONAME([svr4])])
Chris@82: 
Chris@82: 
Chris@82: # _LT_WITH_PIC([MODE])
Chris@82: # --------------------
Chris@82: # implement the --with-pic flag, and support the 'pic-only' and 'no-pic'
Chris@82: # LT_INIT options.
Chris@82: # MODE is either 'yes' or 'no'.  If omitted, it defaults to 'both'.
Chris@82: m4_define([_LT_WITH_PIC],
Chris@82: [AC_ARG_WITH([pic],
Chris@82:     [AS_HELP_STRING([--with-pic@<:@=PKGS@:>@],
Chris@82: 	[try to use only PIC/non-PIC objects @<:@default=use both@:>@])],
Chris@82:     [lt_p=${PACKAGE-default}
Chris@82:     case $withval in
Chris@82:     yes|no) pic_mode=$withval ;;
Chris@82:     *)
Chris@82:       pic_mode=default
Chris@82:       # Look at the argument we got.  We use all the common list separators.
Chris@82:       lt_save_ifs=$IFS; IFS=$IFS$PATH_SEPARATOR,
Chris@82:       for lt_pkg in $withval; do
Chris@82: 	IFS=$lt_save_ifs
Chris@82: 	if test "X$lt_pkg" = "X$lt_p"; then
Chris@82: 	  pic_mode=yes
Chris@82: 	fi
Chris@82:       done
Chris@82:       IFS=$lt_save_ifs
Chris@82:       ;;
Chris@82:     esac],
Chris@82:     [pic_mode=m4_default([$1], [default])])
Chris@82: 
Chris@82: _LT_DECL([], [pic_mode], [0], [What type of objects to build])dnl
Chris@82: ])# _LT_WITH_PIC
Chris@82: 
Chris@82: LT_OPTION_DEFINE([LT_INIT], [pic-only], [_LT_WITH_PIC([yes])])
Chris@82: LT_OPTION_DEFINE([LT_INIT], [no-pic], [_LT_WITH_PIC([no])])
Chris@82: 
Chris@82: # Old name:
Chris@82: AU_DEFUN([AC_LIBTOOL_PICMODE],
Chris@82: [_LT_SET_OPTION([LT_INIT], [pic-only])
Chris@82: AC_DIAGNOSE([obsolete],
Chris@82: [$0: Remove this warning and the call to _LT_SET_OPTION when you
Chris@82: put the 'pic-only' option into LT_INIT's first parameter.])
Chris@82: ])
Chris@82: 
Chris@82: dnl aclocal-1.4 backwards compatibility:
Chris@82: dnl AC_DEFUN([AC_LIBTOOL_PICMODE], [])
Chris@82: 
Chris@82: ## ----------------- ##
Chris@82: ## LTDL_INIT Options ##
Chris@82: ## ----------------- ##
Chris@82: 
Chris@82: m4_define([_LTDL_MODE], [])
Chris@82: LT_OPTION_DEFINE([LTDL_INIT], [nonrecursive],
Chris@82: 		 [m4_define([_LTDL_MODE], [nonrecursive])])
Chris@82: LT_OPTION_DEFINE([LTDL_INIT], [recursive],
Chris@82: 		 [m4_define([_LTDL_MODE], [recursive])])
Chris@82: LT_OPTION_DEFINE([LTDL_INIT], [subproject],
Chris@82: 		 [m4_define([_LTDL_MODE], [subproject])])
Chris@82: 
Chris@82: m4_define([_LTDL_TYPE], [])
Chris@82: LT_OPTION_DEFINE([LTDL_INIT], [installable],
Chris@82: 		 [m4_define([_LTDL_TYPE], [installable])])
Chris@82: LT_OPTION_DEFINE([LTDL_INIT], [convenience],
Chris@82: 		 [m4_define([_LTDL_TYPE], [convenience])])