cannam@48: # CAPNP_GENERATE_CPP ===========================================================
cannam@48: #
cannam@48: # Example usage:
cannam@48: #   find_package(CapnProto)
cannam@48: #   capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
cannam@48: #   include_directories(${CMAKE_CURRENT_BINARY_DIR})
cannam@48: #   add_executable(foo main.cpp ${CAPNP_SRCS})
cannam@48: #   target_link_libraries(foo CapnProto::capnp-rpc)
cannam@48: #
cannam@48: #  If you are using not using the RPC features you can use
cannam@48: #  'CapnProto::capnp' in target_link_libraries call
cannam@48: #
cannam@48: # Configuration variables (optional):
cannam@48: #   CAPNPC_OUTPUT_DIR
cannam@48: #       Directory to place compiled schema sources (default: CMAKE_CURRENT_BINARY_DIR).
cannam@48: #   CAPNPC_IMPORT_DIRS
cannam@48: #       List of additional include directories for the schema compiler.
cannam@48: #       (CMAKE_CURRENT_SOURCE_DIR and CAPNP_INCLUDE_DIRECTORY are always included.)
cannam@48: #   CAPNPC_SRC_PREFIX
cannam@48: #       Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
cannam@48: #   CAPNPC_FLAGS
cannam@48: #       Additional flags to pass to the schema compiler.
cannam@48: #
cannam@48: # TODO: convert to cmake_parse_arguments
cannam@48: 
cannam@48: function(CAPNP_GENERATE_CPP SOURCES HEADERS)
cannam@48:   if(NOT ARGN)
cannam@48:     message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
cannam@48:   endif()
cannam@48:   set(tool_depends ${EMPTY_STRING})
cannam@48:   #Use cmake targets available
cannam@48:   if(TARGET capnp_tool)
cannam@48:     set(CAPNP_EXECUTABLE capnp_tool)
cannam@48:     GET_TARGET_PROPERTY(CAPNPC_CXX_EXECUTABLE capnpc_cpp CAPNPC_CXX_EXECUTABLE)
cannam@48:     GET_TARGET_PROPERTY(CAPNP_INCLUDE_DIRECTORY capnp_tool CAPNP_INCLUDE_DIRECTORY)
cannam@48:     list(APPEND tool_depends capnp_tool capnpc_cpp)
cannam@48:   endif()
cannam@48:   if(NOT CAPNP_EXECUTABLE)
cannam@48:     message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
cannam@48:   endif()
cannam@48:   if(NOT CAPNPC_CXX_EXECUTABLE)
cannam@48:     message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
cannam@48:   endif()
cannam@48:   if(NOT CAPNP_INCLUDE_DIRECTORY)
cannam@48:     message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRECTORY).")
cannam@48:   endif()
cannam@48: 
cannam@48:   # Default compiler includes
cannam@48:   set(include_path -I ${CMAKE_CURRENT_SOURCE_DIR} -I ${CAPNP_INCLUDE_DIRECTORY})
cannam@48: 
cannam@48:   if(DEFINED CAPNPC_IMPORT_DIRS)
cannam@48:     # Append each directory as a series of '-I' flags in ${include_path}
cannam@48:     foreach(directory ${CAPNPC_IMPORT_DIRS})
cannam@48:       get_filename_component(absolute_path "${directory}" ABSOLUTE)
cannam@48:       list(APPEND include_path -I ${absolute_path})
cannam@48:     endforeach()
cannam@48:   endif()
cannam@48: 
cannam@48:   if(DEFINED CAPNPC_OUTPUT_DIR)
cannam@48:     # Prepend a ':' to get the format for the '-o' flag right
cannam@48:     set(output_dir ":${CAPNPC_OUTPUT_DIR}")
cannam@48:   else()
cannam@48:     set(output_dir ":.")
cannam@48:   endif()
cannam@48: 
cannam@48:   if(NOT DEFINED CAPNPC_SRC_PREFIX)
cannam@48:     set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
cannam@48:   endif()
cannam@48:   get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
cannam@48: 
cannam@48:   set(${SOURCES})
cannam@48:   set(${HEADERS})
cannam@48:   foreach(schema_file ${ARGN})
cannam@48:     if(NOT EXISTS "${CAPNPC_SRC_PREFIX}/${schema_file}")
cannam@48:       message(FATAL_ERROR "Cap'n Proto schema file '${CAPNPC_SRC_PREFIX}/${schema_file}' does not exist!")
cannam@48:     endif()
cannam@48:     get_filename_component(file_path "${schema_file}" ABSOLUTE)
cannam@48:     get_filename_component(file_dir "${file_path}" PATH)
cannam@48: 
cannam@48:     # Figure out where the output files will go
cannam@48:     if (NOT DEFINED CAPNPC_OUTPUT_DIR)
cannam@48:       set(CAPNPC_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/")
cannam@48:     endif()
cannam@48:     # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
cannam@48:     # relative to CAPNPC_SRC_PREFIX.
cannam@48:     string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
cannam@48:     string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
cannam@48:     if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
cannam@48:       message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
cannam@48:     endif()
cannam@48: 
cannam@48:     string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
cannam@48:     set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
cannam@48: 
cannam@48:     add_custom_command(
cannam@48:       OUTPUT "${output_base}.c++" "${output_base}.h"
cannam@48:       COMMAND "${CAPNP_EXECUTABLE}"
cannam@48:       ARGS compile
cannam@48:           -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
cannam@48:           --src-prefix ${CAPNPC_SRC_PREFIX}
cannam@48:           ${include_path}
cannam@48:           ${CAPNPC_FLAGS}
cannam@48:           ${file_path}
cannam@48:       DEPENDS "${schema_file}" ${tool_depends}
cannam@48:       COMMENT "Compiling Cap'n Proto schema ${schema_file}"
cannam@48:       VERBATIM
cannam@48:     )
cannam@48: 
cannam@48:     list(APPEND ${SOURCES} "${output_base}.c++")
cannam@48:     list(APPEND ${HEADERS} "${output_base}.h")
cannam@48:   endforeach()
cannam@48: 
cannam@48:   set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
cannam@48:   set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
cannam@48:   set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
cannam@48: endfunction()