diff server.pro @ 1398:6f5a40419b00 bqaudioio

Merge from branch bqresample

--- /dev/null	Thu Jan 01 00:00:00 1970 +0000
+++ b/server.pro	Wed Dec 07 11:53:44 2016 +0000
@@ -0,0 +1,48 @@
+
+TEMPLATE = app
+
+CONFIG += stl c++11 exceptions console warn_on
+
+CONFIG -= qt
+
+exists(config.pri) {
+    include(config.pri)
+}
+
+!exists(config.pri) {
+    include(noconfig.pri)
+
+    macx*: LIBS -= -framework CoreAudio -framework CoreMidi -framework AudioUnit -framework AudioToolbox -framework CoreFoundation -framework CoreServices -framework Accelerate -lbz2 -lz
+}
+
+# Can't support this flag with the JSON11 and basen modules as they stand
+QMAKE_CXXFLAGS -= -Werror
+
+# Using the "console" CONFIG flag above should ensure this happens for
+# normal Windows builds, but this may be necessary when cross-compiling
+win32-x-g++: QMAKE_LFLAGS += -Wl,-subsystem,console
+
+macx*: CONFIG -= app_bundle
+
+linux*: LIBS += -ldl
+
+TARGET = piper-vamp-simple-server
+
+OBJECTS_DIR = o
+MOC_DIR = o
+
+INCLUDEPATH += piper-cpp vamp-plugin-sdk
+
+include(vamp-plugin-sdk-files.pri)
+
+for (file, VAMP_SOURCES) { SOURCES += $$file }
+for (file, VAMP_HEADERS) { HEADERS += $$file }
+
+HEADERS += \
+        piper-cpp/vamp-capnp/piper.capnp.h \
+        piper-cpp/vamp-capnp/VampnProto.h
+
+SOURCES += \
+        piper-cpp/vamp-capnp/piper-capnp.cpp \
+        piper-cpp/json11/json11.cpp \
+        piper-cpp/vamp-server/simple-server.cpp