cannam@133: #
cannam@133: # Finds the Cap'n Proto libraries, and compiles schema files.
cannam@133: #
cannam@133: # Configuration variables (optional):
cannam@133: #   CAPNPC_OUTPUT_DIR
cannam@133: #       Directory to place compiled schema sources (default: the same directory as the schema file).
cannam@133: #   CAPNPC_IMPORT_DIRS
cannam@133: #       List of additional include directories for the schema compiler.
cannam@133: #       (CMAKE_CURRENT_SOURCE_DIR and CAPNP_INCLUDE_DIRS are always included.)
cannam@133: #   CAPNPC_SRC_PREFIX
cannam@133: #       Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
cannam@133: #   CAPNPC_FLAGS
cannam@133: #       Additional flags to pass to the schema compiler.
cannam@133: #
cannam@133: # Variables that are discovered:
cannam@133: #   CAPNP_EXECUTABLE
cannam@133: #       Path to the `capnp` tool (can be set to override).
cannam@133: #   CAPNPC_CXX_EXECUTABLE
cannam@133: #       Path to the `capnpc-c++` tool (can be set to override).
cannam@133: #   CAPNP_INCLUDE_DIRS
cannam@133: #       Include directories for the library's headers (can be set to override).
cannam@133: #   CANP_LIBRARIES
cannam@133: #       The Cap'n Proto library paths.
cannam@133: #   CAPNP_LIBRARIES_LITE
cannam@133: #       Paths to only the 'lite' libraries.
cannam@133: #   CAPNP_DEFINITIONS
cannam@133: #       Compiler definitions required for building with the library.
cannam@133: #   CAPNP_FOUND
cannam@133: #       Set if the libraries have been located.
cannam@133: #
cannam@133: # Example usage:
cannam@133: #
cannam@133: #   find_package(CapnProto REQUIRED)
cannam@133: #   include_directories(${CAPNP_INCLUDE_DIRS})
cannam@133: #   add_definitions(${CAPNP_DEFINITIONS})
cannam@133: #
cannam@133: #   capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
cannam@133: #   add_executable(a a.cc ${CAPNP_SRCS} ${CAPNP_HDRS})
cannam@133: #   target_link_library(a ${CAPNP_LIBRARIES})
cannam@133: #
cannam@133: # For out-of-source builds:
cannam@133: #
cannam@133: #   set(CAPNPC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR})
cannam@133: #   include_directories(${CAPNPC_OUTPUT_DIR})
cannam@133: #   capnp_generate_cpp(...)
cannam@133: #
cannam@133: 
cannam@133: # CAPNP_GENERATE_CPP ===========================================================
cannam@133: 
cannam@133: function(CAPNP_GENERATE_CPP SOURCES HEADERS)
cannam@133:   if(NOT ARGN)
cannam@133:     message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
cannam@133:   endif()
cannam@133:   if(NOT CAPNP_EXECUTABLE)
cannam@133:     message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
cannam@133:   endif()
cannam@133:   if(NOT CAPNPC_CXX_EXECUTABLE)
cannam@133:     message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
cannam@133:   endif()
cannam@133:   if(NOT CAPNP_INCLUDE_DIRS)
cannam@133:     message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRS).")
cannam@133:   endif()
cannam@133: 
cannam@133:   # Default compiler includes
cannam@133:   set(include_path -I ${CMAKE_CURRENT_SOURCE_DIR} -I ${CAPNP_INCLUDE_DIRS})
cannam@133: 
cannam@133:   if(DEFINED CAPNPC_IMPORT_DIRS)
cannam@133:     # Append each directory as a series of '-I' flags in ${include_path}
cannam@133:     foreach(directory ${CAPNPC_IMPORT_DIRS})
cannam@133:       get_filename_component(absolute_path "${directory}" ABSOLUTE)
cannam@133:       list(APPEND include_path -I ${absolute_path})
cannam@133:     endforeach()
cannam@133:   endif()
cannam@133: 
cannam@133:   if(DEFINED CAPNPC_OUTPUT_DIR)
cannam@133:     # Prepend a ':' to get the format for the '-o' flag right
cannam@133:     set(output_dir ":${CAPNPC_OUTPUT_DIR}")
cannam@133:   else()
cannam@133:     set(output_dir ":.")
cannam@133:   endif()
cannam@133: 
cannam@133:   if(NOT DEFINED CAPNPC_SRC_PREFIX)
cannam@133:     set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
cannam@133:   endif()
cannam@133:   get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
cannam@133: 
cannam@133:   set(${SOURCES})
cannam@133:   set(${HEADERS})
cannam@133:   foreach(schema_file ${ARGN})
cannam@133:     get_filename_component(file_path "${schema_file}" ABSOLUTE)
cannam@133:     get_filename_component(file_dir "${file_path}" PATH)
cannam@133: 
cannam@133:     # Figure out where the output files will go
cannam@133:     if (NOT DEFINED CAPNPC_OUTPUT_DIR)
cannam@133:       set(output_base "${file_path}")
cannam@133:     else()
cannam@133:       # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
cannam@133:       # relative to CAPNPC_SRC_PREFIX.
cannam@133:       string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
cannam@133:       string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
cannam@133:       if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
cannam@133:         message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
cannam@133:       endif()
cannam@133: 
cannam@133:       string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
cannam@133:       set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
cannam@133:     endif()
cannam@133: 
cannam@133:     add_custom_command(
cannam@133:       OUTPUT "${output_base}.c++" "${output_base}.h"
cannam@133:       COMMAND "${CAPNP_EXECUTABLE}"
cannam@133:       ARGS compile 
cannam@133:           -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
cannam@133:           --src-prefix ${CAPNPC_SRC_PREFIX}
cannam@133:           ${include_path}
cannam@133:           ${CAPNPC_FLAGS}
cannam@133:           ${file_path}
cannam@133:       DEPENDS "${schema_file}"
cannam@133:       COMMENT "Compiling Cap'n Proto schema ${schema_file}"
cannam@133:       VERBATIM
cannam@133:     )
cannam@133:     list(APPEND ${SOURCES} "${output_base}.c++")
cannam@133:     list(APPEND ${HEADERS} "${output_base}.h")
cannam@133:   endforeach()
cannam@133: 
cannam@133:   set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
cannam@133:   set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
cannam@133:   set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
cannam@133: endfunction()
cannam@133: 
cannam@133: # Find Libraries/Paths =========================================================
cannam@133: 
cannam@133: # Use pkg-config to get path hints and definitions
cannam@133: find_package(PkgConfig QUIET)
cannam@133: pkg_check_modules(PKGCONFIG_CAPNP capnp)
cannam@133: pkg_check_modules(PKGCONFIG_CAPNP_RPC capnp-rpc QUIET)
cannam@133: pkg_check_modules(PKGCONFIG_CAPNP_JSON capnp-json QUIET)
cannam@133: 
cannam@133: find_library(CAPNP_LIB_KJ kj
cannam@133:   HINTS "${PKGCONFIG_CAPNP_LIBDIR}" ${PKGCONFIG_CAPNP_LIBRARY_DIRS}
cannam@133: )
cannam@133: find_library(CAPNP_LIB_KJ-ASYNC kj-async
cannam@133:   HINTS "${PKGCONFIG_CAPNP_RPC_LIBDIR}" ${PKGCONFIG_CAPNP_RPC_LIBRARY_DIRS}
cannam@133: )
cannam@133: find_library(CAPNP_LIB_CAPNP capnp
cannam@133:   HINTS "${PKGCONFIG_CAPNP_LIBDIR}" ${PKGCONFIG_CAPNP_LIBRARY_DIRS}
cannam@133: )
cannam@133: find_library(CAPNP_LIB_CAPNP-RPC capnp-rpc
cannam@133:   HINTS "${PKGCONFIG_CAPNP_RPC_LIBDIR}" ${PKGCONFIG_CAPNP_RPC_LIBRARY_DIRS}
cannam@133: )
cannam@133: find_library(CAPNP_LIB_CAPNP-JSON capnp-json
cannam@133:   HINTS "${PKGCONFIG_CAPNP_JSON_LIBDIR}" ${PKGCONFIG_CAPNP_JSON_LIBRARY_DIRS}
cannam@133: )
cannam@133: mark_as_advanced(CAPNP_LIB_KJ CAPNP_LIB_KJ-ASYNC CAPNP_LIB_CAPNP CAPNP_LIB_CAPNP-RPC CAPNP_LIB_CAPNP-JSON)
cannam@133: set(CAPNP_LIBRARIES_LITE
cannam@133:   ${CAPNP_LIB_CAPNP}
cannam@133:   ${CAPNP_LIB_KJ}
cannam@133: )
cannam@133: set(CAPNP_LIBRARIES
cannam@133:   ${CAPNP_LIB_CAPNP-JSON}
cannam@133:   ${CAPNP_LIB_CAPNP-RPC}
cannam@133:   ${CAPNP_LIB_CAPNP}
cannam@133:   ${CAPNP_LIB_KJ-ASYNC}
cannam@133:   ${CAPNP_LIB_KJ}
cannam@133: )
cannam@133: 
cannam@133: # Was only the 'lite' library found?
cannam@133: if(CAPNP_LIB_CAPNP AND NOT CAPNP_LIB_CAPNP-RPC)
cannam@133:   set(CAPNP_DEFINITIONS -DCAPNP_LITE)
cannam@133: else()
cannam@133:   set(CAPNP_DEFINITIONS)
cannam@133: endif()
cannam@133: 
cannam@133: find_path(CAPNP_INCLUDE_DIRS capnp/generated-header-support.h
cannam@133:   HINTS "${PKGCONFIG_CAPNP_INCLUDEDIR}" ${PKGCONFIG_CAPNP_INCLUDE_DIRS}
cannam@133: )
cannam@133: 
cannam@133: find_program(CAPNP_EXECUTABLE
cannam@133:   NAMES capnp
cannam@133:   DOC "Cap'n Proto Command-line Tool"
cannam@133:   HINTS "${PKGCONFIG_CAPNP_PREFIX}/bin"
cannam@133: )
cannam@133: 
cannam@133: find_program(CAPNPC_CXX_EXECUTABLE
cannam@133:   NAMES capnpc-c++
cannam@133:   DOC "Capn'n Proto C++ Compiler"
cannam@133:   HINTS "${PKGCONFIG_CAPNP_PREFIX}/bin"
cannam@133: )
cannam@133: 
cannam@133: # Only *require* the include directory, libkj, and libcapnp. If compiling with
cannam@133: # CAPNP_LITE, nothing else will be found.
cannam@133: include(FindPackageHandleStandardArgs)
cannam@133: find_package_handle_standard_args(CAPNP DEFAULT_MSG
cannam@133:   CAPNP_INCLUDE_DIRS
cannam@133:   CAPNP_LIB_KJ
cannam@133:   CAPNP_LIB_CAPNP
cannam@133: )