cannam@95: dnl @synopsis ACX_MPI([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
cannam@95: dnl @summary figure out how to compile/link code with MPI
cannam@95: dnl @category InstalledPackages
cannam@95: dnl
cannam@95: dnl This macro tries to find out how to compile programs that
cannam@95: dnl use MPI (Message Passing Interface), a standard API for
cannam@95: dnl parallel process communication (see http://www-unix.mcs.anl.gov/mpi/)
cannam@95: dnl
cannam@95: dnl On success, it sets the MPICC, MPICXX, or MPIF77 output variable to
cannam@95: dnl the name of the MPI compiler, depending upon the current language.
cannam@95: dnl (This may just be $CC/$CXX/$F77, but is more often something like
cannam@95: dnl mpicc/mpiCC/mpif77.)  It also sets MPILIBS to any libraries that are
cannam@95: dnl needed for linking MPI (e.g. -lmpi, if a special MPICC/MPICXX/MPIF77
cannam@95: dnl was not found).
cannam@95: dnl
cannam@95: dnl If you want to compile everything with MPI, you should set:
cannam@95: dnl
cannam@95: dnl     CC="$MPICC" #OR# CXX="$MPICXX" #OR# F77="$MPIF77"
cannam@95: dnl     LIBS="$MPILIBS $LIBS"
cannam@95: dnl
cannam@95: dnl NOTE: The above assumes that you will use $CC (or whatever)
cannam@95: dnl       for linking as well as for compiling.  (This is the
cannam@95: dnl       default for automake and most Makefiles.)
cannam@95: dnl
cannam@95: dnl The user can force a particular library/compiler by setting the
cannam@95: dnl MPICC/MPICXX/MPIF77 and/or MPILIBS environment variables.
cannam@95: dnl
cannam@95: dnl ACTION-IF-FOUND is a list of shell commands to run if an MPI
cannam@95: dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
cannam@95: dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
cannam@95: dnl the default action will define HAVE_MPI.
cannam@95: dnl
cannam@95: dnl @version 2005-09-02
cannam@95: dnl @license GPLWithACException
cannam@95: dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
cannam@95: 
cannam@95: AC_DEFUN([ACX_MPI], [
cannam@95: AC_PREREQ(2.50) dnl for AC_LANG_CASE
cannam@95: 
cannam@95: AC_LANG_CASE([C], [
cannam@95: 	AC_REQUIRE([AC_PROG_CC])
cannam@95: 	AC_ARG_VAR(MPICC,[MPI C compiler command])
cannam@95: 	AC_CHECK_PROGS(MPICC, mpicc hcc mpcc mpcc_r mpxlc cmpicc, $CC)
cannam@95: 	acx_mpi_save_CC="$CC"
cannam@95: 	CC="$MPICC"
cannam@95: 	AC_SUBST(MPICC)
cannam@95: ],
cannam@95: [C++], [
cannam@95: 	AC_REQUIRE([AC_PROG_CXX])
cannam@95: 	AC_ARG_VAR(MPICXX,[MPI C++ compiler command])
cannam@95: 	AC_CHECK_PROGS(MPICXX, mpic++ mpiCC mpicxx mpCC hcp mpxlC mpxlC_r cmpic++, $CXX)
cannam@95: 	acx_mpi_save_CXX="$CXX"
cannam@95: 	CXX="$MPICXX"
cannam@95: 	AC_SUBST(MPICXX)
cannam@95: ],
cannam@95: [Fortran 77], [
cannam@95: 	AC_REQUIRE([AC_PROG_F77])
cannam@95: 	AC_ARG_VAR(MPIF77,[MPI Fortran compiler command])
cannam@95: 	AC_CHECK_PROGS(MPIF77, mpif77 hf77 mpxlf mpf77 mpif90 mpf90 mpxlf90 mpxlf95 mpxlf_r cmpifc cmpif90c, $F77)
cannam@95: 	acx_mpi_save_F77="$F77"
cannam@95: 	F77="$MPIF77"
cannam@95: 	AC_SUBST(MPIF77)
cannam@95: ])
cannam@95: 
cannam@95: if test x = x"$MPILIBS"; then
cannam@95: 	AC_LANG_CASE([C], [AC_CHECK_FUNC(MPI_Init, [MPILIBS=" "])],
cannam@95: 		[C++], [AC_CHECK_FUNC(MPI_Init, [MPILIBS=" "])],
cannam@95: 		[Fortran 77], [AC_MSG_CHECKING([for MPI_Init])
cannam@95: 			AC_TRY_LINK([],[      call MPI_Init], [MPILIBS=" "
cannam@95: 				AC_MSG_RESULT(yes)], [AC_MSG_RESULT(no)])])
cannam@95: fi
cannam@95: if test x = x"$MPILIBS"; then
cannam@95: 	AC_CHECK_LIB(mpi, MPI_Init, [MPILIBS="-lmpi"])
cannam@95: fi
cannam@95: if test x = x"$MPILIBS"; then
cannam@95: 	AC_CHECK_LIB(mpich, MPI_Init, [MPILIBS="-lmpich"])
cannam@95: fi
cannam@95: 
cannam@95: dnl We have to use AC_TRY_COMPILE and not AC_CHECK_HEADER because the
cannam@95: dnl latter uses $CPP, not $CC (which may be mpicc).
cannam@95: AC_LANG_CASE([C], [if test x != x"$MPILIBS"; then
cannam@95: 	AC_MSG_CHECKING([for mpi.h])
cannam@95: 	AC_TRY_COMPILE([#include <mpi.h>],[],[AC_MSG_RESULT(yes)], [MPILIBS=""
cannam@95: 		AC_MSG_RESULT(no)])
cannam@95: fi],
cannam@95: [C++], [if test x != x"$MPILIBS"; then
cannam@95: 	AC_MSG_CHECKING([for mpi.h])
cannam@95: 	AC_TRY_COMPILE([#include <mpi.h>],[],[AC_MSG_RESULT(yes)], [MPILIBS=""
cannam@95: 		AC_MSG_RESULT(no)])
cannam@95: fi])
cannam@95: 
cannam@95: AC_LANG_CASE([C], [CC="$acx_mpi_save_CC"],
cannam@95: 	[C++], [CXX="$acx_mpi_save_CXX"],
cannam@95: 	[Fortran 77], [F77="$acx_mpi_save_F77"])
cannam@95: 
cannam@95: AC_SUBST(MPILIBS)
cannam@95: 
cannam@95: # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
cannam@95: if test x = x"$MPILIBS"; then
cannam@95:         $2
cannam@95:         :
cannam@95: else
cannam@95:         ifelse([$1],,[AC_DEFINE(HAVE_MPI,1,[Define if you have the MPI library.])],[$1])
cannam@95:         :
cannam@95: fi
cannam@95: ])dnl ACX_MPI