Mercurial > hg > qm-vamp-plugins

view qm-vamp-plugins.pro @ 124:7e5fc22c9ab1

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
* Fix beat counts prior to first bar
author Chris Cannam <c.cannam@qmul.ac.uk>
date Thu, 25 Jun 2009 13:28:19 +0000
parents 25ef867820ba
children dd01b0a81f1b
line wrap: on
line source

TEMPLATE = lib
CONFIG += plugin warn_on release
CONFIG -= qt

linux-g++* {
    QMAKE_CXXFLAGS_RELEASE += -DNDEBUG -O3 -fno-exceptions -fPIC -ffast-math -msse -ftree-vectorize -fomit-frame-pointer
    DEFINES += USE_PTHREADS
    INCLUDEPATH += ../vamp-plugin-sdk ../qm-dsp
    LIBPATH += ../vamp-plugin-sdk/vamp-sdk ../qm-dsp
}

linux-g++ {
    LIBS += -static-libgcc -Wl,-Bstatic -lqm-dsp -lvamp-sdk -L/usr/lib/sse2/atlas -L/usr/lib/atlas/sse -llapack -lblas $$system(g++ -print-file-name=libstdc++.a) -lc -Wl,-Bdynamic -lpthread -Wl,--version-script=vamp-plugin.map
}

linux-g++-64 {
    QMAKE_CXXFLAGS_RELEASE += -msse2
    LIBS += -Lbuild/linux/amd64  -Wl,-Bstatic -lqm-dsp -lvamp-sdk -llapack -lcblas -latlas -lc -Wl,-Bdynamic -lpthread -Wl,--version-script=vamp-plugin.map
}

macx-g++* {
    QMAKE_MAC_SDK=/Developer/SDKs/MacOSX10.4u.sdk
    QMAKE_CXXFLAGS_RELEASE += -O2 -g0
    CONFIG += x86 ppc
    DEFINES += USE_PTHREADS
    LIBS += -lqm-dsp -lvamp-sdk -framework Accelerate -lpthread -exported_symbols_list=vamp-plugin.list
    INCLUDEPATH += ../vamp-plugin-sdk ../qm-dsp
    LIBPATH += ../include ../lib ../qm-dsp
}

win32-x-g++ {
    QMAKE_CXXFLAGS_RELEASE += -DNDEBUG -O2 -march=pentium3 -msse
    INCLUDEPATH += ../include ../qm-dsp
    LIBPATH += ./build/mingw32 ../lib ../qm-dsp ../qm-dsp/release 
    LIBS += -shared -Wl,-Bstatic -lqm-dsp -lvamp-sdk -llapack -lcblas -latlas -lf77blas -lg2cstubs -Wl,-Bdynamic -Wl,--version-script=vamp-plugin.map
}

OBJECTS_DIR = tmp_obj
MOC_DIR = tmp_moc

DEPENDPATH += plugins
INCLUDEPATH += . plugins

# Input
HEADERS += plugins/AdaptiveSpectrogram.h \
           plugins/BarBeatTrack.h \
           plugins/BeatTrack.h \
           plugins/DWT.h \
           plugins/OnsetDetect.h \
           plugins/ChromagramPlugin.h \
           plugins/ConstantQSpectrogram.h \
           plugins/KeyDetect.h \
           plugins/MFCCPlugin.h \
           plugins/SegmenterPlugin.h \
           plugins/SimilarityPlugin.h \
           plugins/TonalChangeDetect.h \
           plugins/Transcription.h
SOURCES += g2cstubs.c \
           plugins/AdaptiveSpectrogram.cpp \
           plugins/BarBeatTrack.cpp \
           plugins/BeatTrack.cpp \
           plugins/DWT.cpp \
           plugins/OnsetDetect.cpp \
           plugins/ChromagramPlugin.cpp \
           plugins/ConstantQSpectrogram.cpp \
           plugins/KeyDetect.cpp \
           plugins/MFCCPlugin.cpp \
           plugins/SegmenterPlugin.cpp \
           plugins/SimilarityPlugin.cpp \
           plugins/TonalChangeDetect.cpp \
           plugins/Transcription.cpp \
           ./libmain.cpp