Mercurial > hg > sonic-visualiser

view sonic-visualiser.pro @ 375:62e9f62752e1 macness_autotpl

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
only do genre stuff etc if itunes returns a file
author Dan Stowell <dan.stowell@eecs.qmul.ac.uk>
date Fri, 15 Oct 2010 15:12:24 +0100
parents 726e1c1382f3
children fad5611ef9db
line wrap: on
line source

TEMPLATE = app

include(config.pri)

CONFIG += qt thread warn_on stl rtti exceptions
QT += network xml gui

TARGET = "Sonic Visualiser"
linux*:TARGET = sonic-visualiser
solaris*:TARGET = sonic-visualiser

DEPENDPATH += . ../svcore ../svgui ../svapp
INCLUDEPATH += . ../svcore ../svgui ../svapp

LIBPATH = ../svapp ../svgui ../svcore $$LIBPATH

OBJECTS_DIR = o
MOC_DIR = o

ICON = icons/sv-macicon.icns
RC_FILE = icons/sv.rc

contains(DEFINES, BUILD_STATIC):LIBS -= -ljack

LIBS = -lsvapp -lsvgui -lsvcore $$LIBS

PRE_TARGETDEPS += ../svapp/libsvapp.a \
                  ../svgui/libsvgui.a \
                  ../svcore/libsvcore.a

RESOURCES += sonic-visualiser.qrc

HEADERS += main/MainWindow.h \
           main/PreferencesDialog.h \
           main/Surveyer.h
SOURCES += main/main.cpp \
           main/OSCHandler.cpp \
           main/MainWindow.cpp \
           main/PreferencesDialog.cpp \
           main/Surveyer.cpp

mac {
    QMAKE_INFO_PLIST = osx/Info.plist
    
    OBJECTIVE_SOURCES += osx/svitunes.mm

    LIBS += -framework Foundation
}