Mercurial > hg > sonic-visualiser

view sonic-visualiser.pro @ 503:5762b0aab869

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Oops, that last one was intended for Win only
author Chris Cannam
date Mon, 30 Jan 2012 16:58:54 +0000
parents 173325440b8e
children a830a57084c2
line wrap: on
line source

TEMPLATE = app

include(config.pri)

CONFIG += qt thread warn_on stl rtti exceptions
QT += network xml gui

TARGET = "Sonic Visualiser"
linux*:TARGET = sonic-visualiser
solaris*:TARGET = sonic-visualiser

DEPENDPATH += . ../svcore ../svgui ../svapp
INCLUDEPATH += . ../svcore ../svgui ../svapp

TRANSLATIONS += i18n/sonic-visualiser_ru.ts i18n/sonic-visualiser_en_GB.ts i18n/sonic-visualiser_en_US.ts i18n/sonic-visualiser_cs_CZ.ts

OBJECTS_DIR = o
MOC_DIR = o

ICON = icons/sv-macicon.icns
RC_FILE = icons/sv.rc

contains(DEFINES, BUILD_STATIC):LIBS -= -ljack

LIBS = -L../svapp -L../svgui -L../svcore -lsvapp -lsvgui -lsvcore $$LIBS

win* {
PRE_TARGETDEPS += ../svapp/svapp.lib \
                  ../svgui/svgui.lib \
                  ../svcore/svcore.lib
}
!win* {
PRE_TARGETDEPS += ../svapp/libsvapp.a \
                  ../svgui/libsvgui.a \
                  ../svcore/libsvcore.a
}

RESOURCES += sonic-visualiser.qrc

HEADERS += main/MainWindow.h \
           main/PreferencesDialog.h \
           main/Surveyer.h
SOURCES += main/main.cpp \
           main/OSCHandler.cpp \
           main/MainWindow.cpp \
           main/PreferencesDialog.cpp \
           main/Surveyer.cpp

# for mac integration
QMAKE_INFO_PLIST = deploy/osx/Info.plist