cannam@133: # CAPNP_GENERATE_CPP ===========================================================
cannam@133: #
cannam@133: # Example usage:
cannam@133: #   find_package(CapnProto)
cannam@133: #   capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
cannam@133: #   include_directories(${CMAKE_CURRENT_BINARY_DIR})
cannam@133: #   add_executable(foo main.cpp ${CAPNP_SRCS})
cannam@133: #   target_link_libraries(foo CapnProto::capnp-rpc)
cannam@133: #
cannam@133: #  If you are using not using the RPC features you can use
cannam@133: #  'CapnProto::capnp' in target_link_libraries call
cannam@133: #
cannam@133: # Configuration variables (optional):
cannam@133: #   CAPNPC_OUTPUT_DIR
cannam@133: #       Directory to place compiled schema sources (default: CMAKE_CURRENT_BINARY_DIR).
cannam@133: #   CAPNPC_IMPORT_DIRS
cannam@133: #       List of additional include directories for the schema compiler.
cannam@133: #       (CMAKE_CURRENT_SOURCE_DIR and CAPNP_INCLUDE_DIRECTORY are always included.)
cannam@133: #   CAPNPC_SRC_PREFIX
cannam@133: #       Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
cannam@133: #   CAPNPC_FLAGS
cannam@133: #       Additional flags to pass to the schema compiler.
cannam@133: #
cannam@133: # TODO: convert to cmake_parse_arguments
cannam@133: 
cannam@133: function(CAPNP_GENERATE_CPP SOURCES HEADERS)
cannam@133:   if(NOT ARGN)
cannam@133:     message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
cannam@133:   endif()
cannam@133:   set(tool_depends ${EMPTY_STRING})
cannam@133:   #Use cmake targets available
cannam@133:   if(TARGET capnp_tool)
cannam@133:     set(CAPNP_EXECUTABLE capnp_tool)
cannam@133:     GET_TARGET_PROPERTY(CAPNPC_CXX_EXECUTABLE capnpc_cpp CAPNPC_CXX_EXECUTABLE)
cannam@133:     GET_TARGET_PROPERTY(CAPNP_INCLUDE_DIRECTORY capnp_tool CAPNP_INCLUDE_DIRECTORY)
cannam@133:     list(APPEND tool_depends capnp_tool capnpc_cpp)
cannam@133:   endif()
cannam@133:   if(NOT CAPNP_EXECUTABLE)
cannam@133:     message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
cannam@133:   endif()
cannam@133:   if(NOT CAPNPC_CXX_EXECUTABLE)
cannam@133:     message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
cannam@133:   endif()
cannam@133:   if(NOT CAPNP_INCLUDE_DIRECTORY)
cannam@133:     message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRECTORY).")
cannam@133:   endif()
cannam@133: 
cannam@133:   # Default compiler includes
cannam@133:   set(include_path -I ${CMAKE_CURRENT_SOURCE_DIR} -I ${CAPNP_INCLUDE_DIRECTORY})
cannam@133: 
cannam@133:   if(DEFINED CAPNPC_IMPORT_DIRS)
cannam@133:     # Append each directory as a series of '-I' flags in ${include_path}
cannam@133:     foreach(directory ${CAPNPC_IMPORT_DIRS})
cannam@133:       get_filename_component(absolute_path "${directory}" ABSOLUTE)
cannam@133:       list(APPEND include_path -I ${absolute_path})
cannam@133:     endforeach()
cannam@133:   endif()
cannam@133: 
cannam@133:   if(DEFINED CAPNPC_OUTPUT_DIR)
cannam@133:     # Prepend a ':' to get the format for the '-o' flag right
cannam@133:     set(output_dir ":${CAPNPC_OUTPUT_DIR}")
cannam@133:   else()
cannam@133:     set(output_dir ":.")
cannam@133:   endif()
cannam@133: 
cannam@133:   if(NOT DEFINED CAPNPC_SRC_PREFIX)
cannam@133:     set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
cannam@133:   endif()
cannam@133:   get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
cannam@133: 
cannam@133:   set(${SOURCES})
cannam@133:   set(${HEADERS})
cannam@133:   foreach(schema_file ${ARGN})
cannam@133:     if(NOT EXISTS "${CAPNPC_SRC_PREFIX}/${schema_file}")
cannam@133:       message(FATAL_ERROR "Cap'n Proto schema file '${CAPNPC_SRC_PREFIX}/${schema_file}' does not exist!")
cannam@133:     endif()
cannam@133:     get_filename_component(file_path "${schema_file}" ABSOLUTE)
cannam@133:     get_filename_component(file_dir "${file_path}" PATH)
cannam@133: 
cannam@133:     # Figure out where the output files will go
cannam@133:     if (NOT DEFINED CAPNPC_OUTPUT_DIR)
cannam@133:       set(CAPNPC_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/")
cannam@133:     endif()
cannam@133:     # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
cannam@133:     # relative to CAPNPC_SRC_PREFIX.
cannam@133:     string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
cannam@133:     string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
cannam@133:     if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
cannam@133:       message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
cannam@133:     endif()
cannam@133: 
cannam@133:     string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
cannam@133:     set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
cannam@133: 
cannam@133:     add_custom_command(
cannam@133:       OUTPUT "${output_base}.c++" "${output_base}.h"
cannam@133:       COMMAND "${CAPNP_EXECUTABLE}"
cannam@133:       ARGS compile
cannam@133:           -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
cannam@133:           --src-prefix ${CAPNPC_SRC_PREFIX}
cannam@133:           ${include_path}
cannam@133:           ${CAPNPC_FLAGS}
cannam@133:           ${file_path}
cannam@133:       DEPENDS "${schema_file}" ${tool_depends}
cannam@133:       COMMENT "Compiling Cap'n Proto schema ${schema_file}"
cannam@133:       VERBATIM
cannam@133:     )
cannam@133: 
cannam@133:     list(APPEND ${SOURCES} "${output_base}.c++")
cannam@133:     list(APPEND ${HEADERS} "${output_base}.h")
cannam@133:   endforeach()
cannam@133: 
cannam@133:   set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
cannam@133:   set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
cannam@133:   set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
cannam@133: endfunction()