diff sv.pro @ 517:a830a57084c2

Rework to use hg subrepos

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/sv.pro	Tue Aug 21 13:36:28 2012 +0100
@@ -0,0 +1,52 @@
+
+TEMPLATE = app
+
+include(config.pri)
+
+CONFIG += qt thread warn_on stl rtti exceptions
+QT += network xml gui
+
+TARGET = "Sonic Visualiser"
+linux*:TARGET = sonic-visualiser
+solaris*:TARGET = sonic-visualiser
+
+DEPENDPATH += . svcore svgui svapp
+INCLUDEPATH += . svcore svgui svapp
+
+TRANSLATIONS += i18n/sonic-visualiser_ru.ts i18n/sonic-visualiser_en_GB.ts i18n/sonic-visualiser_en_US.ts i18n/sonic-visualiser_cs_CZ.ts
+
+OBJECTS_DIR = o
+MOC_DIR = o
+
+ICON = icons/sv-macicon.icns
+RC_FILE = icons/sv.rc
+
+contains(DEFINES, BUILD_STATIC):LIBS -= -ljack
+
+LIBS = -Lsvapp -Lsvgui -Lsvcore -lsvapp -lsvgui -lsvcore $$LIBS
+
+win* {
+PRE_TARGETDEPS += svapp/svapp.lib \
+                  svgui/svgui.lib \
+                  svcore/svcore.lib
+}
+!win* {
+PRE_TARGETDEPS += svapp/libsvapp.a \
+                  svgui/libsvgui.a \
+                  svcore/libsvcore.a
+}
+
+RESOURCES += sonic-visualiser.qrc
+
+HEADERS += main/MainWindow.h \
+           main/PreferencesDialog.h \
+           main/Surveyer.h
+SOURCES += main/main.cpp \
+           main/OSCHandler.cpp \
+           main/MainWindow.cpp \
+           main/PreferencesDialog.cpp \
+           main/Surveyer.cpp
+
+# for mac integration
+QMAKE_INFO_PLIST = deploy/osx/Info.plist
+