view base/classes.lisp @ 100:ad9cca28fecf

Added doc-strings

darcs-hash:20070725171218-f76cc-c62173b38861d7c368d5219cc743d85a4f67fda8.gz

(cl:in-package #:amuse) 

;; collections of more than one event

(defclass constituent (anchored-period) ())
(defclass time-ordered-constituent (constituent list-slot-sequence)
  ;; this won't work if lisp implementation doesn't support extensible
  ;; sequences.
  ())
(defclass composition (time-ordered-constituent) ())
(defclass monody (composition) ())

;; types of information-specifiers

(defclass identifier () ()) ;; for composition specification
(defclass moment-designator () ()
  (:documentation "Object indicating a point in time"))
(defclass period-designator () ()
  (:documentation "Object indicating a region of time"))
(defclass anchored-period-designator (moment-designator period-designator) ()
  (:documentation "Object indicating a region of time starting at
  a specific point in time"))
(defclass pitch-designator () ()
  (:documentation "Object indicating some sort of pitch"))
(defclass pitch-interval-designator () ()
  (:documentation "Object indicating a distance in pitch space"))

;; time-related classes

(defclass moment (moment-designator) 
  ((time :accessor %moment-time :initarg :time))
  (:documentation "A moment represented on a number line"))

(defclass period (period-designator) 
  ((interval :accessor %period-interval :initarg :interval))
  (:documentation "A number-line-based period"))

(defclass floating-period (period) ()
  (:documentation "A simple numeric period"))
(defclass anchored-period (period moment anchored-period-designator) ()
  (:documentation "Number-line-based anchored period"))

;; pitch-related classes

(defclass frequency () ())

(defclass pitch (pitch-designator) ())
(defclass chromatic-pitch (pitch) 
  ((number :accessor %chromatic-pitch-number :initarg :number))
  (:documentation "A pitch represented as a number, with higher
  values representing high pitches."))
(defclass diatonic-pitch (pitch)
  ((name :accessor %diatonic-pitch-name :initarg :name)
   (accidental :accessor %diatonic-pitch-accidental :initarg :accidental)
   (octave :accessor %diatonic-pitch-octave :initarg :octave))
  (:documentation "NAME is an integer between 0-6, representing the
note name A-G; ACCIDENTAL is an integer where negative values indicate
numbers of flats, 0 indicates natural and positive values indicate
numbers of sharps; and octave is an integer indicating the ASA octave
number (the lowest full octave of the piano starting with C is octave
1, so the lowest note on the piano is A0; middle C is C4, and
the note just below it is B3)."))

(defclass mips-pitch (pitch) 
  ((cp :initarg :cp :accessor %p-pc)
   (mp :initarg :mp :accessor %p-pm))
  (:documentation "A MIPS pitch: cp is an integer representing
chromatic pitch (An0 = 0, middle C = 39); mp is an integer
representing the morphetic pitch (An0 = 0, middle c = 23)."))

(defclass pitch-interval (pitch-interval-designator) 
  ((span :accessor %pitch-interval-span :initarg :span)))

;; events

(defclass event (anchored-period) ())
(defclass pitched-event (event pitch-designator) ())
(defclass chromatic-pitched-event (pitched-event chromatic-pitch) ())
(defclass percussive-event (event) ())

;;; Range-based `constituents'
;; Whilst these are all constituents in the CHARM sense, their
;; properties apply to a timed range rather than to a set of
;; events. As such, they can be regarded as anchored-periods with
;; properties.

(defclass time-signature (anchored-period) ())

(defclass basic-time-signature (time-signature)
  ;; N.B. Can only deal with numeric signatures
  ((numerator :accessor %basic-time-signature-numerator
	      :initarg :numerator)
   (denominator :accessor %basic-time-signature-denominator
		:initarg :denominator)))

(defclass key-signature (anchored-period) ())

(defclass basic-key-signature (key-signature)
  ;; Only has line-of-fifths distance from c, so custom signatures
  ;; won't work
  ((sharp-count :accessor %basic-key-signature-sharp-count
		:initarg :sharp-count)))

(defclass midi-key-signature (basic-key-signature)
  ;; mode: 0 = major key; 1 = minor key
  ((mode :accessor %midi-key-signature-mode
	 :initarg :mode)))

(defmethod print-object ((mks midi-key-signature) stream)
  (format stream "#<~A ~A ~A>"
          (symbol-name (class-name (class-of mks)))
          (%basic-key-signature-sharp-count mks)
          (%midi-key-signature-mode mks)))

(defclass tempo (anchored-period)
  ;; accel and rit in symbolic encoding will need other structures, as
  ;; will textual tempo markings.
  ((bpm :accessor %tempo-bpm
	:initarg :bpm)))