Mercurial > hg > sonic-visualiser

view test-svcore-data-model.pro @ 1664:62bc7d54def4

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Make some corrections to crosshair (measure cursor) positioning and feature descriptions. Needs review.
author Chris Cannam
date Tue, 07 Mar 2017 18:54:15 +0000
parents e4bd2a532ced
children a86168d1ba68
line wrap: on
line source

TEMPLATE = app

exists(config.pri) {
    include(config.pri)
}

!exists(config.pri) {
    include(noconfig.pri)
}

include(base.pri)

CONFIG += console
QT += network xml testlib
QT -= gui

win32-x-g++:QMAKE_LFLAGS += -Wl,-subsystem,console
macx*: CONFIG -= app_bundle

TARGET = test-svcore-data-model

OBJECTS_DIR = o
MOC_DIR = o

include(svcore/data/model/test/files.pri)

for (file, TEST_SOURCES) { SOURCES += $$sprintf("svcore/data/model/test/%1", $$file) }
for (file, TEST_HEADERS) { HEADERS += $$sprintf("svcore/data/model/test/%1", $$file) }

!win32* {
    QMAKE_POST_LINK = ./$${TARGET}
}