cannam@48: #
cannam@48: # Finds the Cap'n Proto libraries, and compiles schema files.
cannam@48: #
cannam@48: # Configuration variables (optional):
cannam@48: #   CAPNPC_OUTPUT_DIR
cannam@48: #       Directory to place compiled schema sources (default: the same directory as the schema file).
cannam@48: #   CAPNPC_IMPORT_DIRS
cannam@48: #       List of additional include directories for the schema compiler.
cannam@48: #       (CMAKE_CURRENT_SOURCE_DIR and CAPNP_INCLUDE_DIRS are always included.)
cannam@48: #   CAPNPC_SRC_PREFIX
cannam@48: #       Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
cannam@48: #   CAPNPC_FLAGS
cannam@48: #       Additional flags to pass to the schema compiler.
cannam@48: #
cannam@48: # Variables that are discovered:
cannam@48: #   CAPNP_EXECUTABLE
cannam@48: #       Path to the `capnp` tool (can be set to override).
cannam@48: #   CAPNPC_CXX_EXECUTABLE
cannam@48: #       Path to the `capnpc-c++` tool (can be set to override).
cannam@48: #   CAPNP_INCLUDE_DIRS
cannam@48: #       Include directories for the library's headers (can be set to override).
cannam@48: #   CANP_LIBRARIES
cannam@48: #       The Cap'n Proto library paths.
cannam@48: #   CAPNP_LIBRARIES_LITE
cannam@48: #       Paths to only the 'lite' libraries.
cannam@48: #   CAPNP_DEFINITIONS
cannam@48: #       Compiler definitions required for building with the library.
cannam@48: #   CAPNP_FOUND
cannam@48: #       Set if the libraries have been located.
cannam@48: #
cannam@48: # Example usage:
cannam@48: #
cannam@48: #   find_package(CapnProto REQUIRED)
cannam@48: #   include_directories(${CAPNP_INCLUDE_DIRS})
cannam@48: #   add_definitions(${CAPNP_DEFINITIONS})
cannam@48: #
cannam@48: #   capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
cannam@48: #   add_executable(a a.cc ${CAPNP_SRCS} ${CAPNP_HDRS})
cannam@48: #   target_link_library(a ${CAPNP_LIBRARIES})
cannam@48: #
cannam@48: # For out-of-source builds:
cannam@48: #
cannam@48: #   set(CAPNPC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR})
cannam@48: #   include_directories(${CAPNPC_OUTPUT_DIR})
cannam@48: #   capnp_generate_cpp(...)
cannam@48: #
cannam@48: 
cannam@48: # CAPNP_GENERATE_CPP ===========================================================
cannam@48: 
cannam@48: function(CAPNP_GENERATE_CPP SOURCES HEADERS)
cannam@48:   if(NOT ARGN)
cannam@48:     message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
cannam@48:   endif()
cannam@48:   if(NOT CAPNP_EXECUTABLE)
cannam@48:     message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
cannam@48:   endif()
cannam@48:   if(NOT CAPNPC_CXX_EXECUTABLE)
cannam@48:     message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
cannam@48:   endif()
cannam@48:   if(NOT CAPNP_INCLUDE_DIRS)
cannam@48:     message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRS).")
cannam@48:   endif()
cannam@48: 
cannam@48:   # Default compiler includes
cannam@48:   set(include_path -I ${CMAKE_CURRENT_SOURCE_DIR} -I ${CAPNP_INCLUDE_DIRS})
cannam@48: 
cannam@48:   if(DEFINED CAPNPC_IMPORT_DIRS)
cannam@48:     # Append each directory as a series of '-I' flags in ${include_path}
cannam@48:     foreach(directory ${CAPNPC_IMPORT_DIRS})
cannam@48:       get_filename_component(absolute_path "${directory}" ABSOLUTE)
cannam@48:       list(APPEND include_path -I ${absolute_path})
cannam@48:     endforeach()
cannam@48:   endif()
cannam@48: 
cannam@48:   if(DEFINED CAPNPC_OUTPUT_DIR)
cannam@48:     # Prepend a ':' to get the format for the '-o' flag right
cannam@48:     set(output_dir ":${CAPNPC_OUTPUT_DIR}")
cannam@48:   else()
cannam@48:     set(output_dir ":.")
cannam@48:   endif()
cannam@48: 
cannam@48:   if(NOT DEFINED CAPNPC_SRC_PREFIX)
cannam@48:     set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
cannam@48:   endif()
cannam@48:   get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
cannam@48: 
cannam@48:   set(${SOURCES})
cannam@48:   set(${HEADERS})
cannam@48:   foreach(schema_file ${ARGN})
cannam@48:     get_filename_component(file_path "${schema_file}" ABSOLUTE)
cannam@48:     get_filename_component(file_dir "${file_path}" PATH)
cannam@48: 
cannam@48:     # Figure out where the output files will go
cannam@48:     if (NOT DEFINED CAPNPC_OUTPUT_DIR)
cannam@48:       set(output_base "${file_path}")
cannam@48:     else()
cannam@48:       # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
cannam@48:       # relative to CAPNPC_SRC_PREFIX.
cannam@48:       string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
cannam@48:       string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
cannam@48:       if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
cannam@48:         message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
cannam@48:       endif()
cannam@48: 
cannam@48:       string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
cannam@48:       set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
cannam@48:     endif()
cannam@48: 
cannam@48:     add_custom_command(
cannam@48:       OUTPUT "${output_base}.c++" "${output_base}.h"
cannam@48:       COMMAND "${CAPNP_EXECUTABLE}"
cannam@48:       ARGS compile 
cannam@48:           -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
cannam@48:           --src-prefix ${CAPNPC_SRC_PREFIX}
cannam@48:           ${include_path}
cannam@48:           ${CAPNPC_FLAGS}
cannam@48:           ${file_path}
cannam@48:       DEPENDS "${schema_file}"
cannam@48:       COMMENT "Compiling Cap'n Proto schema ${schema_file}"
cannam@48:       VERBATIM
cannam@48:     )
cannam@48:     list(APPEND ${SOURCES} "${output_base}.c++")
cannam@48:     list(APPEND ${HEADERS} "${output_base}.h")
cannam@48:   endforeach()
cannam@48: 
cannam@48:   set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
cannam@48:   set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
cannam@48:   set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
cannam@48: endfunction()
cannam@48: 
cannam@48: # Find Libraries/Paths =========================================================
cannam@48: 
cannam@48: # Use pkg-config to get path hints and definitions
cannam@48: find_package(PkgConfig QUIET)
cannam@48: pkg_check_modules(PKGCONFIG_CAPNP capnp)
cannam@48: pkg_check_modules(PKGCONFIG_CAPNP_RPC capnp-rpc QUIET)
cannam@48: pkg_check_modules(PKGCONFIG_CAPNP_JSON capnp-json QUIET)
cannam@48: 
cannam@48: find_library(CAPNP_LIB_KJ kj
cannam@48:   HINTS "${PKGCONFIG_CAPNP_LIBDIR}" ${PKGCONFIG_CAPNP_LIBRARY_DIRS}
cannam@48: )
cannam@48: find_library(CAPNP_LIB_KJ-ASYNC kj-async
cannam@48:   HINTS "${PKGCONFIG_CAPNP_RPC_LIBDIR}" ${PKGCONFIG_CAPNP_RPC_LIBRARY_DIRS}
cannam@48: )
cannam@48: find_library(CAPNP_LIB_CAPNP capnp
cannam@48:   HINTS "${PKGCONFIG_CAPNP_LIBDIR}" ${PKGCONFIG_CAPNP_LIBRARY_DIRS}
cannam@48: )
cannam@48: find_library(CAPNP_LIB_CAPNP-RPC capnp-rpc
cannam@48:   HINTS "${PKGCONFIG_CAPNP_RPC_LIBDIR}" ${PKGCONFIG_CAPNP_RPC_LIBRARY_DIRS}
cannam@48: )
cannam@48: find_library(CAPNP_LIB_CAPNP-JSON capnp-json
cannam@48:   HINTS "${PKGCONFIG_CAPNP_JSON_LIBDIR}" ${PKGCONFIG_CAPNP_JSON_LIBRARY_DIRS}
cannam@48: )
cannam@48: mark_as_advanced(CAPNP_LIB_KJ CAPNP_LIB_KJ-ASYNC CAPNP_LIB_CAPNP CAPNP_LIB_CAPNP-RPC CAPNP_LIB_CAPNP-JSON)
cannam@48: set(CAPNP_LIBRARIES_LITE
cannam@48:   ${CAPNP_LIB_CAPNP}
cannam@48:   ${CAPNP_LIB_KJ}
cannam@48: )
cannam@48: set(CAPNP_LIBRARIES
cannam@48:   ${CAPNP_LIB_CAPNP-JSON}
cannam@48:   ${CAPNP_LIB_CAPNP-RPC}
cannam@48:   ${CAPNP_LIB_CAPNP}
cannam@48:   ${CAPNP_LIB_KJ-ASYNC}
cannam@48:   ${CAPNP_LIB_KJ}
cannam@48: )
cannam@48: 
cannam@48: # Was only the 'lite' library found?
cannam@48: if(CAPNP_LIB_CAPNP AND NOT CAPNP_LIB_CAPNP-RPC)
cannam@48:   set(CAPNP_DEFINITIONS -DCAPNP_LITE)
cannam@48: else()
cannam@48:   set(CAPNP_DEFINITIONS)
cannam@48: endif()
cannam@48: 
cannam@48: find_path(CAPNP_INCLUDE_DIRS capnp/generated-header-support.h
cannam@48:   HINTS "${PKGCONFIG_CAPNP_INCLUDEDIR}" ${PKGCONFIG_CAPNP_INCLUDE_DIRS}
cannam@48: )
cannam@48: 
cannam@48: find_program(CAPNP_EXECUTABLE
cannam@48:   NAMES capnp
cannam@48:   DOC "Cap'n Proto Command-line Tool"
cannam@48:   HINTS "${PKGCONFIG_CAPNP_PREFIX}/bin"
cannam@48: )
cannam@48: 
cannam@48: find_program(CAPNPC_CXX_EXECUTABLE
cannam@48:   NAMES capnpc-c++
cannam@48:   DOC "Capn'n Proto C++ Compiler"
cannam@48:   HINTS "${PKGCONFIG_CAPNP_PREFIX}/bin"
cannam@48: )
cannam@48: 
cannam@48: # Only *require* the include directory, libkj, and libcapnp. If compiling with
cannam@48: # CAPNP_LITE, nothing else will be found.
cannam@48: include(FindPackageHandleStandardArgs)
cannam@48: find_package_handle_standard_args(CAPNP DEFAULT_MSG
cannam@48:   CAPNP_INCLUDE_DIRS
cannam@48:   CAPNP_LIB_KJ
cannam@48:   CAPNP_LIB_CAPNP
cannam@48: )