cannam@133: ## Process this file with autoconf to produce configure.
cannam@133: 
cannam@133: AC_INIT([Capn Proto],[0.6-dev],[capnproto@googlegroups.com],[capnproto-c++])
cannam@133: 
cannam@133: AC_CONFIG_SRCDIR([src/capnp/layout.c++])
cannam@133: AC_CONFIG_AUX_DIR([build-aux])
cannam@133: AC_CONFIG_HEADERS([config.h])
cannam@133: AC_CONFIG_MACRO_DIR([m4])
cannam@133: 
cannam@133: # autoconf's default CXXFLAGS are usually "-g -O2".  A far more reasonable
cannam@133: # default is -O2 -NDEBUG.
cannam@133: AS_IF([test "x${ac_cv_env_CFLAGS_set}" = "x"],
cannam@133:       [CFLAGS="-O2 -DNDEBUG"])
cannam@133: AS_IF([test "x${ac_cv_env_CXXFLAGS_set}" = "x"],
cannam@133:       [CXXFLAGS="-O2 -DNDEBUG"])
cannam@133: 
cannam@133: AM_INIT_AUTOMAKE([tar-ustar])
cannam@133: 
cannam@133: AC_ARG_WITH([external-capnp],
cannam@133:   [AS_HELP_STRING([--with-external-capnp],
cannam@133:     [use the system capnp binary (or the one specified with $CAPNP) instead of compiling a new
cannam@133:      one (useful for cross-compiling)])],
cannam@133:   [external_capnp=yes],[external_capnp=no])
cannam@133: 
cannam@133: AC_ARG_ENABLE([reflection], [
cannam@133:   AS_HELP_STRING([--disable-reflection], [
cannam@133:     compile Cap'n Proto in "lite mode", in which all reflection APIs (schema.h, dynamic.h, etc.)
cannam@133:     are not included. Produces a smaller library at the cost of features. All programs built
cannam@133:     against the library MUST be compiled with -DCAPNP_LITE=1. Note that because the compiler
cannam@133:     itself uses reflection in its implementation, you must also use --with-external-capnp when
cannam@133:     using this option.])
cannam@133:   ], [
cannam@133:     case "${enableval}" in
cannam@133:       yes)
cannam@133:         lite_mode=no
cannam@133:         ;;
cannam@133:       no)
cannam@133:         lite_mode=yes
cannam@133:         AS_IF([test "$external_capnp" != "yes"], [
cannam@133:           AC_MSG_ERROR([you must specify --with-external-capnp when using --disable-reflection])
cannam@133:         ])
cannam@133:         ;;
cannam@133:       *)
cannam@133:         AC_MSG_ERROR([bad value ${enableval} for --enable-reflection])
cannam@133:         ;;
cannam@133:     esac
cannam@133:   ], [lite_mode=no])
cannam@133: 
cannam@133: # Checks for programs.
cannam@133: AC_PROG_CC
cannam@133: AC_PROG_CXX
cannam@133: AC_LANG([C++])
cannam@133: AX_CXX_COMPILE_STDCXX_11
cannam@133: 
cannam@133: AS_CASE("${host_os}", *mingw*, [
cannam@133:     # We don't use pthreads on MinGW.
cannam@133:     PTHREAD_CFLAGS="-mthreads"
cannam@133:     PTHREAD_LIBS=""
cannam@133:     PTHREAD_CC=""
cannam@133:     AC_SUBST(PTHREAD_LIBS)
cannam@133:     AC_SUBST(PTHREAD_CFLAGS)
cannam@133:     AC_SUBST(PTHREAD_CC)
cannam@133:   ], *, [
cannam@133:     ACX_PTHREAD
cannam@133:   ])
cannam@133: 
cannam@133: LT_INIT
cannam@133: 
cannam@133: AS_IF([test "$external_capnp" != "no"], [
cannam@133: 	AS_IF([test "x$CAPNP" = "x"], [CAPNP="capnp"], [with_capnp=yes])
cannam@133: 	AS_IF([test "x$CAPNPC_CXX" = "x"], [
cannam@133: 	  # CAPNPC_CXX was not specified.  Choose a reasonable default.
cannam@133: 	  AS_CASE([$CAPNP], [*/*], [
cannam@133: 	    # $CAPNP contains a slash, so it's not on $PATH.  Assume capnpc-c++ is not either, but is
cannam@133: 	    # in the same directory.
cannam@133: 	    CAPNPC_CXX=`dirname $CAPNP`/capnpc-c++
cannam@133: 	  ], [
cannam@133: 	    # $CAPNP is on $PATH, so tell it to find the plugin on $PATH as well.
cannam@133: 	    CAPNPC_CXX="c++"
cannam@133: 	  ])
cannam@133: 	])
cannam@133: 	AC_SUBST([CAPNP])
cannam@133: 	AC_SUBST([CAPNPC_CXX])
cannam@133: ])
cannam@133: AM_CONDITIONAL([USE_EXTERNAL_CAPNP], [test "$external_capnp" != "no"])
cannam@133: 
cannam@133: AM_CONDITIONAL([LITE_MODE], [test "$lite_mode" = "yes"])
cannam@133: 
cannam@133: AS_IF([test "$lite_mode" = "yes"], [
cannam@133:   CXXFLAGS="-DCAPNP_LITE $CXXFLAGS"
cannam@133:   CAPNP_LITE_FLAG=-DCAPNP_LITE
cannam@133: ])
cannam@133: AC_SUBST([CAPNP_LITE_FLAG])
cannam@133: 
cannam@133: AC_SEARCH_LIBS(sched_yield, rt)
cannam@133: 
cannam@133: # Users will need to use the same -stdlib as us so we'd better let pkg-config know about it.
cannam@133: STDLIB_FLAG=`echo "$CXX $CXXFLAGS" | grep -o ' [[-]]stdlib=[[^ ]]*'`
cannam@133: AC_SUBST([STDLIB_FLAG])
cannam@133: 
cannam@133: LIBS="$PTHREAD_LIBS $LIBS"
cannam@133: CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
cannam@133: 
cannam@133: AC_CONFIG_FILES([Makefile capnp.pc capnp-rpc.pc capnp-json.pc kj.pc kj-async.pc])
cannam@133: AC_OUTPUT