Chris@82: dnl @synopsis AX_OPENMP([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
Chris@82: dnl @summary determine how to compile programs using OpenMP
Chris@82: dnl @category InstalledPackages
Chris@82: dnl
Chris@82: dnl This macro tries to find out how to compile programs that
Chris@82: dnl use OpenMP, a standard API and set of compiler directives for
Chris@82: dnl parallel programming (see http://www.openmp.org/).
Chris@82: dnl
Chris@82: dnl On success, it sets the OPENMP_CFLAGS/OPENMP_CXXFLAGS/OPENMP_FFLAGS
Chris@82: dnl output variable to the flag (e.g. -omp) used both to compile *and* link
Chris@82: dnl OpenMP programs in the current language.
Chris@82: dnl
Chris@82: dnl NOTE: You are assumed to not only compile your program with these
Chris@82: dnl flags, but also link it with them as well.
Chris@82: dnl
Chris@82: dnl If you want to compile everything with OpenMP, you should set:
Chris@82: dnl
Chris@82: dnl     CFLAGS="$CFLAGS $OPENMP_CFLAGS" 
Chris@82: dnl     #OR#  CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS" 
Chris@82: dnl     #OR#  FFLAGS="$FFLAGS $OPENMP_FFLAGS" 
Chris@82: dnl
Chris@82: dnl (depending on the selected language).
Chris@82: dnl
Chris@82: dnl The user can override the default choice by setting the corresponding
Chris@82: dnl environment variable (e.g. OPENMP_CFLAGS).
Chris@82: dnl
Chris@82: dnl ACTION-IF-FOUND is a list of shell commands to run if an OpenMP
Chris@82: dnl flag is found, and ACTION-IF-NOT-FOUND is a list of commands
Chris@82: dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
Chris@82: dnl the default action will define HAVE_OPENMP.
Chris@82: dnl
Chris@82: dnl @version 2006-11-20
Chris@82: dnl @license GPLWithACException
Chris@82: dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
Chris@82: 
Chris@82: AC_DEFUN([AX_OPENMP], [
Chris@82: AC_PREREQ(2.59) dnl for _AC_LANG_PREFIX
Chris@82: 
Chris@82: AC_CACHE_CHECK([for OpenMP flag of _AC_LANG compiler], ax_cv_[]_AC_LANG_ABBREV[]_openmp, [save[]_AC_LANG_PREFIX[]FLAGS=$[]_AC_LANG_PREFIX[]FLAGS
Chris@82: ax_cv_[]_AC_LANG_ABBREV[]_openmp=unknown
Chris@82: # Flags to try:  -fopenmp (gcc), -openmp (icc), -mp (SGI & PGI),
Chris@82: #                -xopenmp (Sun), -omp (Tru64), -qsmp=omp (AIX), none
Chris@82: ax_openmp_flags="-fopenmp -openmp -mp -xopenmp -omp -qsmp=omp none"
Chris@82: if test "x$OPENMP_[]_AC_LANG_PREFIX[]FLAGS" != x; then
Chris@82:   ax_openmp_flags="$OPENMP_[]_AC_LANG_PREFIX[]FLAGS $ax_openmp_flags"
Chris@82: fi
Chris@82: for ax_openmp_flag in $ax_openmp_flags; do
Chris@82:   case $ax_openmp_flag in
Chris@82:     none) []_AC_LANG_PREFIX[]FLAGS=$save[]_AC_LANG_PREFIX[] ;;
Chris@82:     *) []_AC_LANG_PREFIX[]FLAGS="$save[]_AC_LANG_PREFIX[]FLAGS $ax_openmp_flag" ;;
Chris@82:   esac
Chris@82:   AC_TRY_LINK_FUNC(omp_set_num_threads,
Chris@82: 	[ax_cv_[]_AC_LANG_ABBREV[]_openmp=$ax_openmp_flag; break])
Chris@82: done
Chris@82: []_AC_LANG_PREFIX[]FLAGS=$save[]_AC_LANG_PREFIX[]FLAGS
Chris@82: ])
Chris@82: if test "x$ax_cv_[]_AC_LANG_ABBREV[]_openmp" = "xunknown"; then
Chris@82:   m4_default([$2],:)
Chris@82: else
Chris@82:   if test "x$ax_cv_[]_AC_LANG_ABBREV[]_openmp" != "xnone"; then
Chris@82:     OPENMP_[]_AC_LANG_PREFIX[]FLAGS=$ax_cv_[]_AC_LANG_ABBREV[]_openmp
Chris@82:   fi
Chris@82:   m4_default([$1], [AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])])
Chris@82: fi
Chris@82: AC_SUBST(OPENMP_[]_AC_LANG_PREFIX[]FLAGS)
Chris@82: ])dnl AX_OPENMP