samer@3: "        File: imaps.vim
samer@3: "     Authors: Srinath Avadhanula <srinath AT fastmail.fm>
samer@3: "              Benji Fisher <benji AT member.AMS.org>
samer@3: "              
samer@3: "         WWW: http://cvs.sourceforge.net/cgi-bin/viewcvs.cgi/vim-latex/vimfiles/plugin/imaps.vim?only_with_tag=MAIN
samer@3: "
samer@3: " Description: insert mode template expander with cursor placement
samer@3: "              while preserving filetype indentation.
samer@3: "
samer@3: "     $Id: imaps.vim 997 2006-03-20 09:45:45Z srinathava $
samer@3: "
samer@3: " Documentation: {{{
samer@3: "
samer@3: " Motivation:
samer@3: " this script provides a way to generate insert mode mappings which do not
samer@3: " suffer from some of the problem of mappings and abbreviations while allowing
samer@3: " cursor placement after the expansion. It can alternatively be thought of as
samer@3: " a template expander. 
samer@3: "
samer@3: " Consider an example. If you do
samer@3: "
samer@3: " imap lhs something
samer@3: "
samer@3: " then a mapping is set up. However, there will be the following problems:
samer@3: " 1. the 'ttimeout' option will generally limit how easily you can type the
samer@3: "    lhs. if you type the left hand side too slowly, then the mapping will not
samer@3: "    be activated.
samer@3: " 2. if you mistype one of the letters of the lhs, then the mapping is
samer@3: "    deactivated as soon as you backspace to correct the mistake.
samer@3: "
samer@3: " If, in order to take care of the above problems, you do instead
samer@3: "
samer@3: " iab lhs something
samer@3: "
samer@3: " then the timeout problem is solved and so is the problem of mistyping.
samer@3: " however, abbreviations are only expanded after typing a non-word character.
samer@3: " which causes problems of cursor placement after the expansion and invariably
samer@3: " spurious spaces are inserted.
samer@3: " 
samer@3: " Usage Example:
samer@3: " this script attempts to solve all these problems by providing an emulation
samer@3: " of imaps wchich does not suffer from its attendant problems. Because maps
samer@3: " are activated without having to press additional characters, therefore
samer@3: " cursor placement is possible. furthermore, file-type specific indentation is
samer@3: " preserved, because the rhs is expanded as if the rhs is typed in literally
samer@3: " by the user.
samer@3: "  
samer@3: " The script already provides some default mappings. each "mapping" is of the
samer@3: " form:
samer@3: "
samer@3: " call IMAP (lhs, rhs, ft)
samer@3: " 
samer@3: " Some characters in the RHS have special meaning which help in cursor
samer@3: " placement.
samer@3: "
samer@3: " Example One:
samer@3: "
samer@3: " 	call IMAP ("bit`", "\\begin{itemize}\<cr>\\item <++>\<cr>\\end{itemize}<++>", "tex")
samer@3: " 
samer@3: " This effectively sets up the map for "bit`" whenever you edit a latex file.
samer@3: " When you type in this sequence of letters, the following text is inserted:
samer@3: " 
samer@3: " \begin{itemize}
samer@3: " \item *
samer@3: " \end{itemize}<++>
samer@3: "
samer@3: " where * shows the cursor position. The cursor position after inserting the
samer@3: " text is decided by the position of the first "place-holder". Place holders
samer@3: " are special characters which decide cursor placement and movement. In the
samer@3: " example above, the place holder characters are <+ and +>. After you have typed
samer@3: " in the item, press <C-j> and you will be taken to the next set of <++>'s.
samer@3: " Therefore by placing the <++> characters appropriately, you can minimize the
samer@3: " use of movement keys.
samer@3: "
samer@3: " NOTE: Set g:Imap_UsePlaceHolders to 0 to disable placeholders altogether.
samer@3: " Set 
samer@3: " 	g:Imap_PlaceHolderStart and g:Imap_PlaceHolderEnd
samer@3: " to something else if you want different place holder characters.
samer@3: " Also, b:Imap_PlaceHolderStart and b:Imap_PlaceHolderEnd override the values
samer@3: " of g:Imap_PlaceHolderStart and g:Imap_PlaceHolderEnd respectively. This is
samer@3: " useful for setting buffer specific place hoders.
samer@3: " 
samer@3: " Example Two:
samer@3: " You can use the <C-r> command to insert dynamic elements such as dates.
samer@3: "	call IMAP ('date`', "\<c-r>=strftime('%b %d %Y')\<cr>", '')
samer@3: "
samer@3: " sets up the map for date` to insert the current date.
samer@3: "
samer@3: "--------------------------------------%<--------------------------------------
samer@3: " Bonus: This script also provides a command Snip which puts tearoff strings,
samer@3: " '----%<----' above and below the visually selected range of lines. The
samer@3: " length of the string is chosen to be equal to the longest line in the range.
samer@3: " Recommended Usage:
samer@3: "   '<,'>Snip
samer@3: "--------------------------------------%<--------------------------------------
samer@3: " }}}
samer@3: 
samer@3: " line continuation used here.
samer@3: let s:save_cpo = &cpo
samer@3: set cpo&vim
samer@3: 
samer@3: " ==============================================================================
samer@3: " Script Options / Variables
samer@3: " ============================================================================== 
samer@3: " Options {{{
samer@3: if !exists('g:Imap_StickyPlaceHolders')
samer@3: 	let g:Imap_StickyPlaceHolders = 1
samer@3: endif
samer@3: if !exists('g:Imap_DeleteEmptyPlaceHolders')
samer@3: 	let g:Imap_DeleteEmptyPlaceHolders = 1
samer@3: endif
samer@3: " }}}
samer@3: " Variables {{{
samer@3: " s:LHS_{ft}_{char} will be generated automatically.  It will look like
samer@3: " s:LHS_tex_o = 'fo\|foo\|boo' and contain all mapped sequences ending in "o".
samer@3: " s:Map_{ft}_{lhs} will be generated automatically.  It will look like
samer@3: " s:Map_c_foo = 'for(<++>; <++>; <++>)', the mapping for "foo".
samer@3: "
samer@3: " }}}
samer@3: 
samer@3: " ==============================================================================
samer@3: " functions for easy insert mode mappings.
samer@3: " ==============================================================================
samer@3: " IMAP: Adds a "fake" insert mode mapping. {{{
samer@3: "       For example, doing
samer@3: "           IMAP('abc', 'def' ft) 
samer@3: "       will mean that if the letters abc are pressed in insert mode, then
samer@3: "       they will be replaced by def. If ft != '', then the "mapping" will be
samer@3: "       specific to the files of type ft. 
samer@3: "
samer@3: "       Using IMAP has a few advantages over simply doing:
samer@3: "           imap abc def
samer@3: "       1. with imap, if you begin typing abc, the cursor will not advance and
samer@3: "          long as there is a possible completion, the letters a, b, c will be
samer@3: "          displayed on on top of the other. using this function avoids that.
samer@3: "       2. with imap, if a backspace or arrow key is pressed before completing
samer@3: "          the word, then the mapping is lost. this function allows movement. 
samer@3: "          (this ofcourse means that this function is only limited to
samer@3: "          left-hand-sides which do not have movement keys or unprintable
samer@3: "          characters)
samer@3: "       It works by only mapping the last character of the left-hand side.
samer@3: "       when this character is typed in, then a reverse lookup is done and if
samer@3: "       the previous characters consititute the left hand side of the mapping,
samer@3: "       the previously typed characters and erased and the right hand side is
samer@3: "       inserted
samer@3: 
samer@3: " IMAP: set up a filetype specific mapping.
samer@3: " Description:
samer@3: "   "maps" the lhs to rhs in files of type 'ft'. If supplied with 2
samer@3: "   additional arguments, then those are assumed to be the placeholder
samer@3: "   characters in rhs. If unspecified, then the placeholder characters
samer@3: "   are assumed to be '<+' and '+>' These placeholder characters in
samer@3: "   a:rhs are replaced with the users setting of
samer@3: "   [bg]:Imap_PlaceHolderStart and [bg]:Imap_PlaceHolderEnd settings.
samer@3: "
samer@3: function! IMAP(lhs, rhs, ft, ...)
samer@3: 
samer@3: 	" Find the place holders to save for IMAP_PutTextWithMovement() .
samer@3: 	if a:0 < 2
samer@3: 		let phs = '<+'
samer@3: 		let phe = '+>'
samer@3: 	else
samer@3: 		let phs = a:1
samer@3: 		let phe = a:2
samer@3: 	endif
samer@3: 
samer@3: 	let hash = s:Hash(a:lhs)
samer@3: 	let s:Map_{a:ft}_{hash} = a:rhs
samer@3: 	let s:phs_{a:ft}_{hash} = phs
samer@3: 	let s:phe_{a:ft}_{hash} = phe
samer@3: 
samer@3: 	" Add a:lhs to the list of left-hand sides that end with lastLHSChar:
samer@3: 	let lastLHSChar = a:lhs[strlen(a:lhs)-1]
samer@3: 	let hash = s:Hash(lastLHSChar)
samer@3: 	if !exists("s:LHS_" . a:ft . "_" . hash)
samer@3: 		let s:LHS_{a:ft}_{hash} = escape(a:lhs, '\')
samer@3: 	else
samer@3: 		let s:LHS_{a:ft}_{hash} = escape(a:lhs, '\') .'\|'.  s:LHS_{a:ft}_{hash}
samer@3: 	endif
samer@3: 
samer@3: 	" map only the last character of the left-hand side.
samer@3: 	if lastLHSChar == ' '
samer@3: 		let lastLHSChar = '<space>'
samer@3: 	end
samer@3: 	exe 'inoremap <silent>'
samer@3: 				\ escape(lastLHSChar, '|')
samer@3: 				\ '<C-r>=<SID>LookupCharacter("' .
samer@3: 				\ escape(lastLHSChar, '\|"') .
samer@3: 				\ '")<CR>'
samer@3: endfunction
samer@3: 
samer@3: " }}}
samer@3: " IMAP_list:  list the rhs and place holders corresponding to a:lhs {{{
samer@3: "
samer@3: " Added mainly for debugging purposes, but maybe worth keeping.
samer@3: function! IMAP_list(lhs)
samer@3: 	let char = a:lhs[strlen(a:lhs)-1]
samer@3: 	let charHash = s:Hash(char)
samer@3: 	if exists("s:LHS_" . &ft ."_". charHash) && a:lhs =~ s:LHS_{&ft}_{charHash}
samer@3: 		let ft = &ft
samer@3: 	elseif exists("s:LHS__" . charHash) && a:lhs =~ s:LHS__{charHash}
samer@3: 		let ft = ""
samer@3: 	else
samer@3: 		return ""
samer@3: 	endif
samer@3: 	let hash = s:Hash(a:lhs)
samer@3: 	return "rhs = " . s:Map_{ft}_{hash} . " place holders = " .
samer@3: 				\ s:phs_{ft}_{hash} . " and " . s:phe_{ft}_{hash}
samer@3: endfunction
samer@3: " }}}
samer@3: " LookupCharacter: inserts mapping corresponding to this character {{{
samer@3: "
samer@3: " This function extracts from s:LHS_{&ft}_{a:char} or s:LHS__{a:char}
samer@3: " the longest lhs matching the current text.  Then it replaces lhs with the
samer@3: " corresponding rhs saved in s:Map_{ft}_{lhs} .
samer@3: " The place-holder variables are passed to IMAP_PutTextWithMovement() .
samer@3: function! s:LookupCharacter(char)
samer@3: 	if IMAP_GetVal('Imap_FreezeImap', 0) == 1
samer@3: 		return a:char
samer@3: 	endif
samer@3: 	let charHash = s:Hash(a:char)
samer@3: 
samer@3: 	" The line so far, including the character that triggered this function:
samer@3: 	let text = strpart(getline("."), 0, col(".")-1) . a:char
samer@3: 	" Prefer a local map to a global one, even if the local map is shorter.
samer@3: 	" Is this what we want?  Do we care?
samer@3: 	" Use '\V' (very no-magic) so that only '\' is special, and it was already
samer@3: 	" escaped when building up s:LHS_{&ft}_{charHash} .
samer@3: 	if exists("s:LHS_" . &ft . "_" . charHash)
samer@3: 				\ && text =~ "\\C\\V\\(" . s:LHS_{&ft}_{charHash} . "\\)\\$"
samer@3: 		let ft = &ft
samer@3: 	elseif exists("s:LHS__" . charHash)
samer@3: 				\ && text =~ "\\C\\V\\(" . s:LHS__{charHash} . "\\)\\$"
samer@3: 		let ft = ""
samer@3: 	else
samer@3: 		" If this is a character which could have been used to trigger an
samer@3: 		" abbreviation, check if an abbreviation exists.
samer@3: 		if a:char !~ '\k'
samer@3: 			let lastword = matchstr(getline('.'), '\k\+$', '')
samer@3: 			call IMAP_Debug('getting lastword = ['.lastword.']', 'imap')
samer@3: 			if lastword != ''
samer@3: 				" An extremeley wierd way to get around the fact that vim
samer@3: 				" doesn't have the equivalent of the :mapcheck() function for
samer@3: 				" abbreviations.
samer@3: 				let _a = @a
samer@3: 				exec "redir @a | silent! iab ".lastword." | redir END"
samer@3: 				let abbreviationRHS = matchstr(@a."\n", "\n".'i\s\+'.lastword.'\s\+@\?\zs.*\ze'."\n")
samer@3: 
samer@3: 				call IMAP_Debug('getting abbreviationRHS = ['.abbreviationRHS.']', 'imap')
samer@3: 
samer@3: 				if @a =~ "No abbreviation found" || abbreviationRHS == ""
samer@3: 					let @a = _a
samer@3: 					return a:char
samer@3: 				endif
samer@3: 
samer@3: 				let @a = _a
samer@3: 				let abbreviationRHS = escape(abbreviationRHS, '\<"')
samer@3: 				exec 'let abbreviationRHS = "'.abbreviationRHS.'"'
samer@3: 
samer@3: 				let lhs = lastword.a:char
samer@3: 				let rhs = abbreviationRHS.a:char
samer@3: 				let phs = IMAP_GetPlaceHolderStart()
samer@3: 				let phe = IMAP_GetPlaceHolderEnd()
samer@3: 			else
samer@3: 				return a:char
samer@3: 			endif
samer@3: 		else
samer@3: 			return a:char
samer@3: 		endif
samer@3: 	endif
samer@3: 	" Find the longest left-hand side that matches the line so far.
samer@3: 	" matchstr() returns the match that starts first. This automatically
samer@3: 	" ensures that the longest LHS is used for the mapping.
samer@3: 	if !exists('lhs') || !exists('rhs')
samer@3: 		let lhs = matchstr(text, "\\C\\V\\(" . s:LHS_{ft}_{charHash} . "\\)\\$")
samer@3: 		let hash = s:Hash(lhs)
samer@3: 		let rhs = s:Map_{ft}_{hash}
samer@3: 		let phs = s:phs_{ft}_{hash} 
samer@3: 		let phe = s:phe_{ft}_{hash}
samer@3: 	endif
samer@3: 
samer@3: 	if strlen(lhs) == 0
samer@3: 		return a:char
samer@3: 	endif
samer@3: 	" enough back-spaces to erase the left-hand side; -1 for the last
samer@3: 	" character typed:
samer@3: 	let bs = substitute(strpart(lhs, 1), ".", "\<bs>", "g")
samer@3: 	return bs . IMAP_PutTextWithMovement(rhs, phs, phe)
samer@3: endfunction
samer@3: 
samer@3: " }}}
samer@3: " IMAP_PutTextWithMovement: returns the string with movement appended {{{
samer@3: " Description:
samer@3: "   If a:str contains "placeholders", then appends movement commands to
samer@3: "   str in a way that the user moves to the first placeholder and enters
samer@3: "   insert or select mode. If supplied with 2 additional arguments, then
samer@3: "   they are assumed to be the placeholder specs. Otherwise, they are
samer@3: "   assumed to be '<+' and '+>'. These placeholder chars are replaced
samer@3: "   with the users settings of [bg]:Imap_PlaceHolderStart and
samer@3: "   [bg]:Imap_PlaceHolderEnd.
samer@3: function! IMAP_PutTextWithMovement(str, ...)
samer@3: 
samer@3: 	" The placeholders used in the particular input string. These can be
samer@3: 	" different from what the user wants to use.
samer@3: 	if a:0 < 2
samer@3: 		let phs = '<+'
samer@3: 		let phe = '+>'
samer@3: 	else
samer@3: 		let phs = escape(a:1, '\')
samer@3: 		let phe = escape(a:2, '\')
samer@3: 	endif
samer@3: 
samer@3: 	let text = a:str
samer@3: 
samer@3: 	" The user's placeholder settings.
samer@3: 	let phsUser = IMAP_GetPlaceHolderStart()
samer@3: 	let pheUser = IMAP_GetPlaceHolderEnd()
samer@3: 
samer@3: 	" Problem:  depending on the setting of the 'encoding' option, a character
samer@3: 	" such as "\xab" may not match itself.  We try to get around this by
samer@3: 	" changing the encoding of all our strings.  At the end, we have to
samer@3: 	" convert text back.
samer@3: 	let phsEnc     = s:Iconv(phs, "encode")
samer@3: 	let pheEnc     = s:Iconv(phe, "encode")
samer@3: 	let phsUserEnc = s:Iconv(phsUser, "encode")
samer@3: 	let pheUserEnc = s:Iconv(pheUser, "encode")
samer@3: 	let textEnc    = s:Iconv(text, "encode")
samer@3: 	if textEnc != text
samer@3: 		let textEncoded = 1
samer@3: 	else
samer@3: 		let textEncoded = 0
samer@3: 	endif
samer@3: 
samer@3: 	let pattern = '\V\(\.\{-}\)' .phs. '\(\.\{-}\)' .phe. '\(\.\*\)'
samer@3: 	" If there are no placeholders, just return the text.
samer@3: 	if textEnc !~ pattern
samer@3: 		call IMAP_Debug('Not getting '.phs.' and '.phe.' in '.textEnc, 'imap')
samer@3: 		return text
samer@3: 	endif
samer@3: 	" Break text up into "initial <+template+> final"; any piece may be empty.
samer@3: 	let initialEnc  = substitute(textEnc, pattern, '\1', '')
samer@3: 	let templateEnc = substitute(textEnc, pattern, '\2', '')
samer@3: 	let finalEnc    = substitute(textEnc, pattern, '\3', '')
samer@3: 
samer@3: 	" If the user does not want to use placeholders, then remove all but the
samer@3: 	" first placeholder.
samer@3: 	" Otherwise, replace all occurences of the placeholders here with the
samer@3: 	" user's choice of placeholder settings.
samer@3: 	if exists('g:Imap_UsePlaceHolders') && !g:Imap_UsePlaceHolders
samer@3: 		let finalEnc = substitute(finalEnc, '\V'.phs.'\.\{-}'.phe, '', 'g')
samer@3: 	else
samer@3: 		let finalEnc = substitute(finalEnc, '\V'.phs.'\(\.\{-}\)'.phe,
samer@3: 					\ phsUserEnc.'\1'.pheUserEnc, 'g')
samer@3: 	endif
samer@3: 
samer@3: 	" The substitutions are done, so convert back, if necessary.
samer@3: 	if textEncoded
samer@3: 		let initial = s:Iconv(initialEnc, "decode")
samer@3: 		let template = s:Iconv(templateEnc, "decode")
samer@3: 		let final = s:Iconv(finalEnc, "decode")
samer@3: 	else
samer@3: 		let initial = initialEnc
samer@3: 		let template = templateEnc
samer@3: 		let final = finalEnc
samer@3: 	endif
samer@3: 
samer@3: 	" Build up the text to insert:
samer@3: 	" 1. the initial text plus an extra character;
samer@3: 	" 2. go to Normal mode with <C-\><C-N>, so it works even if 'insertmode'
samer@3: 	" is set, and mark the position;
samer@3: 	" 3. replace the extra character with tamplate and final;
samer@3: 	" 4. back to Normal mode and restore the cursor position;
samer@3: 	" 5. call IMAP_Jumpfunc().
samer@3: 	let template = phsUser . template . pheUser
samer@3: 	" Old trick:  insert and delete a character to get the same behavior at
samer@3: 	" start, middle, or end of line and on empty lines.
samer@3: 	let text = initial . "X\<C-\>\<C-N>:call IMAP_Mark('set')\<CR>\"_s"
samer@3: 	let text = text . template . final
samer@3: 	let text = text . "\<C-\>\<C-N>:call IMAP_Mark('go')\<CR>"
samer@3: 	let text = text . "i\<C-r>=IMAP_Jumpfunc('', 1)\<CR>"
samer@3: 
samer@3: 	call IMAP_Debug('IMAP_PutTextWithMovement: text = ['.text.']', 'imap')
samer@3: 	return text
samer@3: endfunction
samer@3: 
samer@3: " }}}
samer@3: " IMAP_Jumpfunc: takes user to next <+place-holder+> {{{
samer@3: " Author: Luc Hermitte
samer@3: " Arguments:
samer@3: " direction: flag for the search() function. If set to '', search forwards,
samer@3: "            if 'b', then search backwards. See the {flags} argument of the
samer@3: "            |search()| function for valid values.
samer@3: " inclusive: In vim, the search() function is 'exclusive', i.e we always goto
samer@3: "            next cursor match even if there is a match starting from the
samer@3: "            current cursor position. Setting this argument to 1 makes
samer@3: "            IMAP_Jumpfunc() also respect a match at the current cursor
samer@3: "            position. 'inclusive'ness is necessary for IMAP() because a
samer@3: "            placeholder string can occur at the very beginning of a map which
samer@3: "            we want to select.
samer@3: "            We use a non-zero value only in special conditions. Most mappings
samer@3: "            should use a zero value.
samer@3: function! IMAP_Jumpfunc(direction, inclusive)
samer@3: 
samer@3: 	" The user's placeholder settings.
samer@3: 	let phsUser = IMAP_GetPlaceHolderStart()
samer@3: 	let pheUser = IMAP_GetPlaceHolderEnd()
samer@3: 
samer@3: 	let searchString = ''
samer@3: 	" If this is not an inclusive search or if it is inclusive, but the
samer@3: 	" current cursor position does not contain a placeholder character, then
samer@3: 	" search for the placeholder characters.
samer@3: 	if !a:inclusive || strpart(getline('.'), col('.')-1) !~ '\V\^'.phsUser
samer@3: 		let searchString = '\V'.phsUser.'\_.\{-}'.pheUser
samer@3: 	endif
samer@3: 
samer@3: 	" If we didn't find any placeholders return quietly.
samer@3: 	if searchString != '' && !search(searchString, a:direction)
samer@3: 		return ''
samer@3: 	endif
samer@3: 
samer@3: 	" Open any closed folds and make this part of the text visible.
samer@3: 	silent! foldopen!
samer@3: 
samer@3: 	" Calculate if we have an empty placeholder or if it contains some
samer@3: 	" description.
samer@3: 	let template = 
samer@3: 		\ matchstr(strpart(getline('.'), col('.')-1),
samer@3: 		\          '\V\^'.phsUser.'\zs\.\{-}\ze\('.pheUser.'\|\$\)')
samer@3: 	let placeHolderEmpty = !strlen(template)
samer@3: 
samer@3: 	" If we are selecting in exclusive mode, then we need to move one step to
samer@3: 	" the right
samer@3: 	let extramove = ''
samer@3: 	if &selection == 'exclusive'
samer@3: 		let extramove = 'l'
samer@3: 	endif
samer@3: 
samer@3: 	" Select till the end placeholder character.
samer@3: 	let movement = "\<C-o>v/\\V".pheUser."/e\<CR>".extramove
samer@3: 
samer@3: 	" First remember what the search pattern was. s:RemoveLastHistoryItem will
samer@3: 	" reset @/ to this pattern so we do not create new highlighting.
samer@3: 	let g:Tex_LastSearchPattern = @/
samer@3: 
samer@3: 	" Now either goto insert mode or select mode.
samer@3: 	if placeHolderEmpty && g:Imap_DeleteEmptyPlaceHolders
samer@3: 		" delete the empty placeholder into the blackhole.
samer@3: 		return movement."\"_c\<C-o>:".s:RemoveLastHistoryItem."\<CR>"
samer@3: 	else
samer@3: 		return movement."\<C-\>\<C-N>:".s:RemoveLastHistoryItem."\<CR>gv\<C-g>"
samer@3: 	endif
samer@3: 	
samer@3: endfunction
samer@3: 
samer@3: " }}}
samer@3: " Maps for IMAP_Jumpfunc {{{
samer@3: "
samer@3: " These mappings use <Plug> and thus provide for easy user customization. When
samer@3: " the user wants to map some other key to jump forward, he can do for
samer@3: " instance:
samer@3: "   nmap ,f   <plug>IMAP_JumpForward
samer@3: " etc.
samer@3: 
samer@3: " jumping forward and back in insert mode.
samer@3: imap <silent> <Plug>IMAP_JumpForward    <c-r>=IMAP_Jumpfunc('', 0)<CR>
samer@3: imap <silent> <Plug>IMAP_JumpBack       <c-r>=IMAP_Jumpfunc('b', 0)<CR>
samer@3: 
samer@3: " jumping in normal mode
samer@3: nmap <silent> <Plug>IMAP_JumpForward        i<c-r>=IMAP_Jumpfunc('', 0)<CR>
samer@3: nmap <silent> <Plug>IMAP_JumpBack           i<c-r>=IMAP_Jumpfunc('b', 0)<CR>
samer@3: 
samer@3: " deleting the present selection and then jumping forward.
samer@3: vmap <silent> <Plug>IMAP_DeleteAndJumpForward       "_<Del>i<c-r>=IMAP_Jumpfunc('', 0)<CR>
samer@3: vmap <silent> <Plug>IMAP_DeleteAndJumpBack          "_<Del>i<c-r>=IMAP_Jumpfunc('b', 0)<CR>
samer@3: 
samer@3: " jumping forward without deleting present selection.
samer@3: vmap <silent> <Plug>IMAP_JumpForward       <C-\><C-N>i<c-r>=IMAP_Jumpfunc('', 0)<CR>
samer@3: vmap <silent> <Plug>IMAP_JumpBack          <C-\><C-N>`<i<c-r>=IMAP_Jumpfunc('b', 0)<CR>
samer@3: 
samer@3: " }}}
samer@3: " Default maps for IMAP_Jumpfunc {{{
samer@3: " map only if there is no mapping already. allows for user customization.
samer@3: " NOTE: Default mappings for jumping to the previous placeholder are not
samer@3: "       provided. It is assumed that if the user will create such mappings
samer@3: "       hself if e so desires.
samer@3: if !hasmapto('<Plug>IMAP_JumpForward', 'i')
samer@3:     imap <C-J> <Plug>IMAP_JumpForward
samer@3: endif
samer@3: if !hasmapto('<Plug>IMAP_JumpForward', 'n')
samer@3:     nmap <C-J> <Plug>IMAP_JumpForward
samer@3: endif
samer@3: if exists('g:Imap_StickyPlaceHolders') && g:Imap_StickyPlaceHolders
samer@3: 	if !hasmapto('<Plug>IMAP_JumpForward', 'v')
samer@3: 		vmap <C-J> <Plug>IMAP_JumpForward
samer@3: 	endif
samer@3: else
samer@3: 	if !hasmapto('<Plug>IMAP_DeleteAndJumpForward', 'v')
samer@3: 		vmap <C-J> <Plug>IMAP_DeleteAndJumpForward
samer@3: 	endif
samer@3: endif
samer@3: " }}}
samer@3: 
samer@3: nmap <silent> <script> <plug><+SelectRegion+> `<v`>
samer@3: 
samer@3: " ============================================================================== 
samer@3: " enclosing selected region.
samer@3: " ============================================================================== 
samer@3: " VEnclose: encloses the visually selected region with given arguments {{{
samer@3: " Description: allows for differing action based on visual line wise
samer@3: "              selection or visual characterwise selection. preserves the
samer@3: "              marks and search history.
samer@3: function! VEnclose(vstart, vend, VStart, VEnd)
samer@3: 
samer@3: 	" its characterwise if
samer@3: 	" 1. characterwise selection and valid values for vstart and vend.
samer@3: 	" OR
samer@3: 	" 2. linewise selection and invalid values for VStart and VEnd
samer@3: 	if (visualmode() == 'v' && (a:vstart != '' || a:vend != '')) || (a:VStart == '' && a:VEnd == '')
samer@3: 
samer@3: 		let newline = ""
samer@3: 		let _r = @r
samer@3: 
samer@3: 		let normcmd = "normal! \<C-\>\<C-n>`<v`>\"_s"
samer@3: 
samer@3: 		exe "normal! \<C-\>\<C-n>`<v`>\"ry"
samer@3: 		if @r =~ "\n$"
samer@3: 			let newline = "\n"
samer@3: 			let @r = substitute(@r, "\n$", '', '')
samer@3: 		endif
samer@3: 
samer@3: 		" In exclusive selection, we need to select an extra character.
samer@3: 		if &selection == 'exclusive'
samer@3: 			let movement = 8
samer@3: 		else
samer@3: 			let movement = 7
samer@3: 		endif
samer@3: 		let normcmd = normcmd.
samer@3: 			\ a:vstart."!!mark!!".a:vend.newline.
samer@3: 			\ "\<C-\>\<C-N>?!!mark!!\<CR>v".movement."l\"_s\<C-r>r\<C-\>\<C-n>"
samer@3: 
samer@3: 		" this little if statement is because till very recently, vim used to
samer@3: 		" report col("'>") > length of selected line when `> is $. on some
samer@3: 		" systems it reports a -ve number.
samer@3: 		if col("'>") < 0 || col("'>") > strlen(getline("'>"))
samer@3: 			let lastcol = strlen(getline("'>"))
samer@3: 		else
samer@3: 			let lastcol = col("'>")
samer@3: 		endif
samer@3: 		if lastcol - col("'<") != 0
samer@3: 			let len = lastcol - col("'<")
samer@3: 		else
samer@3: 			let len = ''
samer@3: 		endif
samer@3: 
samer@3: 		" the next normal! is for restoring the marks.
samer@3: 		let normcmd = normcmd."`<v".len."l\<C-\>\<C-N>"
samer@3: 
samer@3: 		" First remember what the search pattern was. s:RemoveLastHistoryItem
samer@3: 		" will reset @/ to this pattern so we do not create new highlighting.
samer@3: 		let g:Tex_LastSearchPattern = @/
samer@3: 
samer@3: 		silent! exe normcmd
samer@3: 		" this is to restore the r register.
samer@3: 		let @r = _r
samer@3: 		" and finally, this is to restore the search history.
samer@3: 		execute s:RemoveLastHistoryItem
samer@3: 
samer@3: 	else
samer@3: 
samer@3: 		exec 'normal! `<O'.a:VStart."\<C-\>\<C-n>"
samer@3: 		exec 'normal! `>o'.a:VEnd."\<C-\>\<C-n>"
samer@3: 		if &indentexpr != ''
samer@3: 			silent! normal! `<kV`>j=
samer@3: 		endif
samer@3: 		silent! normal! `>
samer@3: 	endif
samer@3: endfunction 
samer@3: 
samer@3: " }}}
samer@3: " ExecMap: adds the ability to correct an normal/visual mode mapping.  {{{
samer@3: " Author: Hari Krishna Dara <hari_vim@yahoo.com>
samer@3: " Reads a normal mode mapping at the command line and executes it with the
samer@3: " given prefix. Press <BS> to correct and <Esc> to cancel.
samer@3: function! ExecMap(prefix, mode)
samer@3: 	" Temporarily remove the mapping, otherwise it will interfere with the
samer@3: 	" mapcheck call below:
samer@3: 	let myMap = maparg(a:prefix, a:mode)
samer@3: 	exec a:mode."unmap ".a:prefix
samer@3: 
samer@3: 	" Generate a line with spaces to clear the previous message.
samer@3: 	let i = 1
samer@3: 	let clearLine = "\r"
samer@3: 	while i < &columns
samer@3: 		let clearLine = clearLine . ' '
samer@3: 		let i = i + 1
samer@3: 	endwhile
samer@3: 
samer@3: 	let mapCmd = a:prefix
samer@3: 	let foundMap = 0
samer@3: 	let breakLoop = 0
samer@3: 	echon "\rEnter Map: " . mapCmd
samer@3: 	while !breakLoop
samer@3: 		let char = getchar()
samer@3: 		if char !~ '^\d\+$'
samer@3: 			if char == "\<BS>"
samer@3: 				let mapCmd = strpart(mapCmd, 0, strlen(mapCmd) - 1)
samer@3: 			endif
samer@3: 		else " It is the ascii code.
samer@3: 			let char = nr2char(char)
samer@3: 			if char == "\<Esc>"
samer@3: 				let breakLoop = 1
samer@3: 			else
samer@3: 				let mapCmd = mapCmd . char
samer@3: 				if maparg(mapCmd, a:mode) != ""
samer@3: 					let foundMap = 1
samer@3: 					let breakLoop = 1
samer@3: 				elseif mapcheck(mapCmd, a:mode) == ""
samer@3: 					let mapCmd = strpart(mapCmd, 0, strlen(mapCmd) - 1)
samer@3: 				endif
samer@3: 			endif
samer@3: 		endif
samer@3: 		echon clearLine
samer@3: 		echon "\rEnter Map: " . mapCmd
samer@3: 	endwhile
samer@3: 	if foundMap
samer@3: 		if a:mode == 'v'
samer@3: 			" use a plug to select the region instead of using something like
samer@3: 			" `<v`> to avoid problems caused by some of the characters in
samer@3: 			" '`<v`>' being mapped.
samer@3: 			let gotoc = "\<plug><+SelectRegion+>"
samer@3: 		else
samer@3: 			let gotoc = ''
samer@3: 		endif
samer@3: 		exec "normal ".gotoc.mapCmd
samer@3: 	endif
samer@3: 	exec a:mode.'noremap '.a:prefix.' '.myMap
samer@3: endfunction
samer@3: 
samer@3: " }}}
samer@3: 
samer@3: " ============================================================================== 
samer@3: " helper functions
samer@3: " ============================================================================== 
samer@3: " Strntok: extract the n^th token from a list {{{
samer@3: " example: Strntok('1,23,3', ',', 2) = 23
samer@3: fun! <SID>Strntok(s, tok, n)
samer@3: 	return matchstr( a:s.a:tok[0], '\v(\zs([^'.a:tok.']*)\ze['.a:tok.']){'.a:n.'}')
samer@3: endfun
samer@3: 
samer@3: " }}}
samer@3: " s:RemoveLastHistoryItem: removes last search item from search history {{{
samer@3: " Description: Execute this string to clean up the search history.
samer@3: let s:RemoveLastHistoryItem = ':call histdel("/", -1)|let @/=g:Tex_LastSearchPattern'
samer@3: 
samer@3: " }}}
samer@3: " s:Hash: Return a version of a string that can be used as part of a variable" {{{
samer@3: " name.
samer@3: " 	Converts every non alphanumeric character into _{ascii}_ where {ascii} is
samer@3: " 	the ASCII code for that character...
samer@3: fun! s:Hash(text)
samer@3: 	return substitute(a:text, '\([^[:alnum:]]\)',
samer@3: 				\ '\="_".char2nr(submatch(1))."_"', 'g')
samer@3: endfun
samer@3: "" }}}
samer@3: " IMAP_GetPlaceHolderStart and IMAP_GetPlaceHolderEnd:  "{{{
samer@3: " return the buffer local placeholder variables, or the global one, or the default.
samer@3: function! IMAP_GetPlaceHolderStart()
samer@3: 	if exists("b:Imap_PlaceHolderStart") && strlen(b:Imap_PlaceHolderEnd)
samer@3: 		return b:Imap_PlaceHolderStart
samer@3: 	elseif exists("g:Imap_PlaceHolderStart") && strlen(g:Imap_PlaceHolderEnd)
samer@3: 		return g:Imap_PlaceHolderStart
samer@3: 	else
samer@3: 		return "<+"
samer@3: endfun
samer@3: function! IMAP_GetPlaceHolderEnd()
samer@3: 	if exists("b:Imap_PlaceHolderEnd") && strlen(b:Imap_PlaceHolderEnd)
samer@3: 		return b:Imap_PlaceHolderEnd
samer@3: 	elseif exists("g:Imap_PlaceHolderEnd") && strlen(g:Imap_PlaceHolderEnd)
samer@3: 		return g:Imap_PlaceHolderEnd
samer@3: 	else
samer@3: 		return "+>"
samer@3: endfun
samer@3: " }}}
samer@3: " s:Iconv:  a wrapper for iconv()" {{{
samer@3: " Problem:  after
samer@3: " 	let text = "\xab"
samer@3: " (or using the raw 8-bit ASCII character in a file with 'fenc' set to
samer@3: " "latin1") if 'encoding' is set to utf-8, then text does not match itself:
samer@3: " 	echo text =~ text
samer@3: " returns 0.
samer@3: " Solution:  When this happens, a re-encoded version of text does match text:
samer@3: " 	echo iconv(text, "latin1", "utf8") =~ text
samer@3: " returns 1.  In this case, convert text to utf-8 with iconv().
samer@3: " TODO:  Is it better to use &encoding instead of "utf8"?  Internally, vim
samer@3: " uses utf-8, and can convert between latin1 and utf-8 even when compiled with
samer@3: " -iconv, so let's try using utf-8.
samer@3: " Arguments:
samer@3: " 	a:text = text to be encoded or decoded
samer@3: " 	a:mode = "encode" (latin1 to utf8) or "decode" (utf8 to latin1)
samer@3: " Caution:  do not encode and then decode without checking whether the text
samer@3: " has changed, becuase of the :if clause in encoding!
samer@3: function! s:Iconv(text, mode)
samer@3: 	if a:mode == "decode"
samer@3: 		return iconv(a:text, "utf8", "latin1")
samer@3: 	endif
samer@3: 	if a:text =~ '\V\^' . escape(a:text, '\') . '\$'
samer@3: 		return a:text
samer@3: 	endif
samer@3: 	let textEnc = iconv(a:text, "latin1", "utf8")
samer@3: 	if textEnc !~ '\V\^' . escape(a:text, '\') . '\$'
samer@3: 		call IMAP_Debug('Encoding problems with text '.a:text.' ', 'imap')
samer@3: 	endif
samer@3: 	return textEnc
samer@3: endfun
samer@3: "" }}}
samer@3: " IMAP_Debug: interface to Tex_Debug if available, otherwise emulate it {{{
samer@3: " Description: 
samer@3: " Do not want a memory leak! Set this to zero so that imaps always
samer@3: " starts out in a non-debugging mode.
samer@3: if !exists('g:Imap_Debug')
samer@3: 	let g:Imap_Debug = 0
samer@3: endif
samer@3: function! IMAP_Debug(string, pattern)
samer@3: 	if !g:Imap_Debug
samer@3: 		return
samer@3: 	endif
samer@3: 	if exists('*Tex_Debug')
samer@3: 		call Tex_Debug(a:string, a:pattern)
samer@3: 	else
samer@3: 		if !exists('s:debug_'.a:pattern)
samer@3: 			let s:debug_{a:pattern} = a:string
samer@3: 		else
samer@3: 			let s:debug_{a:pattern} = s:debug_{a:pattern}.a:string
samer@3: 		endif
samer@3: 	endif
samer@3: endfunction " }}}
samer@3: " IMAP_DebugClear: interface to Tex_DebugClear if avaialable, otherwise emulate it {{{
samer@3: " Description: 
samer@3: function! IMAP_DebugClear(pattern)
samer@3: 	if exists('*Tex_DebugClear')
samer@3: 		call Tex_DebugClear(a:pattern)
samer@3: 	else	
samer@3: 		let s:debug_{a:pattern} = ''
samer@3: 	endif
samer@3: endfunction " }}}
samer@3: " IMAP_PrintDebug: interface to Tex_DebugPrint if avaialable, otherwise emulate it {{{
samer@3: " Description: 
samer@3: function! IMAP_PrintDebug(pattern)
samer@3: 	if exists('*Tex_PrintDebug')
samer@3: 		call Tex_PrintDebug(a:pattern)
samer@3: 	else
samer@3: 		if exists('s:debug_'.a:pattern)
samer@3: 			echo s:debug_{a:pattern}
samer@3: 		endif
samer@3: 	endif
samer@3: endfunction " }}}
samer@3: " IMAP_Mark:  Save the cursor position (if a:action == 'set') in a" {{{
samer@3: " script-local variable; restore this position if a:action == 'go'.
samer@3: let s:Mark = "(0,0)"
samer@3: let s:initBlanks = ''
samer@3: function! IMAP_Mark(action)
samer@3: 	if a:action == 'set'
samer@3: 		let s:Mark = "(" . line(".") . "," . col(".") . ")"
samer@3: 		let s:initBlanks = matchstr(getline('.'), '^\s*')
samer@3: 	elseif a:action == 'go'
samer@3: 		execute "call cursor" s:Mark
samer@3: 		let blanksNow = matchstr(getline('.'), '^\s*')
samer@3: 		if strlen(blanksNow) > strlen(s:initBlanks)
samer@3: 			execute 'silent! normal! '.(strlen(blanksNow) - strlen(s:initBlanks)).'l'
samer@3: 		elseif strlen(blanksNow) < strlen(s:initBlanks)
samer@3: 			execute 'silent! normal! '.(strlen(s:initBlanks) - strlen(blanksNow)).'h'
samer@3: 		endif
samer@3: 	endif
samer@3: endfunction	"" }}}
samer@3: " IMAP_GetVal: gets the value of a variable {{{
samer@3: " Description: first checks window local, then buffer local etc.
samer@3: function! IMAP_GetVal(name, ...)
samer@3: 	if a:0 > 0
samer@3: 		let default = a:1
samer@3: 	else
samer@3: 		let default = ''
samer@3: 	endif
samer@3: 	if exists('w:'.a:name)
samer@3: 		return w:{a:name}
samer@3: 	elseif exists('b:'.a:name)
samer@3: 		return b:{a:name}
samer@3: 	elseif exists('g:'.a:name)
samer@3: 		return g:{a:name}
samer@3: 	else
samer@3: 		return default
samer@3: 	endif
samer@3: endfunction " }}}
samer@3: 
samer@3: " ============================================================================== 
samer@3: " A bonus function: Snip()
samer@3: " ============================================================================== 
samer@3: " Snip: puts a scissor string above and below block of text {{{
samer@3: " Desciption:
samer@3: "-------------------------------------%<-------------------------------------
samer@3: "   this puts a the string "--------%<---------" above and below the visually
samer@3: "   selected block of lines. the length of the 'tearoff' string depends on the
samer@3: "   maximum string length in the selected range. this is an aesthetically more
samer@3: "   pleasing alternative instead of hardcoding a length.
samer@3: "-------------------------------------%<-------------------------------------
samer@3: function! <SID>Snip() range
samer@3: 	let i = a:firstline
samer@3: 	let maxlen = -2
samer@3: 	" find out the maximum virtual length of each line.
samer@3: 	while i <= a:lastline
samer@3: 		exe i
samer@3: 		let length = virtcol('$')
samer@3: 		let maxlen = (length > maxlen ? length : maxlen)
samer@3: 		let i = i + 1
samer@3: 	endwhile
samer@3: 	let maxlen = (maxlen > &tw && &tw != 0 ? &tw : maxlen)
samer@3: 	let half = maxlen/2
samer@3: 	exe a:lastline
samer@3: 	" put a string below
samer@3: 	exe "norm! o\<esc>".(half - 1)."a-\<esc>A%<\<esc>".(half - 1)."a-"
samer@3: 	" and above. its necessary to put the string below the block of lines
samer@3: 	" first because that way the first line number doesnt change...
samer@3: 	exe a:firstline
samer@3: 	exe "norm! O\<esc>".(half - 1)."a-\<esc>A%<\<esc>".(half - 1)."a-"
samer@3: endfunction
samer@3: 
samer@3: com! -nargs=0 -range Snip :<line1>,<line2>call <SID>Snip()
samer@3: " }}}
samer@3: 
samer@3: let &cpo = s:save_cpo
samer@3: 
samer@3: " vim:ft=vim:ts=4:sw=4:noet:fdm=marker:commentstring=\"\ %s:nowrap