view sonic-visualiser.pro @ 439:6d5ee6860682 toggle

Add a new feature to allow users to toggle between minimal and full modes. This is done by hiding/showing the pane stack, menu actions, and toolbars. The main part of the process is handled in MainWindow::toggleViewMode(). The toggle view mode option appears in the View Menu and is associated with a new toolbar button. Two icons have been added in the resources. They come from: http://www.iconfinder.com/icondetails/42115/32/

In a working state, but the resizing of the main window and the audio file overview can be improved. Some menus or menu actions can be deleted/disabled in the minimal mode (although the changes are active in the hidden pane(s) and do not cause the application to crash). See TO-DO list in MainWindow::toggleViewMode().

In sonic-visualiser.pro: -lvamp-hostsdk has been added to the LIBS (the sonic-visualiser.pro file may be to be removed from the tracked files since the modification seems to depend on the system).

TEMPLATE = app

include(config.pri)

CONFIG += qt thread warn_on stl rtti exceptions
QT += network xml gui

TARGET = "Sonic Visualiser"
linux*:TARGET = sonic-visualiser
solaris*:TARGET = sonic-visualiser

DEPENDPATH += . ../svcore ../svgui ../svapp
INCLUDEPATH += . ../svcore ../svgui ../svapp

TRANSLATIONS += i18n/sonic-visualiser_ru.ts i18n/sonic-visualiser_en_GB.ts i18n/sonic-visualiser_en_US.ts i18n/sonic-visualiser_cs_CZ.ts

OBJECTS_DIR = o
MOC_DIR = o

ICON = icons/sv-macicon.icns
RC_FILE = icons/sv.rc

contains(DEFINES, BUILD_STATIC):LIBS -= -ljack

LIBS = -L../svapp -L../svgui -L../svcore -lsvapp -lsvgui -lsvcore -lvamp-hostsdk $$LIBS

PRE_TARGETDEPS += ../svapp/libsvapp.a \
                  ../svgui/libsvgui.a \
                  ../svcore/libsvcore.a

RESOURCES += sonic-visualiser.qrc

HEADERS += main/MainWindow.h \
           main/PreferencesDialog.h \
           main/Surveyer.h
SOURCES += main/main.cpp \
           main/OSCHandler.cpp \
           main/MainWindow.cpp \
           main/PreferencesDialog.cpp \
           main/Surveyer.cpp

# for mac integration
QMAKE_INFO_PLIST = deploy/osx/Info.plist