yading@10: ;******************************************************************************
yading@10: ;* MMX/SSE2-optimized functions for the RV40 decoder
yading@10: ;* Copyright (c) 2010 Ronald S. Bultje <rsbultje@gmail.com>
yading@10: ;* Copyright (c) 2010 Jason Garrett-Glaser <darkshikari@gmail.com>
yading@10: ;* Copyright (C) 2012 Christophe Gisquet <christophe.gisquet@gmail.com>
yading@10: ;*
yading@10: ;* This file is part of Libav.
yading@10: ;*
yading@10: ;* Libav is free software; you can redistribute it and/or
yading@10: ;* modify it under the terms of the GNU Lesser General Public
yading@10: ;* License as published by the Free Software Foundation; either
yading@10: ;* version 2.1 of the License, or (at your option) any later version.
yading@10: ;*
yading@10: ;* Libav is distributed in the hope that it will be useful,
yading@10: ;* but WITHOUT ANY WARRANTY; without even the implied warranty of
yading@10: ;* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
yading@10: ;* Lesser General Public License for more details.
yading@10: ;*
yading@10: ;* You should have received a copy of the GNU Lesser General Public
yading@10: ;* License along with Libav; if not, write to the Free Software
yading@10: ;* Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
yading@10: ;******************************************************************************
yading@10: 
yading@10: %include "libavutil/x86/x86util.asm"
yading@10: 
yading@10: SECTION_RODATA
yading@10: 
yading@10: align 16
yading@10: pw_1024:   times 8 dw 1 << (16 - 6) ; pw_1024
yading@10: 
yading@10: sixtap_filter_hb_m:  times 8 db   1, -5
yading@10:                      times 8 db  52, 20
yading@10:                      ; multiplied by 2 to have the same shift
yading@10:                      times 8 db   2, -10
yading@10:                      times 8 db  40,  40
yading@10:                      ; back to normal
yading@10:                      times 8 db   1, -5
yading@10:                      times 8 db  20, 52
yading@10: 
yading@10: sixtap_filter_v_m:   times 8 dw   1
yading@10:                      times 8 dw  -5
yading@10:                      times 8 dw  52
yading@10:                      times 8 dw  20
yading@10:                      ; multiplied by 2 to have the same shift
yading@10:                      times 8 dw   2
yading@10:                      times 8 dw -10
yading@10:                      times 8 dw  40
yading@10:                      times 8 dw  40
yading@10:                      ; back to normal
yading@10:                      times 8 dw   1
yading@10:                      times 8 dw  -5
yading@10:                      times 8 dw  20
yading@10:                      times 8 dw  52
yading@10: 
yading@10: %ifdef PIC
yading@10: %define sixtap_filter_hw   picregq
yading@10: %define sixtap_filter_hb   picregq
yading@10: %define sixtap_filter_v    picregq
yading@10: %define npicregs 1
yading@10: %else
yading@10: %define sixtap_filter_hw   sixtap_filter_hw_m
yading@10: %define sixtap_filter_hb   sixtap_filter_hb_m
yading@10: %define sixtap_filter_v    sixtap_filter_v_m
yading@10: %define npicregs 0
yading@10: %endif
yading@10: 
yading@10: filter_h6_shuf1: db 0, 1, 1, 2, 2, 3, 3, 4, 4, 5,  5, 6,  6,  7,  7,  8
yading@10: filter_h6_shuf2: db 2, 3, 3, 4, 4, 5, 5, 6, 6, 7,  7, 8,  8,  9,  9, 10
yading@10: filter_h6_shuf3: db 5, 4, 6, 5, 7, 6, 8, 7, 9, 8, 10, 9, 11, 10, 12, 11
yading@10: 
yading@10: cextern  pw_32
yading@10: cextern  pw_16
yading@10: cextern  pw_512
yading@10: 
yading@10: SECTION .text
yading@10: 
yading@10: ;-----------------------------------------------------------------------------
yading@10: ; subpel MC functions:
yading@10: ;
yading@10: ; void [put|rv40]_rv40_qpel_[h|v]_<opt>(uint8_t *dst, int deststride,
yading@10: ;                                       uint8_t *src, int srcstride,
yading@10: ;                                       int len, int m);
yading@10: ;----------------------------------------------------------------------
yading@10: %macro LOAD  2
yading@10: %if WIN64
yading@10:    movsxd   %1q, %1d
yading@10: %endif
yading@10: %ifdef PIC
yading@10:    add      %1q, picregq
yading@10: %else
yading@10:    add      %1q, %2
yading@10: %endif
yading@10: %endmacro
yading@10: 
yading@10: %macro STORE 3
yading@10: %ifidn %3, avg
yading@10:     movh      %2, [dstq]
yading@10: %endif
yading@10:     packuswb  %1, %1
yading@10: %ifidn %3, avg
yading@10: %if cpuflag(3dnow)
yading@10:     pavgusb   %1, %2
yading@10: %else
yading@10:     pavgb     %1, %2
yading@10: %endif
yading@10: %endif
yading@10:     movh  [dstq], %1
yading@10: %endmacro
yading@10: 
yading@10: %macro FILTER_V 1
yading@10: cglobal %1_rv40_qpel_v, 6,6+npicregs,12, dst, dststride, src, srcstride, height, my, picreg
yading@10: %ifdef PIC
yading@10:     lea  picregq, [sixtap_filter_v_m]
yading@10: %endif
yading@10:     pxor      m7, m7
yading@10:     LOAD      my, sixtap_filter_v
yading@10: 
yading@10:     ; read 5 lines
yading@10:     sub     srcq, srcstrideq
yading@10:     sub     srcq, srcstrideq
yading@10:     movh      m0, [srcq]
yading@10:     movh      m1, [srcq+srcstrideq]
yading@10:     movh      m2, [srcq+srcstrideq*2]
yading@10:     lea     srcq, [srcq+srcstrideq*2]
yading@10:     add     srcq, srcstrideq
yading@10:     movh      m3, [srcq]
yading@10:     movh      m4, [srcq+srcstrideq]
yading@10:     punpcklbw m0, m7
yading@10:     punpcklbw m1, m7
yading@10:     punpcklbw m2, m7
yading@10:     punpcklbw m3, m7
yading@10:     punpcklbw m4, m7
yading@10: 
yading@10: %ifdef m8
yading@10:     mova      m8, [myq+ 0]
yading@10:     mova      m9, [myq+16]
yading@10:     mova     m10, [myq+32]
yading@10:     mova     m11, [myq+48]
yading@10: %define COEFF05  m8
yading@10: %define COEFF14  m9
yading@10: %define COEFF2   m10
yading@10: %define COEFF3   m11
yading@10: %else
yading@10: %define COEFF05  [myq+ 0]
yading@10: %define COEFF14  [myq+16]
yading@10: %define COEFF2   [myq+32]
yading@10: %define COEFF3   [myq+48]
yading@10: %endif
yading@10: .nextrow:
yading@10:     mova      m6, m1
yading@10:     movh      m5, [srcq+2*srcstrideq]      ; read new row
yading@10:     paddw     m6, m4
yading@10:     punpcklbw m5, m7
yading@10:     pmullw    m6, COEFF14
yading@10:     paddw     m0, m5
yading@10:     pmullw    m0, COEFF05
yading@10:     paddw     m6, m0
yading@10:     mova      m0, m1
yading@10:     paddw     m6, [pw_32]
yading@10:     mova      m1, m2
yading@10:     pmullw    m2, COEFF2
yading@10:     paddw     m6, m2
yading@10:     mova      m2, m3
yading@10:     pmullw    m3, COEFF3
yading@10:     paddw     m6, m3
yading@10: 
yading@10:     ; round/clip/store
yading@10:     mova      m3, m4
yading@10:     psraw     m6, 6
yading@10:     mova      m4, m5
yading@10:     STORE     m6, m5, %1
yading@10: 
yading@10:     ; go to next line
yading@10:     add     dstq, dststrideq
yading@10:     add     srcq, srcstrideq
yading@10:     dec  heightd                           ; next row
yading@10:     jg .nextrow
yading@10:     REP_RET
yading@10: %endmacro
yading@10: 
yading@10: %macro FILTER_H  1
yading@10: cglobal %1_rv40_qpel_h, 6, 6+npicregs, 12, dst, dststride, src, srcstride, height, mx, picreg
yading@10: %ifdef PIC
yading@10:     lea  picregq, [sixtap_filter_v_m]
yading@10: %endif
yading@10:     pxor      m7, m7
yading@10:     LOAD      mx, sixtap_filter_v
yading@10:     mova      m6, [pw_32]
yading@10: %ifdef m8
yading@10:     mova      m8, [mxq+ 0]
yading@10:     mova      m9, [mxq+16]
yading@10:     mova     m10, [mxq+32]
yading@10:     mova     m11, [mxq+48]
yading@10: %define COEFF05  m8
yading@10: %define COEFF14  m9
yading@10: %define COEFF2   m10
yading@10: %define COEFF3   m11
yading@10: %else
yading@10: %define COEFF05  [mxq+ 0]
yading@10: %define COEFF14  [mxq+16]
yading@10: %define COEFF2   [mxq+32]
yading@10: %define COEFF3   [mxq+48]
yading@10: %endif
yading@10: .nextrow:
yading@10:     movq      m0, [srcq-2]
yading@10:     movq      m5, [srcq+3]
yading@10:     movq      m1, [srcq-1]
yading@10:     movq      m4, [srcq+2]
yading@10:     punpcklbw m0, m7
yading@10:     punpcklbw m5, m7
yading@10:     punpcklbw m1, m7
yading@10:     punpcklbw m4, m7
yading@10:     movq      m2, [srcq-0]
yading@10:     movq      m3, [srcq+1]
yading@10:     paddw     m0, m5
yading@10:     paddw     m1, m4
yading@10:     punpcklbw m2, m7
yading@10:     punpcklbw m3, m7
yading@10:     pmullw    m0, COEFF05
yading@10:     pmullw    m1, COEFF14
yading@10:     pmullw    m2, COEFF2
yading@10:     pmullw    m3, COEFF3
yading@10:     paddw     m0, m6
yading@10:     paddw     m1, m2
yading@10:     paddw     m0, m3
yading@10:     paddw     m0, m1
yading@10:     psraw     m0, 6
yading@10:     STORE     m0, m1, %1
yading@10: 
yading@10:     ; go to next line
yading@10:     add     dstq, dststrideq
yading@10:     add     srcq, srcstrideq
yading@10:     dec  heightd            ; next row
yading@10:     jg .nextrow
yading@10:     REP_RET
yading@10: %endmacro
yading@10: 
yading@10: %if ARCH_X86_32
yading@10: INIT_MMX  mmx
yading@10: FILTER_V  put
yading@10: FILTER_H  put
yading@10: 
yading@10: INIT_MMX  mmxext
yading@10: FILTER_V  avg
yading@10: FILTER_H  avg
yading@10: 
yading@10: INIT_MMX  3dnow
yading@10: FILTER_V  avg
yading@10: FILTER_H  avg
yading@10: %endif
yading@10: 
yading@10: INIT_XMM  sse2
yading@10: FILTER_H  put
yading@10: FILTER_H  avg
yading@10: FILTER_V  put
yading@10: FILTER_V  avg
yading@10: 
yading@10: %macro FILTER_SSSE3 1
yading@10: cglobal %1_rv40_qpel_v, 6,6+npicregs,8, dst, dststride, src, srcstride, height, my, picreg
yading@10: %ifdef PIC
yading@10:     lea  picregq, [sixtap_filter_hb_m]
yading@10: %endif
yading@10: 
yading@10:     ; read 5 lines
yading@10:     sub     srcq, srcstrideq
yading@10:     LOAD      my, sixtap_filter_hb
yading@10:     sub     srcq, srcstrideq
yading@10:     movh      m0, [srcq]
yading@10:     movh      m1, [srcq+srcstrideq]
yading@10:     movh      m2, [srcq+srcstrideq*2]
yading@10:     lea     srcq, [srcq+srcstrideq*2]
yading@10:     add     srcq, srcstrideq
yading@10:     mova      m5, [myq]
yading@10:     movh      m3, [srcq]
yading@10:     movh      m4, [srcq+srcstrideq]
yading@10:     lea     srcq, [srcq+2*srcstrideq]
yading@10: 
yading@10: .nextrow:
yading@10:     mova      m6, m2
yading@10:     punpcklbw m0, m1
yading@10:     punpcklbw m6, m3
yading@10:     pmaddubsw m0, m5
yading@10:     pmaddubsw m6, [myq+16]
yading@10:     movh      m7, [srcq]      ; read new row
yading@10:     paddw     m6, m0
yading@10:     mova      m0, m1
yading@10:     mova      m1, m2
yading@10:     mova      m2, m3
yading@10:     mova      m3, m4
yading@10:     mova      m4, m7
yading@10:     punpcklbw m7, m3
yading@10:     pmaddubsw m7, m5
yading@10:     paddw     m6, m7
yading@10:     pmulhrsw  m6, [pw_512]
yading@10:     STORE     m6, m7, %1
yading@10: 
yading@10:     ; go to next line
yading@10:     add     dstq, dststrideq
yading@10:     add     srcq, srcstrideq
yading@10:     dec       heightd                          ; next row
yading@10:     jg       .nextrow
yading@10:     REP_RET
yading@10: 
yading@10: cglobal %1_rv40_qpel_h, 6,6+npicregs,8, dst, dststride, src, srcstride, height, mx, picreg
yading@10: %ifdef PIC
yading@10:     lea  picregq, [sixtap_filter_hb_m]
yading@10: %endif
yading@10:     mova      m3, [filter_h6_shuf2]
yading@10:     mova      m4, [filter_h6_shuf3]
yading@10:     LOAD      mx, sixtap_filter_hb
yading@10:     mova      m5, [mxq] ; set up 6tap filter in bytes
yading@10:     mova      m6, [mxq+16]
yading@10:     mova      m7, [filter_h6_shuf1]
yading@10: 
yading@10: .nextrow:
yading@10:     movu      m0, [srcq-2]
yading@10:     mova      m1, m0
yading@10:     mova      m2, m0
yading@10:     pshufb    m0, m7
yading@10:     pshufb    m1, m3
yading@10:     pshufb    m2, m4
yading@10:     pmaddubsw m0, m5
yading@10:     pmaddubsw m1, m6
yading@10:     pmaddubsw m2, m5
yading@10:     paddw     m0, m1
yading@10:     paddw     m0, m2
yading@10:     pmulhrsw  m0, [pw_512]
yading@10:     STORE     m0, m1, %1
yading@10: 
yading@10:     ; go to next line
yading@10:     add     dstq, dststrideq
yading@10:     add     srcq, srcstrideq
yading@10:     dec  heightd            ; next row
yading@10:     jg .nextrow
yading@10:     REP_RET
yading@10: %endmacro
yading@10: 
yading@10: INIT_XMM ssse3
yading@10: FILTER_SSSE3  put
yading@10: FILTER_SSSE3  avg
yading@10: 
yading@10: ; %1=5bits weights?, %2=dst %3=src1 %4=src3 %5=stride if sse2
yading@10: %macro RV40_WCORE  4-5
yading@10:     movh       m4, [%3 + r6 + 0]
yading@10:     movh       m5, [%4 + r6 + 0]
yading@10: %if %0 == 4
yading@10: %define OFFSET r6 + mmsize / 2
yading@10: %else
yading@10:     ; 8x8 block and sse2, stride was provided
yading@10: %define OFFSET r6
yading@10:     add        r6, r5
yading@10: %endif
yading@10:     movh       m6, [%3 + OFFSET]
yading@10:     movh       m7, [%4 + OFFSET]
yading@10: 
yading@10: %if %1 == 0
yading@10:     ; 14bits weights
yading@10:     punpcklbw  m4, m0
yading@10:     punpcklbw  m5, m0
yading@10:     punpcklbw  m6, m0
yading@10:     punpcklbw  m7, m0
yading@10: 
yading@10:     psllw      m4, 7
yading@10:     psllw      m5, 7
yading@10:     psllw      m6, 7
yading@10:     psllw      m7, 7
yading@10:     pmulhw     m4, m3
yading@10:     pmulhw     m5, m2
yading@10:     pmulhw     m6, m3
yading@10:     pmulhw     m7, m2
yading@10: 
yading@10:     paddw      m4, m5
yading@10:     paddw      m6, m7
yading@10: %else
yading@10:     ; 5bits weights
yading@10: %if cpuflag(ssse3)
yading@10:     punpcklbw  m4, m5
yading@10:     punpcklbw  m6, m7
yading@10: 
yading@10:     pmaddubsw  m4, m3
yading@10:     pmaddubsw  m6, m3
yading@10: %else
yading@10:     punpcklbw  m4, m0
yading@10:     punpcklbw  m5, m0
yading@10:     punpcklbw  m6, m0
yading@10:     punpcklbw  m7, m0
yading@10: 
yading@10:     pmullw     m4, m3
yading@10:     pmullw     m5, m2
yading@10:     pmullw     m6, m3
yading@10:     pmullw     m7, m2
yading@10:     paddw      m4, m5
yading@10:     paddw      m6, m7
yading@10: %endif
yading@10: 
yading@10: %endif
yading@10: 
yading@10:     ; bias and shift down
yading@10: %if cpuflag(ssse3)
yading@10:     pmulhrsw   m4, m1
yading@10:     pmulhrsw   m6, m1
yading@10: %else
yading@10:     paddw      m4, m1
yading@10:     paddw      m6, m1
yading@10:     psrlw      m4, 5
yading@10:     psrlw      m6, 5
yading@10: %endif
yading@10: 
yading@10:     packuswb   m4, m6
yading@10: %if %0 == 5
yading@10:     ; Only called for 8x8 blocks and sse2
yading@10:     sub        r6, r5
yading@10:     movh       [%2 + r6], m4
yading@10:     add        r6, r5
yading@10:     movhps     [%2 + r6], m4
yading@10: %else
yading@10:     mova       [%2 + r6], m4
yading@10: %endif
yading@10: %endmacro
yading@10: 
yading@10: 
yading@10: %macro MAIN_LOOP   2
yading@10: %if mmsize == 8
yading@10:     RV40_WCORE %2, r0, r1, r2
yading@10: %if %1 == 16
yading@10:     RV40_WCORE %2, r0 + 8, r1 + 8, r2 + 8
yading@10: %endif
yading@10: 
yading@10:     ; Prepare for next loop
yading@10:     add        r6, r5
yading@10: %else
yading@10: %ifidn %1, 8
yading@10:     RV40_WCORE %2, r0, r1, r2, r5
yading@10:     ; Prepare 2 next lines
yading@10:     add        r6, r5
yading@10: %else
yading@10:     RV40_WCORE %2, r0, r1, r2
yading@10:     ; Prepare single next line
yading@10:     add        r6, r5
yading@10: %endif
yading@10: %endif
yading@10: 
yading@10: %endmacro
yading@10: 
yading@10: ; rv40_weight_func_%1(uint8_t *dst, uint8_t *src1, uint8_t *src2, int w1, int w2, int stride)
yading@10: ; %1=size  %2=num of xmm regs
yading@10: ; The weights are FP0.14 notation of fractions depending on pts.
yading@10: ; For timebases without rounding error (i.e. PAL), the fractions
yading@10: ; can be simplified, and several operations can be avoided.
yading@10: ; Therefore, we check here whether they are multiples of 2^9 for
yading@10: ; those simplifications to occur.
yading@10: %macro RV40_WEIGHT  3
yading@10: cglobal rv40_weight_func_%1_%2, 6, 7, 8
yading@10: %if cpuflag(ssse3)
yading@10:     mova       m1, [pw_1024]
yading@10: %else
yading@10:     mova       m1, [pw_16]
yading@10: %endif
yading@10:     pxor       m0, m0
yading@10:     ; Set loop counter and increments
yading@10:     mov        r6, r5
yading@10:     shl        r6, %3
yading@10:     add        r0, r6
yading@10:     add        r1, r6
yading@10:     add        r2, r6
yading@10:     neg        r6
yading@10: 
yading@10:     movd       m2, r3d
yading@10:     movd       m3, r4d
yading@10: %ifidn %1,rnd
yading@10: %define  RND   0
yading@10:     SPLATW     m2, m2
yading@10: %else
yading@10: %define  RND   1
yading@10: %if cpuflag(ssse3)
yading@10:     punpcklbw  m3, m2
yading@10: %else
yading@10:     SPLATW     m2, m2
yading@10: %endif
yading@10: %endif
yading@10:     SPLATW     m3, m3
yading@10: 
yading@10: .loop:
yading@10:     MAIN_LOOP  %2, RND
yading@10:     jnz        .loop
yading@10:     REP_RET
yading@10: %endmacro
yading@10: 
yading@10: INIT_MMX mmxext
yading@10: RV40_WEIGHT   rnd,    8, 3
yading@10: RV40_WEIGHT   rnd,   16, 4
yading@10: RV40_WEIGHT   nornd,  8, 3
yading@10: RV40_WEIGHT   nornd, 16, 4
yading@10: 
yading@10: INIT_XMM sse2
yading@10: RV40_WEIGHT   rnd,    8, 3
yading@10: RV40_WEIGHT   rnd,   16, 4
yading@10: RV40_WEIGHT   nornd,  8, 3
yading@10: RV40_WEIGHT   nornd, 16, 4
yading@10: 
yading@10: INIT_XMM ssse3
yading@10: RV40_WEIGHT   rnd,    8, 3
yading@10: RV40_WEIGHT   rnd,   16, 4
yading@10: RV40_WEIGHT   nornd,  8, 3
yading@10: RV40_WEIGHT   nornd, 16, 4