Mercurial > hg > sonic-visualiser

view sonic-visualiser.pro @ 386:268478a184a3 macness

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
compile the NSAppleScript objs once only, rather than on every invocation
author Dan Stowell <dan.stowell@eecs.qmul.ac.uk>
date Mon, 18 Oct 2010 15:47:46 +0100
parents fad5611ef9db
children
line wrap: on
line source

TEMPLATE = app

include(config.pri)

CONFIG += qt thread warn_on stl rtti exceptions
QT += network xml gui

TARGET = "Sonic Visualiser"
linux*:TARGET = sonic-visualiser
solaris*:TARGET = sonic-visualiser

DEPENDPATH += . ../svcore ../svgui ../svapp
INCLUDEPATH += . ../svcore ../svgui ../svapp

LIBPATH = ../svapp ../svgui ../svcore $$LIBPATH

OBJECTS_DIR = o
MOC_DIR = o

ICON = icons/sv-macicon.icns
RC_FILE = icons/sv.rc

contains(DEFINES, BUILD_STATIC):LIBS -= -ljack

LIBS = -lsvapp -lsvgui -lsvcore $$LIBS

PRE_TARGETDEPS += ../svapp/libsvapp.a \
                  ../svgui/libsvgui.a \
                  ../svcore/libsvcore.a

RESOURCES += sonic-visualiser.qrc

HEADERS += main/MainWindow.h \
           main/PreferencesDialog.h \
           main/Surveyer.h
SOURCES += main/main.cpp \
           main/OSCHandler.cpp \
           main/MainWindow.cpp \
           main/PreferencesDialog.cpp \
           main/Surveyer.cpp

mac {
    QMAKE_INFO_PLIST = osx/Info.plist
    
    HEADERS += osx/svitunes.h
    OBJECTIVE_SOURCES += osx/svitunes.mm

    LIBS += -framework Foundation
}