Daniel@0: /* Part of DML (Digital Music Laboratory)
Daniel@0: 	Copyright 2014-2015 Samer Abdallah, University of London
Daniel@0: 	 
Daniel@0: 	This program is free software; you can redistribute it and/or
Daniel@0: 	modify it under the terms of the GNU General Public License
Daniel@0: 	as published by the Free Software Foundation; either version 2
Daniel@0: 	of the License, or (at your option) any later version.
Daniel@0: 
Daniel@0: 	This program is distributed in the hope that it will be useful,
Daniel@0: 	but WITHOUT ANY WARRANTY; without even the implied warranty of
Daniel@0: 	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Daniel@0: 	GNU General Public License for more details.
Daniel@0: 
Daniel@0: 	You should have received a copy of the GNU General Public
Daniel@0: 	License along with this library; if not, write to the Free Software
Daniel@0: 	Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA
Daniel@0: */
Daniel@0: 
Daniel@0: :- module(uripattern, [
Daniel@0: 		simplify/2
Daniel@0:    ,  pattern_uri/2
Daniel@0: 	]).
Daniel@0: 
Daniel@0: :- use_module(library(semweb/rdf_db), [ rdf_global_id/2 ]).
Daniel@0: 
Daniel@0: :- multifile uripattern:def/2.
Daniel@0: 
Daniel@0: %% uri_constraint(+P:uripattern,?X:uri) is nondet.
Daniel@0: %  Logical predicate implemented using delayed goals.
Daniel@0: pattern_uri(A,B) :- must_be(nonvar,A), resource(A,B).
Daniel@0: 
Daniel@0: resource(P:A,PB) :- !, rdf_global_id(P:'',Q), plain(Q+A,PB).
Daniel@0: resource(A,B) :- plain(A,B).
Daniel@0: 
Daniel@0: plain(\(M),B) :- def(M,A), (var(A) -> true; plain(A,B)).
Daniel@0: plain(A1/A2,B)  :- plain(A1+'/'+A2,B).
Daniel@0: plain(num(N),B) :- when((nonvar(N);nonvar(B)), atom_number1(B,N)).
Daniel@0: plain(enc(A),B) :- when((nonvar(A);nonvar(B)), www_form_encode1(A,B)).
Daniel@0: plain(atm(A),A).
Daniel@0: plain(A1+A2,B) :- 
Daniel@0:    freeze(A1,plain(A1,B1)),
Daniel@0:    freeze(A2,plain(A2,B2)),
Daniel@0:    when((ground(B1),ground(B2);ground(B)), atom_concat1(B1,B2,B)).
Daniel@0: plain(A,A)     :- atom(A).
Daniel@0: 
Daniel@0: %% simplify(+P1:uri_pattern, -P2:uri_pattern) is nondet.
Daniel@0: %  Non-deterministic maximal reduction of URI pattern.
Daniel@0: simplify(E1,E3) :- 
Daniel@0:    reduce(E1,E2) *-> simplify(E2,E3); E1=E3.
Daniel@0: 
Daniel@0: % simplify resource if possible, fails otherwise
Daniel@0: % The pattern must be nonvar.
Daniel@0: reduce(A,B) :- must_be(nonvar,A), reduce1(A,B).
Daniel@0: 
Daniel@0: reduce1(num(N),A)     :- number(N), atom_number(A,N).
Daniel@0: reduce1(atm(A),A)     :- atomic(A).
Daniel@0: reduce1(\(A),B)       :- nonvar(A), def(A,B).
Daniel@0: reduce1(enc(A),B)     :- atomic(A), www_form_encode(A,B).
Daniel@0: reduce1(P:A,Q+A)      :- rdf_global_id(P:'',Q).
Daniel@0: reduce1(A/B,A+'/'+B).
Daniel@0: reduce1(A+B,A1+B)     :- reduce(A,A1).
Daniel@0: reduce1(A+B,A+B1)     :- reduce(B,B1). % nb to get past these, A and B must be nonvar
Daniel@0: reduce1(A+B,AB)       :- atom(A), atom(B), atom_concat(A,B,AB).
Daniel@0: reduce1((A+B)+C,A+BC) :- reduce1(B+C,BC). 
Daniel@0: reduce1(A+(B+C),AB+C) :- reduce1(A+B,AB).
Daniel@0: 
Daniel@0: % ---------- support predicates ---------
Daniel@0: 
Daniel@0: atom_number1(Atom,Number) :-
Daniel@0:    (nonvar(Number) -> number(Number); true),
Daniel@0:    atom_number(Atom,Number).
Daniel@0: 
Daniel@0: www_form_encode1(Atom,Encoded) :-
Daniel@0:    (nonvar(Encoded) -> atomic(Encoded); true),
Daniel@0:    www_form_encode(Atom,Encoded).
Daniel@0: 
Daniel@0: atom_concat1(A,B,AB) :-
Daniel@0:    (nonvar(AB) -> atomic(AB); true),
Daniel@0:    atom_concat(A,B,AB).
Daniel@0: