cannam@62: # CAPNP_GENERATE_CPP ===========================================================
cannam@62: #
cannam@62: # Example usage:
cannam@62: #   find_package(CapnProto)
cannam@62: #   capnp_generate_cpp(CAPNP_SRCS CAPNP_HDRS schema.capnp)
cannam@62: #   include_directories(${CMAKE_CURRENT_BINARY_DIR})
cannam@62: #   add_executable(foo main.cpp ${CAPNP_SRCS})
cannam@62: #   target_link_libraries(foo CapnProto::capnp-rpc)
cannam@62: #
cannam@62: #  If you are using not using the RPC features you can use
cannam@62: #  'CapnProto::capnp' in target_link_libraries call
cannam@62: #
cannam@62: # Configuration variables (optional):
cannam@62: #   CAPNPC_OUTPUT_DIR
cannam@62: #       Directory to place compiled schema sources (default: CMAKE_CURRENT_BINARY_DIR).
cannam@62: #   CAPNPC_IMPORT_DIRS
cannam@62: #       List of additional include directories for the schema compiler.
cannam@62: #       (CMAKE_CURRENT_SOURCE_DIR and CAPNP_INCLUDE_DIRECTORY are always included.)
cannam@62: #   CAPNPC_SRC_PREFIX
cannam@62: #       Schema file source prefix (default: CMAKE_CURRENT_SOURCE_DIR).
cannam@62: #   CAPNPC_FLAGS
cannam@62: #       Additional flags to pass to the schema compiler.
cannam@62: #
cannam@62: # TODO: convert to cmake_parse_arguments
cannam@62: 
cannam@62: function(CAPNP_GENERATE_CPP SOURCES HEADERS)
cannam@62:   if(NOT ARGN)
cannam@62:     message(SEND_ERROR "CAPNP_GENERATE_CPP() called without any source files.")
cannam@62:   endif()
cannam@62:   set(tool_depends ${EMPTY_STRING})
cannam@62:   #Use cmake targets available
cannam@62:   if(TARGET capnp_tool)
cannam@62:     set(CAPNP_EXECUTABLE capnp_tool)
cannam@62:     GET_TARGET_PROPERTY(CAPNPC_CXX_EXECUTABLE capnpc_cpp CAPNPC_CXX_EXECUTABLE)
cannam@62:     GET_TARGET_PROPERTY(CAPNP_INCLUDE_DIRECTORY capnp_tool CAPNP_INCLUDE_DIRECTORY)
cannam@62:     list(APPEND tool_depends capnp_tool capnpc_cpp)
cannam@62:   endif()
cannam@62:   if(NOT CAPNP_EXECUTABLE)
cannam@62:     message(SEND_ERROR "Could not locate capnp executable (CAPNP_EXECUTABLE).")
cannam@62:   endif()
cannam@62:   if(NOT CAPNPC_CXX_EXECUTABLE)
cannam@62:     message(SEND_ERROR "Could not locate capnpc-c++ executable (CAPNPC_CXX_EXECUTABLE).")
cannam@62:   endif()
cannam@62:   if(NOT CAPNP_INCLUDE_DIRECTORY)
cannam@62:     message(SEND_ERROR "Could not locate capnp header files (CAPNP_INCLUDE_DIRECTORY).")
cannam@62:   endif()
cannam@62: 
cannam@62:   # Default compiler includes
cannam@62:   set(include_path -I ${CMAKE_CURRENT_SOURCE_DIR} -I ${CAPNP_INCLUDE_DIRECTORY})
cannam@62: 
cannam@62:   if(DEFINED CAPNPC_IMPORT_DIRS)
cannam@62:     # Append each directory as a series of '-I' flags in ${include_path}
cannam@62:     foreach(directory ${CAPNPC_IMPORT_DIRS})
cannam@62:       get_filename_component(absolute_path "${directory}" ABSOLUTE)
cannam@62:       list(APPEND include_path -I ${absolute_path})
cannam@62:     endforeach()
cannam@62:   endif()
cannam@62: 
cannam@62:   if(DEFINED CAPNPC_OUTPUT_DIR)
cannam@62:     # Prepend a ':' to get the format for the '-o' flag right
cannam@62:     set(output_dir ":${CAPNPC_OUTPUT_DIR}")
cannam@62:   else()
cannam@62:     set(output_dir ":.")
cannam@62:   endif()
cannam@62: 
cannam@62:   if(NOT DEFINED CAPNPC_SRC_PREFIX)
cannam@62:     set(CAPNPC_SRC_PREFIX "${CMAKE_CURRENT_SOURCE_DIR}")
cannam@62:   endif()
cannam@62:   get_filename_component(CAPNPC_SRC_PREFIX "${CAPNPC_SRC_PREFIX}" ABSOLUTE)
cannam@62: 
cannam@62:   set(${SOURCES})
cannam@62:   set(${HEADERS})
cannam@62:   foreach(schema_file ${ARGN})
cannam@62:     if(NOT EXISTS "${CAPNPC_SRC_PREFIX}/${schema_file}")
cannam@62:       message(FATAL_ERROR "Cap'n Proto schema file '${CAPNPC_SRC_PREFIX}/${schema_file}' does not exist!")
cannam@62:     endif()
cannam@62:     get_filename_component(file_path "${schema_file}" ABSOLUTE)
cannam@62:     get_filename_component(file_dir "${file_path}" PATH)
cannam@62: 
cannam@62:     # Figure out where the output files will go
cannam@62:     if (NOT DEFINED CAPNPC_OUTPUT_DIR)
cannam@62:       set(CAPNPC_OUTPUT_DIR "${CMAKE_CURRENT_BINARY_DIR}/")
cannam@62:     endif()
cannam@62:     # Output files are placed in CAPNPC_OUTPUT_DIR, at a location as if they were
cannam@62:     # relative to CAPNPC_SRC_PREFIX.
cannam@62:     string(LENGTH "${CAPNPC_SRC_PREFIX}" prefix_len)
cannam@62:     string(SUBSTRING "${file_path}" 0 ${prefix_len} output_prefix)
cannam@62:     if(NOT "${CAPNPC_SRC_PREFIX}" STREQUAL "${output_prefix}")
cannam@62:       message(SEND_ERROR "Could not determine output path for '${schema_file}' ('${file_path}') with source prefix '${CAPNPC_SRC_PREFIX}' into '${CAPNPC_OUTPUT_DIR}'.")
cannam@62:     endif()
cannam@62: 
cannam@62:     string(SUBSTRING "${file_path}" ${prefix_len} -1 output_path)
cannam@62:     set(output_base "${CAPNPC_OUTPUT_DIR}${output_path}")
cannam@62: 
cannam@62:     add_custom_command(
cannam@62:       OUTPUT "${output_base}.c++" "${output_base}.h"
cannam@62:       COMMAND "${CAPNP_EXECUTABLE}"
cannam@62:       ARGS compile
cannam@62:           -o ${CAPNPC_CXX_EXECUTABLE}${output_dir}
cannam@62:           --src-prefix ${CAPNPC_SRC_PREFIX}
cannam@62:           ${include_path}
cannam@62:           ${CAPNPC_FLAGS}
cannam@62:           ${file_path}
cannam@62:       DEPENDS "${schema_file}" ${tool_depends}
cannam@62:       COMMENT "Compiling Cap'n Proto schema ${schema_file}"
cannam@62:       VERBATIM
cannam@62:     )
cannam@62: 
cannam@62:     list(APPEND ${SOURCES} "${output_base}.c++")
cannam@62:     list(APPEND ${HEADERS} "${output_base}.h")
cannam@62:   endforeach()
cannam@62: 
cannam@62:   set_source_files_properties(${${SOURCES}} ${${HEADERS}} PROPERTIES GENERATED TRUE)
cannam@62:   set(${SOURCES} ${${SOURCES}} PARENT_SCOPE)
cannam@62:   set(${HEADERS} ${${HEADERS}} PARENT_SCOPE)
cannam@62: endfunction()