Mercurial > hg > sonic-visualiser

view sonic-visualiser.pro @ 351:41f3e8d56bac

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
* Update build system
author Chris Cannam
date Wed, 22 Sep 2010 11:39:37 +0100
parents sv.pro@8fdfdd85881a
children 4e16d48c693d b19bef1bc3f1
line wrap: on
line source

TEMPLATE = app

include(config.pri)

CONFIG += qt thread warn_on stl rtti exceptions
QT += network xml gui

TARGET = "Sonic Visualiser"
linux*:TARGET = sonic-visualiser
solaris*:TARGET = sonic-visualiser

DEPENDPATH += . ../svcore ../svgui ../svapp
INCLUDEPATH += . ../svcore ../svgui ../svapp

LIBPATH = ../svapp ../svgui ../svcore $$LIBPATH

OBJECTS_DIR = o
MOC_DIR = o

ICON = icons/sv-macicon.icns
RC_FILE = icons/sv.rc

contains(DEFINES, BUILD_STATIC):LIBS -= -ljack

LIBS = -lsvapp -lsvgui -lsvcore $$LIBS

PRE_TARGETDEPS += ../svapp/libsvapp.a \
                  ../svgui/libsvgui.a \
                  ../svcore/libsvcore.a

RESOURCES += sonic-visualiser.qrc

HEADERS += main/MainWindow.h \
           main/PreferencesDialog.h \
           main/Surveyer.h
SOURCES += main/main.cpp \
           main/OSCHandler.cpp \
           main/MainWindow.cpp \
           main/PreferencesDialog.cpp \
           main/Surveyer.cpp