Mercurial > hg > sv-dependency-builds

annotate src/fftw-3.3.5/m4/ltsugar.m4 @ 79:91c729825bca pa_catalina

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Update build for AUDIO_COMPONENT_FIX
author Chris Cannam
date Wed, 30 Oct 2019 12:40:34 +0000
parents 2cd0e3b3e1fd
children
rev   line source
Chris@42 1 # ltsugar.m4 -- libtool m4 base layer. -*-Autoconf-*-
Chris@42 2 #
Chris@42 3 # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
Chris@42 4 # Written by Gary V. Vaughan, 2004
Chris@42 5 #
Chris@42 6 # This file is free software; the Free Software Foundation gives
Chris@42 7 # unlimited permission to copy and/or distribute it, with or without
Chris@42 8 # modifications, as long as this notice is preserved.
Chris@42 9
Chris@42 10 # serial 6 ltsugar.m4
Chris@42 11
Chris@42 12 # This is to help aclocal find these macros, as it can't see m4_define.
Chris@42 13 AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
Chris@42 14
Chris@42 15
Chris@42 16 # lt_join(SEP, ARG1, [ARG2...])
Chris@42 17 # -----------------------------
Chris@42 18 # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
Chris@42 19 # associated separator.
Chris@42 20 # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
Chris@42 21 # versions in m4sugar had bugs.
Chris@42 22 m4_define([lt_join],
Chris@42 23 [m4_if([$#], [1], [],
Chris@42 24 [$#], [2], [[$2]],
Chris@42 25 [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
Chris@42 26 m4_define([_lt_join],
Chris@42 27 [m4_if([$#$2], [2], [],
Chris@42 28 [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
Chris@42 29
Chris@42 30
Chris@42 31 # lt_car(LIST)
Chris@42 32 # lt_cdr(LIST)
Chris@42 33 # ------------
Chris@42 34 # Manipulate m4 lists.
Chris@42 35 # These macros are necessary as long as will still need to support
Chris@42 36 # Autoconf-2.59 which quotes differently.
Chris@42 37 m4_define([lt_car], [[$1]])
Chris@42 38 m4_define([lt_cdr],
Chris@42 39 [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
Chris@42 40 [$#], 1, [],
Chris@42 41 [m4_dquote(m4_shift($@))])])
Chris@42 42 m4_define([lt_unquote], $1)
Chris@42 43
Chris@42 44
Chris@42 45 # lt_append(MACRO-NAME, STRING, [SEPARATOR])
Chris@42 46 # ------------------------------------------
Chris@42 47 # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
Chris@42 48 # Note that neither SEPARATOR nor STRING are expanded; they are appended
Chris@42 49 # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
Chris@42 50 # No SEPARATOR is output if MACRO-NAME was previously undefined (different
Chris@42 51 # than defined and empty).
Chris@42 52 #
Chris@42 53 # This macro is needed until we can rely on Autoconf 2.62, since earlier
Chris@42 54 # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
Chris@42 55 m4_define([lt_append],
Chris@42 56 [m4_define([$1],
Chris@42 57 m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
Chris@42 58
Chris@42 59
Chris@42 60
Chris@42 61 # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
Chris@42 62 # ----------------------------------------------------------
Chris@42 63 # Produce a SEP delimited list of all paired combinations of elements of
Chris@42 64 # PREFIX-LIST with SUFFIX1 through SUFFIXn. Each element of the list
Chris@42 65 # has the form PREFIXmINFIXSUFFIXn.
Chris@42 66 # Needed until we can rely on m4_combine added in Autoconf 2.62.
Chris@42 67 m4_define([lt_combine],
Chris@42 68 [m4_if(m4_eval([$# > 3]), [1],
Chris@42 69 [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
Chris@42 70 [[m4_foreach([_Lt_prefix], [$2],
Chris@42 71 [m4_foreach([_Lt_suffix],
Chris@42 72 ]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
Chris@42 73 [_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
Chris@42 74
Chris@42 75
Chris@42 76 # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
Chris@42 77 # -----------------------------------------------------------------------
Chris@42 78 # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
Chris@42 79 # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
Chris@42 80 m4_define([lt_if_append_uniq],
Chris@42 81 [m4_ifdef([$1],
Chris@42 82 [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
Chris@42 83 [lt_append([$1], [$2], [$3])$4],
Chris@42 84 [$5])],
Chris@42 85 [lt_append([$1], [$2], [$3])$4])])
Chris@42 86
Chris@42 87
Chris@42 88 # lt_dict_add(DICT, KEY, VALUE)
Chris@42 89 # -----------------------------
Chris@42 90 m4_define([lt_dict_add],
Chris@42 91 [m4_define([$1($2)], [$3])])
Chris@42 92
Chris@42 93
Chris@42 94 # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
Chris@42 95 # --------------------------------------------
Chris@42 96 m4_define([lt_dict_add_subkey],
Chris@42 97 [m4_define([$1($2:$3)], [$4])])
Chris@42 98
Chris@42 99
Chris@42 100 # lt_dict_fetch(DICT, KEY, [SUBKEY])
Chris@42 101 # ----------------------------------
Chris@42 102 m4_define([lt_dict_fetch],
Chris@42 103 [m4_ifval([$3],
Chris@42 104 m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
Chris@42 105 m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
Chris@42 106
Chris@42 107
Chris@42 108 # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
Chris@42 109 # -----------------------------------------------------------------
Chris@42 110 m4_define([lt_if_dict_fetch],
Chris@42 111 [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
Chris@42 112 [$5],
Chris@42 113 [$6])])
Chris@42 114
Chris@42 115
Chris@42 116 # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
Chris@42 117 # --------------------------------------------------------------
Chris@42 118 m4_define([lt_dict_filter],
Chris@42 119 [m4_if([$5], [], [],
Chris@42 120 [lt_join(m4_quote(m4_default([$4], [[, ]])),
Chris@42 121 lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
Chris@42 122 [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
Chris@42 123 ])