yading@10: /*
yading@10:  * Copyright (c) 2008 Mans Rullgard <mans@mansr.com>
yading@10:  *
yading@10:  * This file is part of FFmpeg.
yading@10:  *
yading@10:  * FFmpeg is free software; you can redistribute it and/or
yading@10:  * modify it under the terms of the GNU Lesser General Public
yading@10:  * License as published by the Free Software Foundation; either
yading@10:  * version 2.1 of the License, or (at your option) any later version.
yading@10:  *
yading@10:  * FFmpeg is distributed in the hope that it will be useful,
yading@10:  * but WITHOUT ANY WARRANTY; without even the implied warranty of
yading@10:  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
yading@10:  * Lesser General Public License for more details.
yading@10:  *
yading@10:  * You should have received a copy of the GNU Lesser General Public
yading@10:  * License along with FFmpeg; if not, write to the Free Software
yading@10:  * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
yading@10:  */
yading@10: 
yading@10: #include "libavutil/arm/asm.S"
yading@10: #include "neon.S"
yading@10: 
yading@10:         /* H.264 qpel MC */
yading@10: 
yading@10: .macro  lowpass_const   r
yading@10:         movw            \r,  #5
yading@10:         movt            \r,  #20
yading@10:         vmov.32         d6[0], \r
yading@10: .endm
yading@10: 
yading@10: .macro  lowpass_8       r0,  r1,  r2,  r3,  d0,  d1,  narrow=1
yading@10:   .if \narrow
yading@10:         t0 .req q0
yading@10:         t1 .req q8
yading@10:   .else
yading@10:         t0 .req \d0
yading@10:         t1 .req \d1
yading@10:   .endif
yading@10:         vext.8          d2,  \r0, \r1, #2
yading@10:         vext.8          d3,  \r0, \r1, #3
yading@10:         vaddl.u8        q1,  d2,  d3
yading@10:         vext.8          d4,  \r0, \r1, #1
yading@10:         vext.8          d5,  \r0, \r1, #4
yading@10:         vaddl.u8        q2,  d4,  d5
yading@10:         vext.8          d30, \r0, \r1, #5
yading@10:         vaddl.u8        t0,  \r0, d30
yading@10:         vext.8          d18, \r2, \r3, #2
yading@10:         vmla.i16        t0,  q1,  d6[1]
yading@10:         vext.8          d19, \r2, \r3, #3
yading@10:         vaddl.u8        q9,  d18, d19
yading@10:         vext.8          d20, \r2, \r3, #1
yading@10:         vmls.i16        t0,  q2,  d6[0]
yading@10:         vext.8          d21, \r2, \r3, #4
yading@10:         vaddl.u8        q10, d20, d21
yading@10:         vext.8          d31, \r2, \r3, #5
yading@10:         vaddl.u8        t1,  \r2, d31
yading@10:         vmla.i16        t1,  q9,  d6[1]
yading@10:         vmls.i16        t1,  q10, d6[0]
yading@10:   .if \narrow
yading@10:         vqrshrun.s16    \d0, t0,  #5
yading@10:         vqrshrun.s16    \d1, t1,  #5
yading@10:   .endif
yading@10:         .unreq  t0
yading@10:         .unreq  t1
yading@10: .endm
yading@10: 
yading@10: .macro  lowpass_8_1     r0,  r1,  d0,  narrow=1
yading@10:   .if \narrow
yading@10:         t0 .req q0
yading@10:   .else
yading@10:         t0 .req \d0
yading@10:   .endif
yading@10:         vext.8          d2,  \r0, \r1, #2
yading@10:         vext.8          d3,  \r0, \r1, #3
yading@10:         vaddl.u8        q1,  d2,  d3
yading@10:         vext.8          d4,  \r0, \r1, #1
yading@10:         vext.8          d5,  \r0, \r1, #4
yading@10:         vaddl.u8        q2,  d4,  d5
yading@10:         vext.8          d30, \r0, \r1, #5
yading@10:         vaddl.u8        t0,  \r0, d30
yading@10:         vmla.i16        t0,  q1,  d6[1]
yading@10:         vmls.i16        t0,  q2,  d6[0]
yading@10:   .if \narrow
yading@10:         vqrshrun.s16    \d0, t0,  #5
yading@10:   .endif
yading@10:         .unreq  t0
yading@10: .endm
yading@10: 
yading@10: .macro  lowpass_8.16    r0,  r1,  l0,  h0,  l1,  h1,  d
yading@10:         vext.16         q1,  \r0, \r1, #2
yading@10:         vext.16         q0,  \r0, \r1, #3
yading@10:         vaddl.s16       q9,  d2,  d0
yading@10:         vext.16         q2,  \r0, \r1, #1
yading@10:         vaddl.s16       q1,  d3,  d1
yading@10:         vext.16         q3,  \r0, \r1, #4
yading@10:         vaddl.s16       q10, d4,  d6
yading@10:         vext.16         \r1, \r0, \r1, #5
yading@10:         vaddl.s16       q2,  d5,  d7
yading@10:         vaddl.s16       q0,  \h0, \h1
yading@10:         vaddl.s16       q8,  \l0, \l1
yading@10: 
yading@10:         vshl.i32        q3,  q9,  #4
yading@10:         vshl.i32        q9,  q9,  #2
yading@10:         vshl.i32        q15, q10, #2
yading@10:         vadd.i32        q9,  q9,  q3
yading@10:         vadd.i32        q10, q10, q15
yading@10: 
yading@10:         vshl.i32        q3,  q1,  #4
yading@10:         vshl.i32        q1,  q1,  #2
yading@10:         vshl.i32        q15, q2,  #2
yading@10:         vadd.i32        q1,  q1,  q3
yading@10:         vadd.i32        q2,  q2,  q15
yading@10: 
yading@10:         vadd.i32        q9,  q9,  q8
yading@10:         vsub.i32        q9,  q9,  q10
yading@10: 
yading@10:         vadd.i32        q1,  q1,  q0
yading@10:         vsub.i32        q1,  q1,  q2
yading@10: 
yading@10:         vrshrn.s32      d18, q9,  #10
yading@10:         vrshrn.s32      d19, q1,  #10
yading@10: 
yading@10:         vqmovun.s16     \d,  q9
yading@10: .endm
yading@10: 
yading@10: function put_h264_qpel16_h_lowpass_neon_packed
yading@10:         mov             r4,  lr
yading@10:         mov             r12, #16
yading@10:         mov             r3,  #8
yading@10:         bl              put_h264_qpel8_h_lowpass_neon
yading@10:         sub             r1,  r1,  r2, lsl #4
yading@10:         add             r1,  r1,  #8
yading@10:         mov             r12, #16
yading@10:         mov             lr,  r4
yading@10:         b               put_h264_qpel8_h_lowpass_neon
yading@10: endfunc
yading@10: 
yading@10: .macro  h264_qpel_h_lowpass type
yading@10: function \type\()_h264_qpel16_h_lowpass_neon
yading@10:         push            {lr}
yading@10:         mov             r12, #16
yading@10:         bl              \type\()_h264_qpel8_h_lowpass_neon
yading@10:         sub             r0,  r0,  r3, lsl #4
yading@10:         sub             r1,  r1,  r2, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         add             r1,  r1,  #8
yading@10:         mov             r12, #16
yading@10:         pop             {lr}
yading@10: endfunc
yading@10: 
yading@10: function \type\()_h264_qpel8_h_lowpass_neon
yading@10: 1:      vld1.8          {d0, d1},  [r1], r2
yading@10:         vld1.8          {d16,d17}, [r1], r2
yading@10:         subs            r12, r12, #2
yading@10:         lowpass_8       d0,  d1,  d16, d17, d0,  d16
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d2},     [r0,:64], r3
yading@10:         vrhadd.u8       d0,  d0,  d2
yading@10:         vld1.8          {d3},     [r0,:64]
yading@10:         vrhadd.u8       d16, d16, d3
yading@10:         sub             r0,  r0,  r3
yading@10:   .endif
yading@10:         vst1.8          {d0},     [r0,:64], r3
yading@10:         vst1.8          {d16},    [r0,:64], r3
yading@10:         bne             1b
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel_h_lowpass put
yading@10:         h264_qpel_h_lowpass avg
yading@10: 
yading@10: .macro  h264_qpel_h_lowpass_l2 type
yading@10: function \type\()_h264_qpel16_h_lowpass_l2_neon
yading@10:         push            {lr}
yading@10:         mov             r12, #16
yading@10:         bl              \type\()_h264_qpel8_h_lowpass_l2_neon
yading@10:         sub             r0,  r0,  r2, lsl #4
yading@10:         sub             r1,  r1,  r2, lsl #4
yading@10:         sub             r3,  r3,  r2, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         add             r1,  r1,  #8
yading@10:         add             r3,  r3,  #8
yading@10:         mov             r12, #16
yading@10:         pop             {lr}
yading@10: endfunc
yading@10: 
yading@10: function \type\()_h264_qpel8_h_lowpass_l2_neon
yading@10: 1:      vld1.8          {d0, d1},  [r1], r2
yading@10:         vld1.8          {d16,d17}, [r1], r2
yading@10:         vld1.8          {d28},     [r3], r2
yading@10:         vld1.8          {d29},     [r3], r2
yading@10:         subs            r12, r12, #2
yading@10:         lowpass_8       d0,  d1,  d16, d17, d0,  d1
yading@10:         vrhadd.u8       q0,  q0,  q14
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d2},      [r0,:64], r2
yading@10:         vrhadd.u8       d0,  d0,  d2
yading@10:         vld1.8          {d3},      [r0,:64]
yading@10:         vrhadd.u8       d1,  d1,  d3
yading@10:         sub             r0,  r0,  r2
yading@10:   .endif
yading@10:         vst1.8          {d0},      [r0,:64], r2
yading@10:         vst1.8          {d1},      [r0,:64], r2
yading@10:         bne             1b
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel_h_lowpass_l2 put
yading@10:         h264_qpel_h_lowpass_l2 avg
yading@10: 
yading@10: function put_h264_qpel16_v_lowpass_neon_packed
yading@10:         mov             r4,  lr
yading@10:         mov             r2,  #8
yading@10:         bl              put_h264_qpel8_v_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         bl              put_h264_qpel8_v_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #4
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         add             r1,  r1,  #8
yading@10:         bl              put_h264_qpel8_v_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         mov             lr,  r4
yading@10:         b               put_h264_qpel8_v_lowpass_neon
yading@10: endfunc
yading@10: 
yading@10: .macro  h264_qpel_v_lowpass type
yading@10: function \type\()_h264_qpel16_v_lowpass_neon
yading@10:         mov             r4,  lr
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_neon
yading@10:         sub             r0,  r0,  r2, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         sub             r1,  r1,  r3, lsl #4
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         add             r1,  r1,  #8
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         mov             lr,  r4
yading@10: endfunc
yading@10: 
yading@10: function \type\()_h264_qpel8_v_lowpass_neon
yading@10:         vld1.8          {d8},  [r1], r3
yading@10:         vld1.8          {d10}, [r1], r3
yading@10:         vld1.8          {d12}, [r1], r3
yading@10:         vld1.8          {d14}, [r1], r3
yading@10:         vld1.8          {d22}, [r1], r3
yading@10:         vld1.8          {d24}, [r1], r3
yading@10:         vld1.8          {d26}, [r1], r3
yading@10:         vld1.8          {d28}, [r1], r3
yading@10:         vld1.8          {d9},  [r1], r3
yading@10:         vld1.8          {d11}, [r1], r3
yading@10:         vld1.8          {d13}, [r1], r3
yading@10:         vld1.8          {d15}, [r1], r3
yading@10:         vld1.8          {d23}, [r1]
yading@10: 
yading@10:         transpose_8x8   q4,  q5,  q6,  q7,  q11, q12, q13, q14
yading@10:         lowpass_8       d8,  d9,  d10, d11, d8,  d10
yading@10:         lowpass_8       d12, d13, d14, d15, d12, d14
yading@10:         lowpass_8       d22, d23, d24, d25, d22, d24
yading@10:         lowpass_8       d26, d27, d28, d29, d26, d28
yading@10:         transpose_8x8   d8,  d10, d12, d14, d22, d24, d26, d28
yading@10: 
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d9},  [r0,:64], r2
yading@10:         vrhadd.u8       d8,  d8,  d9
yading@10:         vld1.8          {d11}, [r0,:64], r2
yading@10:         vrhadd.u8       d10, d10, d11
yading@10:         vld1.8          {d13}, [r0,:64], r2
yading@10:         vrhadd.u8       d12, d12, d13
yading@10:         vld1.8          {d15}, [r0,:64], r2
yading@10:         vrhadd.u8       d14, d14, d15
yading@10:         vld1.8          {d23}, [r0,:64], r2
yading@10:         vrhadd.u8       d22, d22, d23
yading@10:         vld1.8          {d25}, [r0,:64], r2
yading@10:         vrhadd.u8       d24, d24, d25
yading@10:         vld1.8          {d27}, [r0,:64], r2
yading@10:         vrhadd.u8       d26, d26, d27
yading@10:         vld1.8          {d29}, [r0,:64], r2
yading@10:         vrhadd.u8       d28, d28, d29
yading@10:         sub             r0,  r0,  r2,  lsl #3
yading@10:   .endif
yading@10: 
yading@10:         vst1.8          {d8},  [r0,:64], r2
yading@10:         vst1.8          {d10}, [r0,:64], r2
yading@10:         vst1.8          {d12}, [r0,:64], r2
yading@10:         vst1.8          {d14}, [r0,:64], r2
yading@10:         vst1.8          {d22}, [r0,:64], r2
yading@10:         vst1.8          {d24}, [r0,:64], r2
yading@10:         vst1.8          {d26}, [r0,:64], r2
yading@10:         vst1.8          {d28}, [r0,:64], r2
yading@10: 
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel_v_lowpass put
yading@10:         h264_qpel_v_lowpass avg
yading@10: 
yading@10: .macro  h264_qpel_v_lowpass_l2 type
yading@10: function \type\()_h264_qpel16_v_lowpass_l2_neon
yading@10:         mov             r4,  lr
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         sub             r0,  r0,  r3, lsl #4
yading@10:         sub             r12, r12, r2, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         add             r12, r12, #8
yading@10:         sub             r1,  r1,  r3, lsl #4
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         add             r1,  r1,  #8
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         mov             lr,  r4
yading@10: endfunc
yading@10: 
yading@10: function \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         vld1.8          {d8},  [r1], r3
yading@10:         vld1.8          {d10}, [r1], r3
yading@10:         vld1.8          {d12}, [r1], r3
yading@10:         vld1.8          {d14}, [r1], r3
yading@10:         vld1.8          {d22}, [r1], r3
yading@10:         vld1.8          {d24}, [r1], r3
yading@10:         vld1.8          {d26}, [r1], r3
yading@10:         vld1.8          {d28}, [r1], r3
yading@10:         vld1.8          {d9},  [r1], r3
yading@10:         vld1.8          {d11}, [r1], r3
yading@10:         vld1.8          {d13}, [r1], r3
yading@10:         vld1.8          {d15}, [r1], r3
yading@10:         vld1.8          {d23}, [r1]
yading@10: 
yading@10:         transpose_8x8   q4,  q5,  q6,  q7,  q11, q12, q13, q14
yading@10:         lowpass_8       d8,  d9,  d10, d11, d8,  d9
yading@10:         lowpass_8       d12, d13, d14, d15, d12, d13
yading@10:         lowpass_8       d22, d23, d24, d25, d22, d23
yading@10:         lowpass_8       d26, d27, d28, d29, d26, d27
yading@10:         transpose_8x8   d8,  d9,  d12, d13, d22, d23, d26, d27
yading@10: 
yading@10:         vld1.8          {d0},  [r12], r2
yading@10:         vld1.8          {d1},  [r12], r2
yading@10:         vld1.8          {d2},  [r12], r2
yading@10:         vld1.8          {d3},  [r12], r2
yading@10:         vld1.8          {d4},  [r12], r2
yading@10:         vrhadd.u8       q0,  q0,  q4
yading@10:         vld1.8          {d5},  [r12], r2
yading@10:         vrhadd.u8       q1,  q1,  q6
yading@10:         vld1.8          {d10}, [r12], r2
yading@10:         vrhadd.u8       q2,  q2,  q11
yading@10:         vld1.8          {d11}, [r12], r2
yading@10:         vrhadd.u8       q5,  q5,  q13
yading@10: 
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d16}, [r0,:64], r3
yading@10:         vrhadd.u8       d0,  d0,  d16
yading@10:         vld1.8          {d17}, [r0,:64], r3
yading@10:         vrhadd.u8       d1,  d1,  d17
yading@10:         vld1.8          {d16}, [r0,:64], r3
yading@10:         vrhadd.u8       d2,  d2,  d16
yading@10:         vld1.8          {d17}, [r0,:64], r3
yading@10:         vrhadd.u8       d3,  d3,  d17
yading@10:         vld1.8          {d16}, [r0,:64], r3
yading@10:         vrhadd.u8       d4,  d4,  d16
yading@10:         vld1.8          {d17}, [r0,:64], r3
yading@10:         vrhadd.u8       d5,  d5,  d17
yading@10:         vld1.8          {d16}, [r0,:64], r3
yading@10:         vrhadd.u8       d10, d10, d16
yading@10:         vld1.8          {d17}, [r0,:64], r3
yading@10:         vrhadd.u8       d11, d11, d17
yading@10:         sub             r0,  r0,  r3,  lsl #3
yading@10:   .endif
yading@10: 
yading@10:         vst1.8          {d0},  [r0,:64], r3
yading@10:         vst1.8          {d1},  [r0,:64], r3
yading@10:         vst1.8          {d2},  [r0,:64], r3
yading@10:         vst1.8          {d3},  [r0,:64], r3
yading@10:         vst1.8          {d4},  [r0,:64], r3
yading@10:         vst1.8          {d5},  [r0,:64], r3
yading@10:         vst1.8          {d10}, [r0,:64], r3
yading@10:         vst1.8          {d11}, [r0,:64], r3
yading@10: 
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel_v_lowpass_l2 put
yading@10:         h264_qpel_v_lowpass_l2 avg
yading@10: 
yading@10: function put_h264_qpel8_hv_lowpass_neon_top
yading@10:         lowpass_const   r12
yading@10:         mov             r12, #12
yading@10: 1:      vld1.8          {d0, d1},  [r1], r3
yading@10:         vld1.8          {d16,d17}, [r1], r3
yading@10:         subs            r12, r12, #2
yading@10:         lowpass_8       d0,  d1,  d16, d17, q11, q12, narrow=0
yading@10:         vst1.8          {d22-d25}, [r4,:128]!
yading@10:         bne             1b
yading@10: 
yading@10:         vld1.8          {d0, d1},  [r1]
yading@10:         lowpass_8_1     d0,  d1,  q12, narrow=0
yading@10: 
yading@10:         mov             r12, #-16
yading@10:         add             r4,  r4,  r12
yading@10:         vld1.8          {d30,d31}, [r4,:128], r12
yading@10:         vld1.8          {d20,d21}, [r4,:128], r12
yading@10:         vld1.8          {d18,d19}, [r4,:128], r12
yading@10:         vld1.8          {d16,d17}, [r4,:128], r12
yading@10:         vld1.8          {d14,d15}, [r4,:128], r12
yading@10:         vld1.8          {d12,d13}, [r4,:128], r12
yading@10:         vld1.8          {d10,d11}, [r4,:128], r12
yading@10:         vld1.8          {d8, d9},  [r4,:128], r12
yading@10:         vld1.8          {d6, d7},  [r4,:128], r12
yading@10:         vld1.8          {d4, d5},  [r4,:128], r12
yading@10:         vld1.8          {d2, d3},  [r4,:128], r12
yading@10:         vld1.8          {d0, d1},  [r4,:128]
yading@10: 
yading@10:         swap4           d1,  d3,  d5,  d7,  d8,  d10, d12, d14
yading@10:         transpose16_4x4 q0,  q1,  q2,  q3,  q4,  q5,  q6,  q7
yading@10: 
yading@10:         swap4           d17, d19, d21, d31, d24, d26, d28, d22
yading@10:         transpose16_4x4 q8,  q9,  q10, q15, q12, q13, q14, q11
yading@10: 
yading@10:         vst1.8          {d30,d31}, [r4,:128]!
yading@10:         vst1.8          {d6, d7},  [r4,:128]!
yading@10:         vst1.8          {d20,d21}, [r4,:128]!
yading@10:         vst1.8          {d4, d5},  [r4,:128]!
yading@10:         vst1.8          {d18,d19}, [r4,:128]!
yading@10:         vst1.8          {d2, d3},  [r4,:128]!
yading@10:         vst1.8          {d16,d17}, [r4,:128]!
yading@10:         vst1.8          {d0, d1},  [r4,:128]
yading@10: 
yading@10:         lowpass_8.16    q4,  q12, d8,  d9,  d24, d25, d8
yading@10:         lowpass_8.16    q5,  q13, d10, d11, d26, d27, d9
yading@10:         lowpass_8.16    q6,  q14, d12, d13, d28, d29, d10
yading@10:         lowpass_8.16    q7,  q11, d14, d15, d22, d23, d11
yading@10: 
yading@10:         vld1.8          {d16,d17}, [r4,:128], r12
yading@10:         vld1.8          {d30,d31}, [r4,:128], r12
yading@10:         lowpass_8.16    q8,  q15, d16, d17, d30, d31, d12
yading@10:         vld1.8          {d16,d17}, [r4,:128], r12
yading@10:         vld1.8          {d30,d31}, [r4,:128], r12
yading@10:         lowpass_8.16    q8,  q15, d16, d17, d30, d31, d13
yading@10:         vld1.8          {d16,d17}, [r4,:128], r12
yading@10:         vld1.8          {d30,d31}, [r4,:128], r12
yading@10:         lowpass_8.16    q8,  q15, d16, d17, d30, d31, d14
yading@10:         vld1.8          {d16,d17}, [r4,:128], r12
yading@10:         vld1.8          {d30,d31}, [r4,:128]
yading@10:         lowpass_8.16    q8,  q15, d16, d17, d30, d31, d15
yading@10: 
yading@10:         transpose_8x8   d12, d13, d14, d15, d8,  d9,  d10, d11
yading@10: 
yading@10:         bx              lr
yading@10: endfunc
yading@10: 
yading@10: .macro  h264_qpel8_hv_lowpass type
yading@10: function \type\()_h264_qpel8_hv_lowpass_neon
yading@10:         mov             r10, lr
yading@10:         bl              put_h264_qpel8_hv_lowpass_neon_top
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d0},      [r0,:64], r2
yading@10:         vrhadd.u8       d12, d12, d0
yading@10:         vld1.8          {d1},      [r0,:64], r2
yading@10:         vrhadd.u8       d13, d13, d1
yading@10:         vld1.8          {d2},      [r0,:64], r2
yading@10:         vrhadd.u8       d14, d14, d2
yading@10:         vld1.8          {d3},      [r0,:64], r2
yading@10:         vrhadd.u8       d15, d15, d3
yading@10:         vld1.8          {d4},      [r0,:64], r2
yading@10:         vrhadd.u8       d8,  d8,  d4
yading@10:         vld1.8          {d5},      [r0,:64], r2
yading@10:         vrhadd.u8       d9,  d9,  d5
yading@10:         vld1.8          {d6},      [r0,:64], r2
yading@10:         vrhadd.u8       d10, d10, d6
yading@10:         vld1.8          {d7},      [r0,:64], r2
yading@10:         vrhadd.u8       d11, d11, d7
yading@10:         sub             r0,  r0,  r2,  lsl #3
yading@10:   .endif
yading@10: 
yading@10:         vst1.8          {d12},     [r0,:64], r2
yading@10:         vst1.8          {d13},     [r0,:64], r2
yading@10:         vst1.8          {d14},     [r0,:64], r2
yading@10:         vst1.8          {d15},     [r0,:64], r2
yading@10:         vst1.8          {d8},      [r0,:64], r2
yading@10:         vst1.8          {d9},      [r0,:64], r2
yading@10:         vst1.8          {d10},     [r0,:64], r2
yading@10:         vst1.8          {d11},     [r0,:64], r2
yading@10: 
yading@10:         mov             lr,  r10
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel8_hv_lowpass put
yading@10:         h264_qpel8_hv_lowpass avg
yading@10: 
yading@10: .macro  h264_qpel8_hv_lowpass_l2 type
yading@10: function \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         mov             r10, lr
yading@10:         bl              put_h264_qpel8_hv_lowpass_neon_top
yading@10: 
yading@10:         vld1.8          {d0, d1},  [r2,:128]!
yading@10:         vld1.8          {d2, d3},  [r2,:128]!
yading@10:         vrhadd.u8       q0,  q0,  q6
yading@10:         vld1.8          {d4, d5},  [r2,:128]!
yading@10:         vrhadd.u8       q1,  q1,  q7
yading@10:         vld1.8          {d6, d7},  [r2,:128]!
yading@10:         vrhadd.u8       q2,  q2,  q4
yading@10:         vrhadd.u8       q3,  q3,  q5
yading@10:   .ifc \type,avg
yading@10:         vld1.8          {d16},     [r0,:64], r3
yading@10:         vrhadd.u8       d0,  d0,  d16
yading@10:         vld1.8          {d17},     [r0,:64], r3
yading@10:         vrhadd.u8       d1,  d1,  d17
yading@10:         vld1.8          {d18},     [r0,:64], r3
yading@10:         vrhadd.u8       d2,  d2,  d18
yading@10:         vld1.8          {d19},     [r0,:64], r3
yading@10:         vrhadd.u8       d3,  d3,  d19
yading@10:         vld1.8          {d20},     [r0,:64], r3
yading@10:         vrhadd.u8       d4,  d4,  d20
yading@10:         vld1.8          {d21},     [r0,:64], r3
yading@10:         vrhadd.u8       d5,  d5,  d21
yading@10:         vld1.8          {d22},     [r0,:64], r3
yading@10:         vrhadd.u8       d6,  d6,  d22
yading@10:         vld1.8          {d23},     [r0,:64], r3
yading@10:         vrhadd.u8       d7,  d7,  d23
yading@10:         sub             r0,  r0,  r3,  lsl #3
yading@10:   .endif
yading@10:         vst1.8          {d0},      [r0,:64], r3
yading@10:         vst1.8          {d1},      [r0,:64], r3
yading@10:         vst1.8          {d2},      [r0,:64], r3
yading@10:         vst1.8          {d3},      [r0,:64], r3
yading@10:         vst1.8          {d4},      [r0,:64], r3
yading@10:         vst1.8          {d5},      [r0,:64], r3
yading@10:         vst1.8          {d6},      [r0,:64], r3
yading@10:         vst1.8          {d7},      [r0,:64], r3
yading@10: 
yading@10:         mov             lr,  r10
yading@10:         bx              lr
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel8_hv_lowpass_l2 put
yading@10:         h264_qpel8_hv_lowpass_l2 avg
yading@10: 
yading@10: .macro  h264_qpel16_hv  type
yading@10: function \type\()_h264_qpel16_hv_lowpass_neon
yading@10:         mov             r9,  lr
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #4
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         add             r1,  r1,  #8
yading@10:         sub             r0,  r0,  r2, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         mov             lr,  r9
yading@10:         b               \type\()_h264_qpel8_hv_lowpass_neon
yading@10: endfunc
yading@10: 
yading@10: function \type\()_h264_qpel16_hv_lowpass_l2_neon
yading@10:         mov             r9,  lr
yading@10:         sub             r2,  r4,  #256
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         sub             r1,  r1,  r3, lsl #4
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         add             r1,  r1,  #8
yading@10:         sub             r0,  r0,  r3, lsl #4
yading@10:         add             r0,  r0,  #8
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         sub             r1,  r1,  r3, lsl #2
yading@10:         mov             lr,  r9
yading@10:         b               \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel16_hv put
yading@10:         h264_qpel16_hv avg
yading@10: 
yading@10: .macro  h264_qpel8      type
yading@10: function ff_\type\()_h264_qpel8_mc10_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         mov             r3,  r1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r12, #8
yading@10:         b               \type\()_h264_qpel8_h_lowpass_l2_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc20_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         mov             r12, #8
yading@10:         b               \type\()_h264_qpel8_h_lowpass_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc30_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         add             r3,  r1,  #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r12, #8
yading@10:         b               \type\()_h264_qpel8_h_lowpass_l2_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc01_neon, export=1
yading@10:         push            {lr}
yading@10:         mov             r12, r1
yading@10: \type\()_h264_qpel8_mc01:
yading@10:         lowpass_const   r3
yading@10:         mov             r3,  r2
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         pop             {pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc11_neon, export=1
yading@10:         push            {r0, r1, r11, lr}
yading@10: \type\()_h264_qpel8_mc11:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #64
yading@10:         mov             r0,  sp
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  #8
yading@10:         mov             r12, #8
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel8_h_lowpass_neon
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         mov             r3,  r2
yading@10:         add             r12, sp,  #64
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r2,  #8
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc21_neon, export=1
yading@10:         push            {r0, r1, r4, r10, r11, lr}
yading@10: \type\()_h264_qpel8_mc21:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #(8*8+16*12)
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  #8
yading@10:         mov             r0,  sp
yading@10:         mov             r12, #8
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel8_h_lowpass_neon
yading@10:         mov             r4,  r0
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         sub             r2,  r4,  #64
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4, r10, r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc31_neon, export=1
yading@10:         add             r1,  r1,  #1
yading@10:         push            {r0, r1, r11, lr}
yading@10:         sub             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel8_mc11
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc02_neon, export=1
yading@10:         push            {lr}
yading@10:         lowpass_const   r3
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r3,  r2
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel8_v_lowpass_neon
yading@10:         vpop            {d8-d15}
yading@10:         pop             {pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc12_neon, export=1
yading@10:         push            {r0, r1, r4, r10, r11, lr}
yading@10: \type\()_h264_qpel8_mc12:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #(8*8+16*12)
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r3,  r2
yading@10:         mov             r2,  #8
yading@10:         mov             r0,  sp
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel8_v_lowpass_neon
yading@10:         mov             r4,  r0
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         sub             r1,  r1,  r3, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         sub             r2,  r4,  #64
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4, r10, r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc22_neon, export=1
yading@10:         push            {r4, r10, r11, lr}
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r4,  r11, #15
yading@10: T       mov             sp,  r4
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         sub             sp,  sp,  #(16*12)
yading@10:         mov             r4,  sp
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel8_hv_lowpass_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4, r10, r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc32_neon, export=1
yading@10:         push            {r0, r1, r4, r10, r11, lr}
yading@10:         add             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel8_mc12
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc03_neon, export=1
yading@10:         push            {lr}
yading@10:         add             r12, r1,  r2
yading@10:         b               \type\()_h264_qpel8_mc01
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc13_neon, export=1
yading@10:         push            {r0, r1, r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         b               \type\()_h264_qpel8_mc11
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc23_neon, export=1
yading@10:         push            {r0, r1, r4, r10, r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         b               \type\()_h264_qpel8_mc21
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel8_mc33_neon, export=1
yading@10:         add             r1,  r1,  #1
yading@10:         push            {r0, r1, r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         sub             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel8_mc11
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel8 put
yading@10:         h264_qpel8 avg
yading@10: 
yading@10: .macro  h264_qpel16     type
yading@10: function ff_\type\()_h264_qpel16_mc10_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         mov             r3,  r1
yading@10:         sub             r1,  r1,  #2
yading@10:         b               \type\()_h264_qpel16_h_lowpass_l2_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc20_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         b               \type\()_h264_qpel16_h_lowpass_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc30_neon, export=1
yading@10:         lowpass_const   r3
yading@10:         add             r3,  r1,  #1
yading@10:         sub             r1,  r1,  #2
yading@10:         b               \type\()_h264_qpel16_h_lowpass_l2_neon
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc01_neon, export=1
yading@10:         push            {r4, lr}
yading@10:         mov             r12, r1
yading@10: \type\()_h264_qpel16_mc01:
yading@10:         lowpass_const   r3
yading@10:         mov             r3,  r2
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel16_v_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         pop             {r4, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc11_neon, export=1
yading@10:         push            {r0, r1, r4, r11, lr}
yading@10: \type\()_h264_qpel16_mc11:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #256
yading@10:         mov             r0,  sp
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  #16
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel16_h_lowpass_neon
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         mov             r3,  r2
yading@10:         add             r12, sp,  #64
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r2,  #16
yading@10:         bl              \type\()_h264_qpel16_v_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4, r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc21_neon, export=1
yading@10:         push            {r0, r1, r4-r5, r9-r11, lr}
yading@10: \type\()_h264_qpel16_mc21:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #(16*16+16*12)
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r0,  sp
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel16_h_lowpass_neon_packed
yading@10:         mov             r4,  r0
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         bl              \type\()_h264_qpel16_hv_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4-r5, r9-r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc31_neon, export=1
yading@10:         add             r1,  r1,  #1
yading@10:         push            {r0, r1, r4, r11, lr}
yading@10:         sub             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel16_mc11
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc02_neon, export=1
yading@10:         push            {r4, lr}
yading@10:         lowpass_const   r3
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r3,  r2
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel16_v_lowpass_neon
yading@10:         vpop            {d8-d15}
yading@10:         pop             {r4, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc12_neon, export=1
yading@10:         push            {r0, r1, r4-r5, r9-r11, lr}
yading@10: \type\()_h264_qpel16_mc12:
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r0,  r11, #15
yading@10: T       mov             sp,  r0
yading@10:         sub             sp,  sp,  #(16*16+16*12)
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         mov             r0,  sp
yading@10:         mov             r3,  r2
yading@10:         vpush           {d8-d15}
yading@10:         bl              put_h264_qpel16_v_lowpass_neon_packed
yading@10:         mov             r4,  r0
yading@10:         ldrd            r0,  r1,  [r11], #8
yading@10:         sub             r1,  r1,  r3, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r2,  r3
yading@10:         bl              \type\()_h264_qpel16_hv_lowpass_l2_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4-r5, r9-r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc22_neon, export=1
yading@10:         push            {r4, r9-r11, lr}
yading@10:         lowpass_const   r3
yading@10:         mov             r11, sp
yading@10: A       bic             sp,  sp,  #15
yading@10: T       bic             r4,  r11, #15
yading@10: T       mov             sp,  r4
yading@10:         sub             r1,  r1,  r2, lsl #1
yading@10:         sub             r1,  r1,  #2
yading@10:         mov             r3,  r2
yading@10:         sub             sp,  sp,  #(16*12)
yading@10:         mov             r4,  sp
yading@10:         vpush           {d8-d15}
yading@10:         bl              \type\()_h264_qpel16_hv_lowpass_neon
yading@10:         vpop            {d8-d15}
yading@10:         mov             sp,  r11
yading@10:         pop             {r4, r9-r11, pc}
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc32_neon, export=1
yading@10:         push            {r0, r1, r4-r5, r9-r11, lr}
yading@10:         add             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel16_mc12
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc03_neon, export=1
yading@10:         push            {r4, lr}
yading@10:         add             r12, r1,  r2
yading@10:         b               \type\()_h264_qpel16_mc01
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc13_neon, export=1
yading@10:         push            {r0, r1, r4, r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         b               \type\()_h264_qpel16_mc11
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc23_neon, export=1
yading@10:         push            {r0, r1, r4-r5, r9-r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         b               \type\()_h264_qpel16_mc21
yading@10: endfunc
yading@10: 
yading@10: function ff_\type\()_h264_qpel16_mc33_neon, export=1
yading@10:         add             r1,  r1,  #1
yading@10:         push            {r0, r1, r4, r11, lr}
yading@10:         add             r1,  r1,  r2
yading@10:         sub             r1,  r1,  #1
yading@10:         b               \type\()_h264_qpel16_mc11
yading@10: endfunc
yading@10: .endm
yading@10: 
yading@10:         h264_qpel16 put
yading@10:         h264_qpel16 avg